C# と VB.NET の質問掲示板

Visual Basic2012を使用しています。
集約例外ハンドラを使っているのですが、思うように例外を受け取れていません。
ログファイルをオープンする際に例外が発生した場合に、ログ出力をしたくないので
下記のようにコードを書きました。

メインクラス
<STAThread> _
Public Shared Sub Main()
    AddHandler Application.ThreadException, _
        AddressOf Application_ThreadException

    Application.Run(New Form1())
End Sub

Private Shared Sub Application_ThreadException(sender As Object, _
        e As System.Threading.ThreadExceptionEventArgs)

        If TypeOf e.Exception Is Log_Exception Then   �@
             'メッセージ表示のみ
        Else
             'メッセージ表示してログ出力
        End If
    
        'アプリケーション終了
        Application.Exit()
    
End Sub

ログ例外クラス
Public Class Log_Exception
        Inherits Exception
        'これの他、メッセージのみ、引数なしのコンストラクタを定義しています
        Public Sub New(ByVal errorMessage As String,ByVal _InnerException as  Exception)
                MyBase.New(errorMessage,_InnerException)
        End Sub
End Class

ログ出力クラス
Public sub Write_Log(ByVal _Log As String)
        Dim stream As IO.StreamWriter = Get_Stream
        stream.WriteLine(_Log)
End sub

Private Function Get_Stream() As IO.StreamWriter
         Try
                Return New IO.StreamWriter("ログファイルパス",True,System.Text.Encoding.GetEncoding("shift_jis"))
         Catch ex As IOException 
                 Throw New Log_Exception("ログファイルオープン時エラー発生",ex)    �A
         End Try
End Function



ログファイルを別のアプリケーションで開いたままにすると
一応�Aの後に�@には来るんですけど、中を見るとIOExceptionになっているため、
If判定しても意味がないという状態になっています。
もう�Aでメッセージを出してアプリケーション終了させようかなと思ったのですが、
何故上手くいかないのかが気になって仕方ないです。
ちなみにメッセージのみ、または引数なしでLog_Exceptionを生成すると、何故かうまくいきます。
InnerExceptionがあるときだけ、おかしくなります。
�AのLog_ExceptionをExceptionクラスに変えて試しましたが、
やはりInnerExceptionがあると�@の時点でe.ExceptionがIOExceptionになっています。

現在公開されている情報からは、
単純なコードから徐々に元のコードに復元していって、
何が原因かを探るという手法を提案できるぐらいですね。

とりあえず以下のもっとも単純な形では問題なくLogExceptionが表示されました。
（Windows 10 ver.1809, 対象フレームワーク:.NET 4.5.2および.NET 3.5）

1. 新しくWindows Formsのプロジェクトを作成する
2. Programという名前でモジュールを追加して、後述のコードを記述
3. Form1にボタンを1つ配置し、後述のコードを記述
4. プロジェクトのプロパティでアプリケーションフレームワーク有効のチェックを外し
　スタートアップオブジェクトをProgramに変更

ちなみにアプリケーションフレームワーク有効のまま、
ThreadExceptionへのAddHandlerをForm1_Loadに移動させても
問題ありませんでした。


Program.vb ------------------------------
Imports System.IO
Imports System.Text
Imports System.Threading

Module Program
    <STAThread>
    Public Sub Main()
        AddHandler Application.ThreadException, AddressOf Application_ThreadException
        Application.Run(New Form1())
    End Sub

    Public Sub Application_ThreadException(sender As Object, e As ThreadExceptionEventArgs)

        If TypeOf e.Exception Is Log_Exception Then
            MessageBox.Show("LogException")
        Else
            MessageBox.Show(e.Exception.ToString())
        End If
        Application.Exit()
    End Sub
End Module
Public Class Log_Exception
    Inherits Exception
    Public Sub New(ByVal errorMessage As String, ByVal _InnerException As Exception)
        MyBase.New(errorMessage, _InnerException)
    End Sub
End Class
Public Class Log
    Public Sub Write_Log(ByVal _Log As String)
        Using writer As StreamWriter = Get_Stream()
            writer.WriteLine(_Log)
        End Using
    End Sub
    Public Const LogPath As String = "F:\OCR\Documents\log.txt"
    Private Function Get_Stream() As StreamWriter
        Try
            Return New StreamWriter(LogPath, True, Encoding.GetEncoding("shift_jis"))
        Catch ex As IOException
            Throw New Log_Exception("ログファイルオープン時エラー発生", ex)
        End Try
    End Function
End Class

Form1.vb --------------------------------
Public Class Form1
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Using writer As New IO.StreamWriter(Log.LogPath)
            Dim log As New Log
            log.Write_Log("test")
        End Using
    End Sub
End Class