C# と VB.NET の質問掲示板

コントロールの生成処理をメソッドに分割するなどはどうでしょうか。

例えば、このようなメソッドを作成して

Private Function MakeControl(type As Integer) As Control
    Select Case type
        Case 0
            Return New TextBox()
        Case 1
            Return New ComboBox()
        Case 2
            Return New CheckBox()
    End Select
    Return Nothing
End Function

使う時はこんな感じで

'TextBox作成
Dim c1 As Control = MakeControl(0)
Me.Controls.Add(c1)

'ComboBox作成()
Dim c2 As Control = MakeControl(1)
Me.Controls.Add(c2)

'CheckBox作成()
Dim c3 As Control = MakeControl(2)
Me.Controls.Add(c3)

■No68174 (海犬 さん) に返信
> と書いていますが、上記のTextbox部分を動的に変更するにはどのようにすればよいのでしょうか？

何のためにでしょうか?

.designer.vb 相当のコードを自動生成するためのツールと言う意味であれば、CodeDOM を使う手があります。

Imports System
Imports System.IO
Imports System.CodeDom

Public Class Form1
    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Dim var As New CodeVariableDeclarationStatement(GetType(TextBox), "ctrl",
            New CodeObjectCreateExpression(New CodeTypeReference(GetType(TextBox))))

        Using sw As New StringWriter()
            'Dim cp As New Microsoft.CSharp.CSharpCodeProvider()
            Dim cp As New Microsoft.VisualBasic.VBCodeProvider()
            cp.GenerateCodeFromStatement(var, sw, Nothing)

            sw.Flush()
            TextBox1.Text = sw.ToString()
        End Using
    End Sub
End Class


あるいは、実行時に動的生成することが目的の場合は、変数を As Control 等で受けるようにしておき、
Activator.CreateInstance で生成するとか。


Public Class Form1
    Private x As Control

    Private Sub Form1_Load(sender As Object, e As System.EventArgs) Handles Me.Load
        ComboBox1.Items.Add("System.Windows.Forms.TextBox")
        ComboBox1.Items.Add("System.Windows.Forms.Button")
        ComboBox1.Items.Add("System.Windows.Forms.CheckBox")
        ComboBox1.DropDownStyle = ComboBoxStyle.DropDownList
        ComboBox1.SelectedIndex = 0
    End Sub

    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        If x IsNot Nothing Then
            Controls.Remove(x)
            x.Dispose()
        End If

        Dim typeName As String = CStr(ComboBox1.SelectedItem)
        Dim t As Type = GetType(Control).Assembly.GetType(typeName, True)
        x = DirectCast(Activator.CreateInstance(t), Control)

        x.Text = "Sample"
        x.Visible = True
        x.Location = New Point(30, 30)
        Controls.Add(x)
    End Sub

End Class

■No68176 (魔界の仮面弁士 さん) に返信
> あるいは、実行時に動的生成することが目的の場合は、変数を As Control 等で受けるようにしておき、
> Activator.CreateInstance で生成するとか。

別案。やっていることは同じですが。


Public Class Form1
    Private x As Control

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles Me.Load
        ComboBox1.DataSource = New Type() {GetType(TextBox), GetType(Button), GetType(CheckBox), GetType(RadioButton), GetType(Form)}
        ComboBox1.DisplayMember = "Name"
        ComboBox1.DropDownStyle = ComboBoxStyle.DropDownList
    End Sub

    Private Sub ComboBox1_SelectedIndexChanged(sender As Object, e As EventArgs) Handles ComboBox1.SelectedIndexChanged
        If x IsNot Nothing Then
            Controls.Remove(x)
            x.Dispose()
        End If

        Dim t As Type = CType(ComboBox1.SelectedItem, Type)
        x = DirectCast(t.GetConstructor(Type.EmptyTypes).Invoke(Nothing), Control)
        If TypeOf x Is Form Then DirectCast(x, Form).TopLevel = False

        x.Text = "Sample"
        x.Location = New Point(30, 30)
        Controls.Add(x)
        x.Visible = True
    End Sub
End Class