C# と VB.NET の質問掲示板

■No60970 (逆運の覇者 さん) に返信
> 単純なループで負荷を不必要にかけ続けているのでフリーズした状態になっています。
> それはそういうエラーメッセージです。
> ERさんのプログラムがCPUを待機して休む時間を与えずに動かしまくっているのです。
> これを参考にすると良いかと。
> 
> 時間がかかる処理での「応答なし」を回避するには？
> ttp://www.atmarkit.co.jp/fdotnet/dotnettips/136doevents/doevents.html
> 
エラーについては、解決いたしました。
ですが今度は、プログラムが正常に動作しないという事が起こりました。
どこかコードにおかしい所はありますか？
ヒント程度でいいので、お教え頂ければ光栄です。

■No61003 (逆運の覇者 さん) に返信
> さて、問題点についてですが
> 指定の時間になってもこのループを抜けることができないことが問題です。
> これでは、指定の時間になっても実行できないのがわかりますね？
> 実行する処理がループの外にあるのにもかかわらず、いつまでもループの中にいるのですから。
> 対処としては、Count=0 の下に Break を加えてくださいな。
> それでループを脱出します。

Count=0の下にループ脱出を加えました。
ですが、GenZaiとXdayが等しくなっても、ループから脱出(？)できません。
現在下記のようになっています。

       Do Until Count = 0

            If genZai = xDay Then

                Count = 0
                Exit Do
            Else

                Count = 1
            End If
            Application.DoEvents()
        Loop

うまく説明できなくて申し訳ありません。

■No61005 (ER さん) に返信
> GenZaiとXdayが等しくなっても

GenZai と Xday ではなく、
genZai と xDay ですよね。

(VB は大文字小文字を区別しませんが、質問内容を明確にするため、念のために確認)


> Count=0の下にループ脱出を加えました。
> ですが、GenZaiとXdayが等しくなっても、ループから脱出(？)できません。

一致していることをどのようにして確認されましたか?
それらが等しく無いからこそ、Exit Do しないのだと思いますよ。


> 現在下記のようになっています。

ループ中には、genZai や xDay を書き換えている箇所がありませんよね。
これでは、これらの変数はいつまでも経っても変わりませんので、脱出条件を満たせません。

(もしかしたら、DoEvents のタイミングでループ外から書き換えているのかな…とも思ったのですが、
 今回の変数はローカル変数のようですから、外部から書き換わることはありえませんしね。)


ついでに、本題以外の点についても幾つか指摘させてください。

>>> Dim Count As String
>>> Count = 1

String 変数に Integer 値を代入してしまっていますね。データ型を揃えましょう。
型の違いによる問題を防ぐため、『Option Strict On』を使う事も検討してみてください。



>>> '現在日時をセット
>>> genZai = Format(Now, "yyyyMMddHHmmss")
>>> '設定日時をセット
>>> xDay = yyyy & mm & dd & hh & nn & ss

設定日付は、Form3.TextBox1.Text などから得ているようですが、
これらの変数の桁数は保証されていますか?

たとえば午前6時に実行される場合に、hh が "06" ではなく "6" になってしまう可能性が
あるのならば、事前に入力検査を実施する必要があるかと思います。


また、OS の地域設定が和暦モードに設定されていた場合に、
yyyy の内容と genZai の年部分の書式が合致しているかも確認した方が良いでしょう。


>        Do Until Count = 0
(中略)
>             Application.DoEvents()
>         Loop
DoEvents を延々とループで呼び出し続けるのは、あまり望ましい実装ではありません。

DoEvents の繰り返さずに済むよう、Timer コンポーネントあるいは BackgrondWorker を
使ったコーディングに変更することをお奨めします。

■No61015 (ER さん) に返信

button1をクリックして15秒間EnabledがFalseになります。

Timer1(Timerコントロール)をFormに貼り付け
Interval=100、
Enabled=False
に設定


    Private ExecTime As Date

    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Timer1.Enabled = True
        ExecTime = Date.Now.AddSeconds(15)
        Button1.Enabled = False
    End Sub

    Private Sub Timer1_Tick(sender As System.Object, e As System.EventArgs) Handles Timer1.Tick
        If Date.Now.Subtract(ExecTime).TotalSeconds >= 0 Then
            Timer1.Enabled = False
            '---　処理
            Button1.Enabled = True
        End If
    End Sub

■No61015 (ER さん) に返信
> プログラムがとても重くなってしまうことが分かりました。

重くなります。そのため、今回のような目的にはループ待機は使われません。


たとえば、カップラーメンを作るために 3 分の待ち処理があるとします。
これを実世界の作業で考えてみると、待ち処理をループで実装するという事は、

　(1) 子供が親に、「もう 3 分経った？」と質問する。
　(2) 親が「まだだよ」と答えたら、子は間髪入れずに(1)に戻って再質問。
　(3) 「もういいよ」の答えとともに、子供は食べ始める。

という処理にあたります。
単純なやりとりとはいえ、これでは相当の負担となりますよね。

この質問の嵐という負担から解放される手法としては、
　≪A案≫ キッチンタイマーを「3分後」に鳴るように仕掛けておく。
　≪B案≫ 現在時刻の確認は連続して行わず、一定間隔(たとえば 30 秒ごと)に行う。
などが考えられますが、ここで使われるのが Timer コンポーネントです。


Timer は、一定時間が経過するごとに(≠一定時間ごとに)Tick イベントを発生させます。
この時間間隔は、Interval プロパティで指定できます。
(Interval の最大値は 2147483647 ミリ秒であり、これは約 24.8 日間に相当します)


たとえば A案の 3 分後にセットするという流れなら、こんな感じです。

Private Sub Button1_Click() Handles Button1.Click
    Button1.Enabled = False     '2度押し禁止

    Timer1.Interval = 180000    '3分=180秒=18万ミリ秒
    Timer1.Start()
End Sub

Private Sub Timer1_Tick() Handles Timer1.Tick
    Timer1.Stop()
    MessageBox.Show("3分経ったよ！")

    Button1.Enabled = True
End Sub



あるいは B 案ならこんな感じ。

    Private endTime As Date

    Private Sub Button1_Click() Handles Button1.Click
        Button1.Enabled = False     '2度押し禁止

        endTime = Now.AddMinutes(3.0R)  '終了時刻(3分後)

        Timer1.Interval = 30000     '30秒間隔で確認
        Timer1.Start()
    End Sub

    Private Sub Timer1_Tick() Handles Timer1.Tick
        If Now >= endTime Then
            Timer1.Stop()
            MessageBox.Show("3分経ったよ！")

            Button1.Enabled = True
       'Else
       '    Label1.Text = FormatDateTime(Now)
        End If
    End Sub


上記では 30 秒間隔にしていますが、たとえば Interval を 1 秒間隔にしておいて、
目標時刻になるまでは経過秒数や現在時刻を表示するようにする、といった使い方もできます。