C# と VB.NET の質問掲示板

■No60520 (やんまー さん) に返信
> WebBrowserの縮小ができなくて困っています。アドバイスいただけないでしょうか・・・
WebBrowser には
　(1) ActiveX 版 WebBrowser コントロール
　(2) System.Windows.Forms.WebBrowser クラス
　(3) System.Windows.Controls.WebBrowser クラス
があります。

参考にされていたコードは(1)用の物だと思いますが、
やんまーさんが使っているのは(2)では無いでしょうか?


> 「'runtimeStyle' is not a member of 'System.Windows.Forms.HtmlElement'. (BC30456)」
VB.NET から マネージWebBrowser を使っている場合は、
　WebBrowser1.Document.Body.DomElement.runtimeStyle.zoom = "50%"
のように、DomElement プロパティを使って COM オブジェクトを得ることができます。

> となってしまいました。VBAじゃないとダメなんですね。。。
VBA かどうかではなく、ActiveX(COM)版のオブジェクトであるかどうかです。

もしも VB.NET や VBA から ActiveX 版 WebBrowser を使っている場合には
　WebBrowser1.Document.body.runtimeStyle.zoom = "50%"
のように書けます。今回使っているのは ActiveX 版ではありませんけれどね。


> Dim pvaIn As Object = 50　'パーセント。10〜1000 の範囲
> Dim pvaOut As Object = Type.Missing　' 変更結果が返される
> Dim OLECMDID_OPTICAL_ZOOM As SHDocVw.OLECMDID = DirectCast(63, SHDocVw.OLECMDID)
> DirectCast(webBrowser1.ActiveXInstance, SHDocVw.IWebBrowser2).ExecWB(OLECMDID_OPTICAL_ZOOM, SHDocVw.OLECMDEXECOPT.OLECMDEXECOPT_DODEFAULT, pvaIn, pvaOut)
OLECMDID_OPTICAL_ZOOM が使えるのは IE7 以降ですが、その点は大丈夫でしょうか。
http://msdn.microsoft.com/en-us/library/ms691264.aspx

OLECMDID_OPTICAL_ZOOM ( = 63 ) は IE7 以降が必要ですが、
OLECMDID_ZOOM ( = 19 ) の場合は、それ以前のバージョンでも使えます。
拡大縮小ではなく、文字サイズの変更という意味になってしまいますし、
1〜5の段階しか設定できませんけれどね。


> としたのですが、
> 「Type 'SHDocVw.OLECMDID' is not defined. (BC30002) 」
> となってしまいました・・・
とりあえず、
　DirectCast(WebBrowser1.ActiveXInstance, SHDocVw.IWebBrowser2).ExecWB(63, 0, pvaIn)
でも一応動作します。OLECMDID は単なる列挙体なので、値さえ正しければ Integer で代用できます。
http://www.icsharpcode.net/CodeReader/SharpDevelop/085/GuiBrowserSHDocVw.cs.html



> 参照でshdocvw.dllも追加したのですが・・・
とりあえず、
　Dim a As SHDocVw.IWebBrowser2
　Dim b As SHDocVw.OLECMDID
というコードはコンパイルが通りますか?
通らないのであれば、OLECMDID 等が ShDocVW.dll 以外のライブラリに含まれているのかも知れません。
(OS /IE によって、タイプライブラリのファイル名が微妙に異なっているため)


> もしかしたらvisualStudioではないからとも思ったのですが（Sharpdevelopを使ってます）
> そんなハズはないとも思っています。
SharpDevelop はアンインストールしてしまったので、私は検証できません…。

■No60565 (やんまー さん) に返信
>>必要な DLL を参照設定した後、IWebBrowser2 等が SHDocVw 以外の名前空間に
>>含まれていないかどうか探してみてください。

手元の Visual Studio 2008 環境では、参照設定すると Interop.SHDocVw.dll が
自動生成されました。それを、「.NET Reflector v6.8」で参照してみると、
その Interop.SHDocVw アセンブリの中に SHDocVw.IWebBrowser2 がありました。

ただし、Visual Studio のインテリセンスでは表示されませんでした。開発環境からは非表示のようです。


> 簡単にできそうだと思っていたのですが、
> かなり難しそうですね。。。。

手元の環境( XP/SP3 + IE8 + VB2008 )では、下記のようにして拡大/縮小できました。

Private Sub Form1_Load(ByVal sender As Object, _
                       ByVal e As EventArgs) Handles Me.Load
    TrackBar1.Minimum = 10
    TrackBar1.Maximum = 1000
    TrackBar1.LargeChange = 10
    TrackBar1.SmallChange = 1
    TrackBar1.Value = 100

    WebBrowser1.Navigate("http://jumbofoot.cocolog-nifty.com/yass_vbnet_tips/2006/09/webbrowser_bcb8.html")
End Sub

Private Sub TrackBar1_ValueChanged(ByVal sender As Object, ByVal e As EventArgs) Handles TrackBar1.ValueChanged
    Dim wb As Object = WebBrowser1.ActiveXInstance
    If wb IsNot Nothing Then
        Const OLECMDID_OPTICAL_ZOOM As Integer = 63

        Dim pvaIn As Object = TrackBar1.Value
        Dim pvaOut As Object = Type.Missing

        CallByName(WebBrowser1.ActiveXInstance, "[DispID=502]", CallType.Method, _
                   OLECMDID_OPTICAL_ZOOM, 0, pvaIn, pvaOut)
    End If
End Sub

■No60566 (魔界の仮面弁士) に追記
>         CallByName(WebBrowser1.ActiveXInstance, "[DispID=502]", CallType.Method, _
>                    OLECMDID_OPTICAL_ZOOM, 0, pvaIn, pvaOut)

別案として。


Private Sub TrackBar1_ValueChanged(ByVal sender As Object, ByVal e As EventArgs) Handles TrackBar1.ValueChanged
    Dim wb As Object = WebBrowser1.ActiveXInstance
    If wb IsNot Nothing Then
        Dim asm As Assembly = Assembly.GetAssembly(GetType(Form))
        Dim t As Type = asm.GetType("System.Windows.Forms.UnsafeNativeMethods+IWebBrowser2")

        Const OLECMDID_OPTICAL_ZOOM As Integer = 63
        Dim pvaIn As Object = TrackBar1.Value
        Dim params() As Object = {OLECMDID_OPTICAL_ZOOM, 0, pvaIn, IntPtr.Zero}

        t.GetMethod("ExecWB").Invoke(wb, BindingFlags.InvokeMethod, Nothing, params, Nothing)
    End If
End Sub