C# と VB.NET の質問掲示板

■No60712 (ザキヤマ さん) に返信
> DataTableに"ID"と"TEXT"というカラムがあるとします。
ID は Integer 型、Text は String 型で
PrimaryKey は設定されていないという状況で良いですか?


> 今回、DataTable dtを、ID=1の行を、TEXTカラムの文字数でソートしたいのですが、そのようにすればよいでしょうか？

Linq 案は shu さんが既に書かれているので、「式列」を用いた場合を。

dt.Columns.Add("TextLength", GetType(Integer), "LEN(TEXT)")
Dim 案2() As DataRow = dt.Select("ID=1", "TextLength")



■No60713 (shu さん) に返信
> Dim rows = (From row In dt.AsEnumerable _
> Where row.Field(Of Integer)("ID") = 1 _
> Order By row.Field(Of String)("Text").Length).ToArray

TEXT が DBNull だった場合にも対応させるための別案として。

Dim 案1a() As DataRow = (From row In dt Where row!ID = 1 _
    Order By row("TEXT").ToString().Length).ToArray()

Dim 案1b() As DataRow = (From row In dt Where row!ID = 1 _
        Order By If(row.IsNull("TEXT"), Integer.MinValue, Len(row!TEXT))).ToArray()


案1a は、空文字列と DBNull を共に「長さゼロ」として並び替えます。

案1b は、DBNull を空文字列よりも短い文字列として並び替えます。

■No60718 (ザキヤマ さん) に返信
>>> dt.Columns.Add("TextLength", GetType(Integer), "LEN(TEXT)")
>>> Dim 案2() As DataRow = dt.Select("ID=1", "TextLength")
追加した式列が邪魔な場合は、DataRow 配列を得た後で
　dt.Columns.Remove("TextLength")
を実行するなどして除去しておいてください。


>> Linkは変数で条件式を設定できるので、とてもいいです。
Linq を使った行は、エディット コンティニュ(一時停止作業中のコード編集)を
利用できないという制限がありますので、その点は注意が必要ですね。

まぁ、C# よりは制限が緩いのですけれども。
(VB は Linq 行のみが編集禁止。C# は Linq 呼び出しを含むメソッド全体が編集禁止。)
http://msdn.microsoft.com/ja-jp/library/bb763103.aspx



>>Dim 案1a() As DataRow = (From row In dt Where row!ID = 1 _
> とありますが、row!ID の部分はrow("ID")としてもいいんですよね？
はい。「row!ID」も「row("ID")」も、いずれも「row.Item("ID")」の呼び出しを意味します。

感嘆符演算子(ディクショナリアクセス演算子)は、
『String に相当する引数 1 つだけを受け取るインデクサなプロパティ』を
呼び出すための表記です。


> （なるべく記載方法を統一したいもので．．．）
その通りですね。すみません。(^^;

なお、ID 列から DBNull 値が返される可能性がある場合には、
「Where row("ID") = 1」はエラーとなります。

DBNull がありうる場合は、拡張メソッド Field を用いて
null 許容型として取得すると安全です。
(TEXT 列にはこの方法が使えませんが)


(A案) Where row.Field(Of Integer?)("ID") = 1

(B案) Where If(row.Field(Of Integer?)("ID"), Integer.MinValue) = 1


A案は、DBNull を 0 として扱っています。
(「If Nothing = 1 Then」は「If 0 = 1 Then」の意味で解釈される)

B案は、DBNull を -2147483648 として扱っています。