C# と VB.NET の質問掲示板

■No90422 (るぴん さん) に返信

こんな感じです

Public Shared Sub Main()
    Dim checker As New NameChecker()

    Console.WriteLine(Rename(checker, "abcxyz"))
    Console.WriteLine(Rename(checker, "012789"))
    Console.WriteLine(Rename(checker, "アイウワヲン"))
    Console.WriteLine(Rename(checker, "あいうわをん"))
    Console.WriteLine(Rename(checker, "亜哀愛枠湾腕"))
    Console.WriteLine(Rename(checker, "丑abcxyz"))
    Console.WriteLine(Rename(checker, "abc丑xyz"))
    Console.WriteLine(Rename(checker, "abcxyz丑"))

    Console.ReadKey()
End Sub

Shared Function Rename(checker As NameChecker, name As String) As String
    Dim b As New Text.StringBuilder(name.Length)

    For Each c As Char In name.ToCharArray()
        If checker.NeedsRename(c) Then
            b.Append("_")
        Else
            b.Append(c)
        End If
    Next

    Return b.ToString()
End Function

Class NameChecker
    Private CharSet As HashSet(Of Integer)

    Public Sub New()
        CharSet = New HashSet(Of Integer)()

        '英数字
        For i As Integer = &H20 To &H7E
            CharSet.Add(i)
        Next

        'ひらがな
        For i As Integer = &H3040 To &H309F
            CharSet.Add(i)
        Next

        'カタカナ
        For i As Integer = &H30A0 To &H30FF
            CharSet.Add(i)
        Next

        ' 漢字
        Dim kanji As String = System.IO.File.ReadAllText("kanji.txt")

        For Each i As Integer In kanji.Select(AddressOf Convert.ToInt32)
            CharSet.Add(i)
        Next
    End Sub

    Public Function NeedsRename(c As Char) As Boolean
        Return Not CharSet.Contains(Convert.ToInt32(c))
    End Function

End Class