C# と VB.NET の質問掲示板

こんにちは。
コンボボックスのDataSourceにDataTableを用いて、Display,ValueMember
それぞれを設定しようとしているのですが
DataTable.Selectを用いたフィルタを行った結果をDataSourceに代入するいい方法がわかりません。

よろしければSelectでの戻り値のDataRow()を使った方法があればお教えいただければと思います。

上記方法よりいい方法があればそちらでも構いません。よろしくお願いいたします。


試験的に試しているコードです。

        Dim names As String() = {"りんご", "バナナ", "レモン", "トマト", "ぶどう", "みかん", "柿", "めろん"}
        Dim colors As String() = {"赤", "黄", "黄", "赤", "紫", "橙", "橙", "緑"}
        Dim dt As New DataTable
        dt.Columns.Add("Name", GetType(String))
        dt.Columns.Add("Color", GetType(String))
        Dim row As DataRow
        For lp As Integer = 0 To UBound(names)
            row = dt.NewRow
            row("Name") = names(lp)
            row("Color") = colors(lp)
            dt.Rows.Add(row)
        Next

        Dim result As DataRow() = dt.Select("Color = '黄'")

        ComboBox1.DataSource = ??

■No74224 (しろくま５ さん) に返信


以下のような感じで各要素をプロパティ付のクラス化して
ValueMember,DisplayMemberによる割り当てが出来るようにすればよいです。

        Dim result = (From r In dt.Select("Color = '黄'")
                      Select Disp = r("Name").ToString, value = r).ToList

        ComboBox1.ValueMember = "value"
        ComboBox1.DisplayMember = "Disp"
        ComboBox1.DataSource = result


    Private Sub ComboBox1_SelectedValueChanged(sender As Object, e As System.EventArgs) Handles ComboBox1.SelectedValueChanged
        Dim row = TryCast(ComboBox1.SelectedValue, DataRow)
        If row Is Nothing Then Exit Sub
        Label1.Text = row("Name").ToString
        Label2.Text = row("Color").ToString
    End Sub