C# と VB.NET の質問掲示板

■No66895 (pang2 さん) に返信
> つ
> http://bbs.wankuma.com/index.cgi?mode=al2&namber=60603&KLOG=101

pang2 さま、教えて頂いたサイトでうまくいきました。ありがとうございました。
具体的には、ここに書いてあったWebClientを継承したCookieAwareWebClientクラスをアレンジし、
以下のようにCookieContainerのプロパティを用意して、ここにクッキーを含めたクッキーコンテナを
セットすることによりダウンロードができました。

Imports System.Net

Public Class CookieAwareWebClient
    Inherits WebClient
    Private m_container As CookieContainer

    Public Property CookieContainer() As CookieContainer
        Get
            Return m_container
        End Get
        Set(ByVal value As CookieContainer)
            m_container = value
        End Set
    End Property

    Protected Overrides Function GetWebRequest(ByVal address As Uri) As WebRequest
        Dim webRequest As WebRequest = MyBase.GetWebRequest(address)

        If TypeOf webRequest Is HttpWebRequest Then
            Dim httpWebRequest As HttpWebRequest = DirectCast(webRequest, HttpWebRequest)
            httpWebRequest.CookieContainer = m_container
        End If

        Return webRequest
    End Function
End Class

ただし、このサイトに書いてあった

> CookieContainer.SetCookies(uri, webBrowser1.Document.Cookie)

ではなぜかCookieがうまく渡せなかったので、webBrowser1.Document.Cookieの内容を分割したものから
CookieCollectionを作成してCookieContainerを用意しました。

とりあえず本件は解決しました。ありがとうございました。

>>CookieContainer.SetCookies(uri, webBrowser1.Document.Cookie)
> 
> ではなぜかCookieがうまく渡せなかったので、webBrowser1.Document.Cookieの内容を分割したものから
> CookieCollectionを作成してCookieContainerを用意しました。

webBrowser1.Document.Cookieの内容を確認したところ、各Cookieの組み合わせがセミコロン";"で区切られていました。
Cookieのヘッダ情報では、各Cookieの区切りはセミコロンではなくカンマ","だったと思い、試しに、以下のコードのように
セミコロンをカンマに置き換えたものをCookieContainer.SetCookiesに渡したところ、うまくCookieをセットすることができました。


Dim url As String = 「PDFのURL」
Dim cc As New CookieContainer
cc.SetCookies(New Uri(url), Replace(WebBrowser1.Document.Cookie, ";", ","))
Using wc As New CookieAwareWebClient
    wc.CookieContainer = cc
    wc.DownloadFile(url, 「保存先ファイル名」)
End Using

これで完全解決です。ありがとうございました。