C# と VB.NET の質問掲示板

■No103815 (shiro さん) に返信
> pointListからwallListに変えました。
> Private wallList As New List(Of Wall)
その方が分かりやすいので良いと思います。


> startPoint、endPointとWallクラスでエラーが出ます。
いわゆるコンパイルエラーというやつですね。

前回 ( No103812 ) でも指摘させていただきましたが、「変数のスコープと寿命」に関して
Visual Basic の言語機能として習得しきれていない印象を受けました。


> '耐力壁
> Case "wall"
> 　startPoint As New Wall(SnapToGrid(e.Location))

As 句は、変数宣言時に型を明示するためのものです。

startPoint は、MouseDown イベントで書き込まれ、Paint イベントで読まれる値
endPoint は、MouseMove/MouseUp イベントで書き込まれ、Paint イベントで読まれる値
ですよね。そのほか、isPlacing もそうですね。

つまり、これらの変数は『複数のイベントで使われる変数』なのですから、
これらの変数は「ローカル変数」ではなく「フィールド変数」でなければなりません。
ローカル変数だと、変数の寿命がプロシージャー単位(Sub や Function ごと)になってしまいます。


さて、ローカル変数における
　　Dim a As New Foo(b)
という記述は、Visual Basic では
　　Dim a As Foo = New Foo(b)
と完全に同じです。
これらは、変数の宣言と同時に、その初期値を設定するためのコードですよね。

宣言済みのクラス変数に対して、そのインスタンスを割り当てる場合、
宣言済みの「Dim a As Foo」あるいは「Priavate a As Foo」への代入のために
　　a = New Foo(b)
と書くことはできますが
　　a As New Foo(b)
と書くことはできません。As は変数宣言時に型を指定するためのものだからです。

そのため、現在の
> startPoint As New Wall(SnapToGrid(e.Location))
> endPoint As New Wall(SnapToGrid(e.Location))
という記述は、コンパイルエラーになってしまっているということです。
複数のイベントで使われる変数は、Form1 直下にローカル変数として宣言しましょう。


ただ、startPoint や endPoint という名から想像するに、
それらは壁そのものではなく、
壁の端を表す位置情報に過ぎないはずです。つまり、
　　Private startPoint As Wall
　　Private endPoint As Wall
といった「壁オブジェクト」(Wall クラス)ではなく、
　　Private startPoint As Point
　　Private endPoint As Point
といった「位置オブジェクト」(Point 構造体)であるはずなのです。


MouseDown で決まるのは壁の始端位置なので、「startPoint = SnapToGrid(e.Location)」とします。
MouseMode/MouseUp では壁の終端位置なので、「endPoint = SnapToGrid(e.Location)」とします。
いずれの場合も、位置情報が更新されたので、「PictureBox1.Invalidate()」で再描画を依頼します。

また、MouseUp のタイミングでは、始端と終端の両方が揃ったことになりますので、
これでようやく「壁」を建てることできるようになります。両端が確定したので、
　　Dim newWall As New Wall(startPoint, endPoint)　'新しい壁を準備
　　wallList.Add(newWall)　'それを壁一覧に加える
を行うことで、Paint イベントに壁情報を渡せるようになります。


……とはいえ、上記の改修を行うと、今度は New Wall(〜) を呼び出す部分で、
また別のコンパイルエラー（引数の数が違っているので）になってしまうはずです。


そもそも、壁の位置は (X,Y) が一つだけあっても決定できません。
当然、(X1,Y1)と(X2,Y2) が必要なわけです。そのための修正を行いましょう。

ついでに、剛性値も「既定値(2.5)」または「任意値」の両方に対応させちゃいましょうか。


'=== 案1 ===
Public Class Wall
    Private Shared LastIndex As Integer = 0
    Private Const DefaultStiffnessValue As Double = 2.5

    Public ReadOnly Property Index As Integer
    Public Property StartPoint As Point
    Public Property EndPoint As Point
    Public Property Stiffness As Double

    Public Sub New(startPoint As Point, endPoint As Point)
        Me.New(startPoint, endPoint, DefaultStiffnessValue)
    End Sub

    Public Sub New(startPoint As Point, endPoint As Point, stiffness As Double)
        LastIndex += 1
        Me.Index = LastIndex
        Me.StartPoint = startPoint
        Me.EndPoint = endPoint
        Me.Stiffness = stiffness
    End Sub
End Class


'=== 案2 ===
Public Class Wall
    Private Shared LastIndex As Integer = 0
    Private Const DefaultStiffnessValue As Double = 2.5

    Public ReadOnly Property Index As Integer
    Public Property StartPoint As Point
    Public Property EndPoint As Point
    Public Property Stiffness As Double

    Public Sub New(startPoint As Point, endPoint As Point, Optional stiffness As Double = DefaultStiffnessValue)
        LastIndex += 1
        Me.Index = LastIndex
        Me.StartPoint = startPoint
        Me.EndPoint = endPoint
        Me.Stiffness = stiffness
    End Sub
End Class


これにより、
　　Dim newWall As New Wall(startPoint, endPoint)
　　wallList.Add(newWall)
あるいは、両者をまとめて
　　wallList.Add(New Wall(startPoint, endPoint))
と書けるようになります。また、剛性値を別の値とするために
　　wallList.Add(New Wall(startPoint, endPoint, 2.2))
といった指定も可能となっています。


Paint イベントの描画については、
　For Each w In WallList
　　e.Graphics.DrawLine(pen7, w.StartPoint, w.EndPoint)
　Next
になります。一つの Wall インスタンスで始点と終点の両方を管理しているため、
従来の Step 2 な For ループを使う必要がなく、処理が簡潔になります。


なお、上記では Wall クラスの座標情報を 2 つの Point で表していますが、
元のソースに従って、X1, Y1, X2, Y2 の 4 つの Integer で表現することもできるでしょう。
どちらが良いかはお好みで。


> csvファイルへの出力は、壁の始点(X,Y)、終点(X,Y)、剛性と出力したいです。
> Type	Index	 X1	 Y1	 X2	 Y2	Stiff
> W   	1    	280	 40	360	 40	  2.5
> W   	2    	280	120	360	120	  2.5

Type=W が壁を意味するデータで
Type=C が柱を意味する行データなのですよね。
柱用の CSV と壁用の CSV で別ファイルになるのでしょうか?

もしも一つのファイルにするのなら、壁と柱で列数が動的に変化するのは、ちょっと不自然かもしれませんね。
列数可変な CSV も世の中にはありますが、ヘッダー付き CSV で行ごとに列数が異なるケースは稀ですし。

案1) ヘッダー行（今回は、"Type,Index," で始まる行)が、ファイル先頭だけでなく文中にも現れ、そこから列数が切り替る
案2) どちらも7列構成にするが、柱の時は先頭4列だけを使い、未使用列には空のデータが入る（空列のためのカンマが続く形になる）
案3) CSV の代わりに、レコードごとに構造を混ぜられる形式(JSON や XML など)を採用する



＜ひとりごと＞

建築構造体としての柱というニュアンスであれば、Pillar クラスではなく Column クラスの方が単語的に望ましいかな…。
でも Column だと、グリッドや CSV などの「Row/Column」の意味に混同されそうで、命名的に悩んでしまった。

Column 　⇒ 柱、あるいは建築物の中で装飾的・構造的に並んでいる縦の柱
Pillar 　⇒ 建物の主要構造を支える支柱、記念碑や大黒柱などといった中心的存在あるいは意匠的に独立した支柱
Pier 　　⇒ 建築・土木分野の専門用語で「柱状の構造物」「基礎・橋脚・大型の柱」を指す
Post 　　⇒ 支柱・杭、小さい柱や看板の支え
Pole 　　⇒ 細長い棒・支柱、電信柱や旗竿など
Stanchion⇒ 鉄パイプなどの支柱・枠、工事現場の柵や支柱
Support　⇒ 支えとしての支柱、構造体のサポート部材
Beam 　　⇒ 横向きの梁、水平な構造体

方眼上に配置するための柱なので、GridColumn とか? こちらは WPF の Grid.Column を連想してしまいそう。

StructuralColumn クラスという名前にすれば明確にはなるけれど、それだと Wall に比べて名前が冗長すぎるか。

Pier であれば、Pillar と Column の中間的なニュアンスとなり、Row/Column との混同も避けられるけれど、
そもそも専門用語過ぎて伝わらないだろうなぁ…。(一般語としての Pier は、桟橋・埠頭の意味で使われる)


＜／ひとりごと＞