C# と VB.NET の質問掲示板

↓たとえばこんなの?

Imports System.Collections.Generic

Public Interface IHoge
  Sub Hoge()
End Interface

Public Class HogeInt : Implements IHoge
  Private value As Integer
  Public Sub New(n As Integer)
    value = n
  End Sub
  Public Sub Hoge() Implements IHoge.Hoge
    System.Console.WriteLine("Hoge:{0}", value)
  End Sub
End Class

Module Program

  '--- IHoge を実装する T を要素とするhogesの各要素に対し、
  '--- 片っ端からほげる。
  Sub AllHoge(Of T As IHoge)(hoges As IEnumerable(Of T))
    For Each item As IHoge In hoges
      item.Hoge()
    Next
  End Sub

  Sub Main()
    Dim hoges As New List(Of IHoge)
    hoges.Add(New HogeInt(123))
    hoges.Add(New HogeInt(456))
    hoges.Add(New HogeInt(789))
    AllHoge(hoges)
  End Sub
End Module

んー...C#だと yield 使って"似たこと"やらせられるんですけどねー

using System.Collections.Generic;

public abstract class Parent {

  private int value;
  private void Hoge() {
    System.Console.WriteLine("Parent.Hoge {0}", value);
  }
  public Parent(int n) {
    value = n;
  }
  public void TestMethod() {
    List<Parent> parents = new List<Parent>(GetList());
    foreach ( Parent item in GetList() ) {
      item.Hoge();
    }
  }

  protected abstract IEnumerable<Parent> GetList();
}

public class Child : Parent {
  protected override IEnumerable<Parent> GetList() {
    foreach ( Parent child in Children ) {
      yield return child;
    }
  }
  public Child(int n) : base(n) { 
    Children.Add(this);
  }

  public static readonly List<Child> Children = new List<Child>();

}

class Program {
  public static void Main() {
    Parent p;
    p = new Child(123);
    p = new Child(456);
    p = new Child(789);
    p.TestMethod();
  }
}

で、Childが
 Public Shared ReadOnly List As List(Of Parent)
を持つわけにはいかんのですか?

まぁ、いよいよとなれば 

Protected Overrides Function GetList() As System.Collections.Generic.List(Of Parent)
  Dim result As New List(Of Parent)して
  ForEachでくるくる回って
    Addして
  result 返せばいいんちゃいます?
  ' ガキが数千人いたらｧﾚですけど
End Function

> VBにはyieldはありませんし・・・

足らぬ足らぬは工夫が足らぬ、と♪

Imports System.Collections.Generic

Public MustInherit Class Parent

    Private value As Integer
    Private Sub Hoge()
        System.Console.WriteLine("Parent.Hoge {0}", value)
    End Sub

    Public Sub New(ByVal n As Integer)
        value = n
    End Sub

    Public Sub TestMethod()
        Dim parents As New List(Of Parent)(GetList())
        For Each item As Parent In parents
            item.Hoge()
        Next
    End Sub

    Public MustOverride Function GetList() As IEnumerable(Of Parent)

End Class

Public Class Child : Inherits Parent

    Public Class Enumerable : Implements IEnumerable(Of Parent)
        Public Function GetEnumeratorGeneric() As IEnumerator(Of Parent) Implements IEnumerable(Of Parent).GetEnumerator
            Return New Enumerator(Children.GetEnumerator())
        End Function
        Public Function GetEnumerator() As IEnumerator Implements IEnumerable.GetEnumerator
            Return New Enumerator(Children.GetEnumerator())
        End Function
    End Class

    Public Class Enumerator : Implements IEnumerator(Of Parent)
        Private en_ As IEnumerator(Of Child)
        Public Sub New(ByVal en As IEnumerator(Of Child))
            en_ = en
        End Sub
        Public Sub Reset() Implements IEnumerator(Of Parent).Reset
            en_.Reset()
        End Sub
        Protected Sub Dispose() Implements IDisposable.Dispose
            ' nothing to do
        End Sub
        Public Function MoveNext() As Boolean Implements IEnumerator(Of Parent).MoveNext
            Return en_.MoveNext()
        End Function

        Public ReadOnly Property CurrentGeneric() As Parent Implements IEnumerator(Of Parent).Current
            Get
                Return en_.Current
            End Get
        End Property
        Public ReadOnly Property Current() As Object Implements IEnumerator.Current
            Get
                Return en_.Current
            End Get
        End Property
    End Class

    Public Overrides Function GetList() As IEnumerable(Of Parent)
        Return New Enumerable()
    End Function

    Public Sub New(ByVal n As Integer)
        MyBase.new(n)
        Children.Add(Me)
    End Sub

    Public Shared ReadOnly Children As New List(Of Child)

End Class

Module Program
    Sub Main()
        Dim p As Parent
        p = New Child(123)
        p = New Child(456)
        p = New Child(789)
        p.TestMethod()
    End Sub
End Module