C# と VB.NET の質問掲示板

■No63894 (kiri さん) に返信
あなたがしたい方法とは違うので、適切に修正して下さい。

' 新規に WindowsApplication を作成
' フォーム上に、Label, TextBox, Button を1個ずつ配置
' フォーム上に、Timer を3個配置し、Name を ScrollTimer, StartTimer, StopTimer に変更
' テキストボックスに開始時間を "HH:mm" 等、DateTime にパースできる形で入力し、button1 をクリックする。
' その時間になると20秒間、"時間になりました" を表示する。
' "時間になりました" は、ウインドウの右端から左端へスクロール表示される。
Public Class Form1
    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
        Me.Label1.Text = String.Empty
        Me.StartTimer.Stop()
        Me.ScrollTimer.Stop()
        Me.StopTimer.Stop()
        Me.StopTimer.Interval = 20 * 1000
    End Sub

    Private Function CheckTime(ByRef setTime As DateTime) As Boolean
        Dim s As System.Globalization.DateTimeStyles = Globalization.DateTimeStyles.AllowWhiteSpaces _
                                                       Or Globalization.DateTimeStyles.AssumeLocal
        If DateTime.TryParse(Me.TextBox1.Text, Nothing, s, setTime) = False Then
            MessageBox.Show(Me, "時間の指定が正しくありません")
            Return False
        End If

        If setTime < DateTime.Now Then
            MessageBox.Show(Me, "既に過ぎています")
            Return False
        End If

        Return True
    End Function

    Private Sub StartScrolling(ByVal source As Object, ByVal e As EventArgs) Handles StartTimer.Tick
        Me.StartTimer.Stop()
        Me.Label1.Text = "時間になりました"
        Me.Label1.Left = Me.Width
        Me.ScrollTimer.Start()
        Me.StopTimer.Start()
    End Sub

    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Dim setTime As DateTime
        If Me.CheckTime(setTime) = False Then Return
        Me.Button1.Enabled = False
        Me.TextBox1.Enabled = False
        Me.StartTimer.Interval = CInt(setTime.Subtract(DateTime.Now).TotalMilliseconds)
        Me.StartTimer.Start()
    End Sub

    Private Sub ScrollTelop(sender As System.Object, e As System.EventArgs) Handles ScrollTimer.Tick
        Me.Label1.Left -= 10
        If Me.Label1.Left < Me.Label1.Width Then
            Me.Label1.Left = Me.Width
        End If
    End Sub

    Private Sub StopScrolling(sender As System.Object, e As System.EventArgs) Handles StopTimer.Tick
        Me.StopTimer.Stop()
        Me.ScrollTimer.Stop()
        Me.Label1.Text = String.Empty
        Me.TextBox1.Enabled = True
        Me.Button1.Enabled = True
    End Sub
End Class