C# と VB.NET の質問掲示板

■No67297 (青花 さん) に返信
> DataGridViewで、同じコンボボックスのリスト内容を変えて表示することは可能でしょうか？

using System.Linq;
using System.Windows.Forms;

namespace WindowsFormsApplication1
{
    public partial class Form1 : Form
    {
        private DataGridView dgv;
        private string[][] data = { null, null, null };
        public Form1()
        {
            InitializeComponent();
            data[0] = new string[] {};
            data[1] = new string[] { "赤", "黄", "桃" };
            data[2] = new string[] { "青", "緑", "紫" };
            
            dgv = new DataGridView() { Dock = DockStyle.Fill, Name = "dgv" };
            dgv.EditMode = DataGridViewEditMode.EditOnEnter;
            dgv.Columns.Add("Flg", "Flg");
            dgv.Columns.Add(new DataGridViewComboBoxColumn() {
                DisplayStyle = DataGridViewComboBoxDisplayStyle.Nothing,
                HeaderText = "コンボリスト",
                Name = "コンボリスト" });

            //dgv.DataError += delegate(object o, DataGridViewDataErrorEventArgs arg)
            //{
            //    arg.Cancel = false;
            //};
            dgv.CellValueChanged += delegate(object o, DataGridViewCellEventArgs arg)
            {
                if (arg.ColumnIndex == 0)
                {
                    DataGridView g = (DataGridView)o;
                    var r = arg.RowIndex;
                    var s = (g[0, r].Value ?? "").ToString();
                    int i; int.TryParse(s, out i);
                    if (i < 0 || i > 2) i = 0;
                    g[1, r] = new DataGridViewComboBoxCell() { DataSource = data[i], Value = data[i].FirstOrDefault() };
                    g[0, r].ErrorText = (i != 0) ? "" : "Flg には 1 または 2 を指定してください。";
                }
            };

            Controls.Add(dgv);
        }
    }
}

■No67336 (青花 さん) に返信
> 魔界の仮面弁士さんのソースをVB.Netに移植しようとしてますが、中々エラーが消えません。
VB を利用されているなら、「.NET全般」で投稿せず、VB.NET を指定してくだされば良かったのに…。(^_^;)

それから、質問時にはバージョンも明記してください。古いバージョンの VB.NET を
使っている場合には、幾つかの文法構文が使えない可能性がありますので。


> 一応、頑張って下記の状態まで持ってきました。

とりあえず、最初のコードを VB 版に訳しておきます。


Option Strict On
Option Infer On
Imports System
Imports System.Linq
Imports System.Windows.Forms
Partial Public Class Form1
    Private dgv As DataGridView
    Private data(2)() As String
    Public Sub New()
        InitializeComponent()
        data(0) = {}
        data(1) = {"赤", "黄", "桃"}
        data(2) = {"青", "緑", "紫"}
        dgv = New DataGridView() With {.Dock = DockStyle.Fill, .Name = "dgv"}
        dgv.EditMode = DataGridViewEditMode.EditOnEnter
        With dgv.Columns
            .Add("Flg", "Flg")
            .Add(New DataGridViewComboBoxColumn() With _
            {.DisplayStyle = DataGridViewComboBoxDisplayStyle.Nothing _
            , .HeaderText = "コンボリスト" _
            , .Name = "コンボリスト" _
            })
        End With

        'AddHandler dgv.DataError, _
        '    Sub(o, arg)
        '        arg.Cancel = False
        '    End Sub

        AddHandler dgv.CellValueChanged, _
            Sub(o, arg)
                If arg.ColumnIndex = 0 Then
                    Dim g = DirectCast(o, DataGridView)
                    Dim r = arg.RowIndex
                    Dim s = If(g(0, r).Value, "").ToString()
                    Dim i = 0
                    Integer.TryParse(s, i)
                    If i < 0 OrElse i > 2 Then i = 0
                    g(1, r) = New DataGridViewComboBoxCell() With _
                    {.DisplayStyle = DataGridViewComboBoxDisplayStyle.Nothing _
                    , .DataSource = data(i) _
                    , .Value = data(i).FirstOrDefault() _
                    }
                    g(0, r).ErrorText = If(i <> 0, "", "Flg には 1 または 2 を指定してください。")
                End If
            End Sub

        Controls.Add(dgv)
    End Sub
End Class


上記では、最初の C# のコードで書き漏らしていた
「DisplayStyle = DataGridViewComboBoxDisplayStyle.Nothing」
の指定を追加しています。付けるかどうかはお好みで。

■No67338 (魔界の仮面弁士) に追記
> それから、質問時にはバージョンも明記してください。古いバージョンの VB.NET を
> 使っている場合には、幾つかの文法構文が使えない可能性がありますので。

バージョン依存のコードを廃しました。VB2005以降であれば動作するはずです。


Option Strict On
Imports System
Imports System.Windows.Forms
Partial Public Class Form1
    Private WithEvents dgv As DataGridView
    Private data(2)() As String
    Public Sub New()
        InitializeComponent()
        ReDim data(0)(-1)
        data(1) = New String() {"赤", "黄", "桃"}
        data(2) = New String() {"青", "緑", "紫"}
        dgv = New DataGridView()
        With dgv
            .Dock = DockStyle.Fill
            .Name = "dgv"
            .EditMode = DataGridViewEditMode.EditOnEnter

        End With
        With dgv.Columns
            Dim col As New DataGridViewComboBoxColumn()
            col.DisplayStyle = DataGridViewComboBoxDisplayStyle.Nothing
            col.HeaderText = "コンボリスト"
            col.Name = "コンボリスト"
            .Add("Flg", "Flg")
            .Add(col)
        End With
        Controls.Add(dgv)
    End Sub

    'Private Sub dgv_DataError(ByVal sender As Object, ByVal e As DataGridViewDataErrorEventArgs) Handles dgv.DataError
    '    e.Cancel = True
    'End Sub

    Private Sub dgv_CellValueChanged(ByVal sender As Object, ByVal e As DataGridViewCellEventArgs) Handles dgv.CellValueChanged
        If e.ColumnIndex = 0 Then
            Dim g As DataGridView = DirectCast(sender, DataGridView)
            Dim r As Integer = e.RowIndex
            Dim o As Object = g(0, r).Value
            Dim i As Integer = 0
            If o IsNot Nothing Then
                Dim s As String = o.ToString()
                Integer.TryParse(s, i)
                If i < 0 OrElse i > 2 Then
                    i = 0
                End If
            End If
            Dim combo As New DataGridViewComboBoxCell()
            With combo
                .DisplayStyle = DataGridViewComboBoxDisplayStyle.Nothing
                .DataSource = data(i)
                If data(i).Length > 0 Then
                    .Value = data(i)(0)
                Else
                    .Value = Nothing
                End If
                g(1, r) = combo
            End With
            If i <> 0 Then
                g(0, r).ErrorText = ""
            Else
                g(0, r).ErrorText = "Flg には 1 または 2 を指定してください。"
            End If
        End If
    End Sub
End Class