C# と VB.NET の質問掲示板

■No61111 (五右衛門 さん) に返信
> PrintDocumentのPrintPageイベントで最大ページ数は分かるのですが、
> PrintPreviewControlのプロパティなどにこの情報があればいいなと思いまして。
取得方法が確立しているのであれば、PrintPreviewControl を継承して、
最大ページプロパティを追加してしまうというのは如何でしょうか。


> 自作の印刷プレビュー画面では、「次頁」「前頁」またはスピンボタンで表示ページを指定しようと思うのですが、
> 最大ページ数などはどのように取得すればいいのでしょうか？

StartPage に Integer.MaxValue を渡すというのはどうでしょうか。

  Private Sub Button1_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button1.Click
      Dim curPage As Integer = PrintPreviewControl1.StartPage
      PrintPreviewControl1.StartPage = Integer.MaxValue
      Dim maxPage As Integer = PrintPreviewControl1.StartPage
      PrintPreviewControl1.StartPage = curPage
      MsgBox(maxPage)
  End Sub



あるいは PreviewPrintController の GetPreviewPageInfo が返す配列の数から
取得できないかな…と思いましたが、こちらは良い手法が思いつきませんでした。

  Private Sub Button2_Click(ByVal sender As Object, ByVal e As EventArgs) Handles Button2.Click
      Dim defaultController As System.Drawing.Printing.PrintController
      defaultController = Me.PrintPreviewControl1.Document.PrintController
      Dim sampleController As New Sample()
      Me.PrintPreviewControl1.Document.PrintController = sampleController
      Me.PrintPreviewControl1.Document.Print()
      Dim maxPage As Integer = sampleController.GetCount()
      Me.PrintPreviewControl1.Document.PrintController = defaultController
      MsgBox(maxPage)
  End Sub
  Private Class Sample
      Inherits System.Drawing.Printing.PreviewPrintController
      Public Function GetCount() As Integer
          Dim p() As System.Drawing.Printing.PreviewPageInfo = MyBase.GetPreviewPageInfo()
          Return If(p Is Nothing, -1, p.Length)
      End Function
  End Class

■No61120 (魔界の仮面弁士 さん) の方法に欠点があるのか分からないですが

ちょっと変えてみた。


    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim sampleController As New SampleController()
        MsgBox(sampleController.GetCount(Me.PrintPreviewControl1.Document))
    End Sub


Public Class SampleController
    Inherits System.Drawing.Printing.PreviewPrintController

    Private Pages As Integer

    Public Overrides Sub OnStartPrint(ByVal document As System.Drawing.Printing.PrintDocument, ByVal e As System.Drawing.Printing.PrintEventArgs)
        MyBase.OnStartPrint(document, e)
        Pages = 0
    End Sub

    Public Overrides Sub OnEndPage(ByVal document As System.Drawing.Printing.PrintDocument, ByVal e As System.Drawing.Printing.PrintPageEventArgs)
        MyBase.OnEndPage(document, e)
        Pages += 1
    End Sub

    Public Function GetCount(ByVal doc As PrintDocument) As Integer
        Dim cntlbak = doc.PrintController
        doc.PrintController = Me
        doc.Print()
        doc.PrintController = cntlbak
        Return Pages
    End Function
End Class