C# と VB.NET の質問掲示板

■No68365 (みや さん) に返信
> CSVの情報を読み込んで処理したいのですが、その際、値を囲むダブルクォーテーションごとデータを取得したい。

TextFieldParser に、そういった機能は無いと思います。


以下、手抜き実装。「改行を含んだデータ」は考慮していません。


Public Class Form1
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim rows = System.IO.File.ReadLines("C:\temp\test.csv", System.Text.Encoding.GetEncoding("Shift_JIS"))

        'XML に変換
        Dim data = <sample><%= From row In rows Select
                            <csv>
                                <%= Miya68365(row).Select(Function(f, i) <<%= "F" & CStr(i) %>><%= f %></>) %>
                            </csv>
                           %>
                   </sample>

        'XML を DataSet に変換
        Dim ds As New DataSet()
        Using r = data.CreateReader()
            ds.ReadXml(r)
            r.Close()
        End Using

        'DataGridView に表示
        DataGridView1.DataSource = ds.Tables("csv")
    End Sub



    '行の解析処理(手抜き)
    Public Iterator Function Miya68365(ByVal line As String) As IEnumerable(Of String)
        Dim col As New System.Text.StringBuilder()
        col.Clear()
        Dim quot As Boolean = False
        For Each c As Char In line
            If c = ","c Then
                If quot Then
                    col.Append(c)
                Else
                    Yield col.ToString()
                    col.Clear()
                End If
            ElseIf c = """"c Then
                col.Append(c)
                quot = Not quot
            Else
                col.Append(c)
            End If
        Next
        If quot Then
            Throw New ArgumentOutOfRangeException("line", line, "ダブルクォーテーションが閉じられていません。")
        Else
            Yield col.ToString()
        End If
    End Function

End Class