C# と VB.NET の質問掲示板

わんくま同盟

ASP.NET、C++/CLI、Java 何でもどうぞ

C# と VB.NET の入門サイト

■91906 / 3階層)  C++からVBへの変換
□投稿者/ 魔界の仮面弁士 (2291回)-(2019/08/09(Fri) 12:18:23)
No91905 (えんえん さん) に返信
> 配列と同じように値を取得できませんが
> どのように使用すれば良いのでしょうか?

ArraySegment は「大きな配列に対する一部の範囲のみ」を切り出した情報を管理します。
イメージとしてはこんな感じ。

Public Class ArraySegment
 Public Property Array As Double() '←管理対象となる配列そのものを表す

 Public Property Offset As Integer  'その配列のどの位置から
 Public Property Count As Integer   '幾つ分の要素を扱いたいのかを管理
End Class


使い方の例として:

Module Module1

  Sub Main()
    Dim dblArray As Double() = {11, 22, 33, 44, 55, 66, 77, 88}

    Dim ar1 As New ArraySegment(Of Double)(dblArray)

    Console.WriteLine("=== 中身を確認 ===")
    Test1_Dump(ar1)

    Console.WriteLine("=== 2〜5番目を切り出す ===")
    Dim ar2 = Test2_Slice(ar1)
    Test1_Dump(ar2)

    Console.WriteLine("=== 0 番目と 2 番目の値を入れ替える ===")
    Test3_Swap(ar2)
    Test1_Dump(ar2)

    Console.WriteLine("=== 1 番目の値を 10 倍にする ===")
    Test4_Modify(ar2)
    Test1_Dump(ar2)

    Console.WriteLine("=== 元の配列はどうなったか? ===")
    Array.ForEach(dblArray, AddressOf Console.WriteLine)

    Console.Write("*** 何かキーを押してください ***")
    Console.ReadKey()
  End Sub

  '中身を列挙してみる
  Sub Test1_Dump(a As ArraySegment(Of Double))
    Console.WriteLine("全要素数={0}", a.Array.Length)
    Console.WriteLine("開始位置={0}", a.Offset)
    Console.WriteLine("範囲の数={0}", a.Count)
    For Each dbl In a
      Console.WriteLine("... {0}", dbl)
    Next
    Console.WriteLine("----")
  End Sub

  '相対位置指定で index +2〜+5 の位置を切り出して返す
  Function Test2_Slice(a As ArraySegment(Of Double)) As ArraySegment(Of Double)
    Return New ArraySegment(Of Double)(a.Array, a.Offset + 2, 4)
  End Function

  '相対位置指定で index 0 と index 2 の値を入れ替える
  Sub Test3_Swap(a As ArraySegment(Of Double))
    Dim swap0 As Double = a(0)
    Dim swap2 As Double = a(2)
    a.Array(a.Offset + 0) = swap2
    a.Array(a.Offset + 2) = swap0
  End Sub

  '相対位置指定で index 1 の場所の値を 10 倍にする
  Sub Test4_Modify(a As ArraySegment(Of Double))
    a.Array(a.Offset + 1) *= 10
  End Sub
End Module
編集キー/

前の記事(元になった記事) 次の記事(この記事の返信)
←Re[2]: C++からVBへの変換 /えんえん →Re[4]: C++からVBへの変換 /えんえん
 
上記関連ツリー

C++からVBへの変換 / えんえん (19/08/08(Thu) 22:51) #91899
Re[1]: C++からVBへの変換 / 魔界の仮面弁士 (19/08/08(Thu) 23:48) #91900
  └ Re[2]: C++からVBへの変換 / えんえん (19/08/09(Fri) 10:36) #91905
    └ C++からVBへの変換 / 魔界の仮面弁士 (19/08/09(Fri) 12:18) #91906 ←Now
      └ Re[4]: C++からVBへの変換 / えんえん (19/08/09(Fri) 12:28) #91907
        └ Re[5]: C++からVBへの変換 / Hongliang (19/08/09(Fri) 12:46) #91908
          └ Re[6]: C++からVBへの変換 / ぶなっぷ (19/08/09(Fri) 13:05) #91909
            └ Re[7]: C++からVBへの変換 / えんえん (19/08/09(Fri) 13:12) #91910
              ├ Re[8]: C++からVBへの変換 / Hongliang (19/08/09(Fri) 13:18) #91911
              │└ Re[9]: C++からVBへの変換 / えんえん (19/08/09(Fri) 13:23) #91912
              │  └ Re[10]: C++からVBへの変換 / 魔界の仮面弁士 (19/08/09(Fri) 17:42) #91917
              └ Re[8]: C++からVBへの変換 / 魔界の仮面弁士 (19/08/09(Fri) 13:54) #91913
                └ Re[9]: C++からVBへの変換 / えんえん (19/08/10(Sat) 07:13) #91924
                  └ Re[10]: C++からVBへの変換 / 魔界の仮面弁士 (19/08/10(Sat) 09:41) #91925
                    └ Re[11]: C++からVBへの変換 / えんえん (19/08/10(Sat) 10:16) #91927
                      └ Re[12]: C++からVBへの変換 / 魔界の仮面弁士 (19/08/10(Sat) 14:19) #91930
                        └ Re[13]: C++からVBへの変換 / 774RR (19/08/10(Sat) 15:02) #91932
                          ├ Re[14]: C++からVBへの変換 / 魔界の仮面弁士 (19/08/10(Sat) 16:23) #91933
                          │└ Re[15]: C++からVBへの変換 / えんえん (19/08/11(Sun) 21:42) #91934
                          │  └ Re[16]: C++からVBへの変換 / 魔界の仮面弁士 (19/08/12(Mon) 12:05) #91938
                          │    ├ Re[17]: C++からVBへの変換 / えんえん (19/08/12(Mon) 14:12) #91939
                          │    │├ Re[18]: C++からVBへの変換 / 魔界の仮面弁士 (19/08/12(Mon) 16:25) #91940
                          │    │├ Re[18]: C++からVBへの変換 / 魔界の仮面弁士 (19/08/12(Mon) 17:33) #91942
                          │    │└ Re[18]: C++からVBへの変換 / 774RR (19/08/12(Mon) 16:56) #91941
                          │    └ Re[17]: C++からVBへの変換 / 魔界の仮面弁士 (19/08/13(Tue) 01:00) #91946
                          └ Re[14]: C++からVBへの変換 / 魔界の仮面弁士 (19/08/12(Mon) 22:51) #91944
                            └ Re[15]: C++からVBへの変換 / えんえん (19/08/13(Tue) 11:01) #91947

上記ツリーを一括表示 / 上記ツリーをトピック表示
 
上記の記事へ返信