C# と VB.NET の質問掲示板

■No75068 (ガッキー さん) に返信

> 　　　　�@入力した文字列をHEX、ASC�Uコードに変換し、配列の中に代入する。

この部分が少し違うかもしれません。
送信コマンドの仕様として

1バイト目 02H
2バイト目 30H "0" 
3バイト目 30H "0" 2バイト目と3バイト目を合わせて Node No.
4バイト目 30H "0" 
5バイト目 30H "0" 4バイト目と5バイト目を合わせて Sub Address
6バイト目 30H "0" SID

という感じになるのだと思われます。
（コマンドで Google 検索をしたらそれらしき機器の説明書が見つかりました）
なので Node No. を代入している部分

>         '--- Node No(00〜31番)
>         NodeNo = "00"
> 
>         '--- サブアドレス
>         SubAdd = "00"
>         byttmp(2) = Asc(SubAdd)
>         byttmp(1) = Asc(NodeNo)

は、このような感じになるかと思います。

>         '--- Node No(00〜31番)
>         NodeNo = "00"
> 
>         '--- サブアドレス
>         SubAdd = "00"
>         byttmp(1) = CByte(Asc(NodeNo.SubString(0,1)))
>         byttmp(2) = CByte(Asc(NodeNo.SubString(1,1)))
>         byttmp(3) = CByte(Asc(SubAdd.SubString(0,1)))
>         byttmp(4) = CByte(Asc(SubAdd.SubString(1,1)))

以下 byttmp のサイズもそれに合わせて大きくなると思います。
この場合は

>         Dim byttmp As List(Of Byte())

のように宣言して

>         '--- Node No(00〜31番)
>         NodeNo = "00"
> 
>         '--- サブアドレス
>         SubAdd = "00"
>         byttmp.Add(CByte(Asc(NodeNo.SubString(0,1))))
>         byttmp.Add(CByte(Asc(NodeNo.SubString(1,1))))
>         byttmp.Add(CByte(Asc(SubAdd.SubString(0,1))))
>         byttmp.Add(CByte(Asc(SubAdd.SubString(1,1))))
（中略）
>         'シリアルポートからデータを送信する.
>         SerialPort1.Write(byttmp.ToArray(), 0, byttmp.Count)

と書いたほうがいいかもしれませんね。

■No75070 (ぽぴ王子 さん) に返信
> ■No75069 (ぽぴ王子 さん) に返信
> 
> ちなみにVBのコードはうろ覚えで書いたので、間違っているかもしれません。
> その場合はゴメンナサイ。

　お返事遅くなりました。ご回答ありがとうございます。
　非常にわかりやすくて参考になりました。
　
　もう一点、疑問があるのですが、�Aの可変番号なのですが、
　�Aはデザイン画面でコンボボックスを配置し、コンボボックス内から値を選択(00〜31)番して、
　　その値をbyttmpに代入する(ご教示頂いた内容で)
>　　2バイト目 30H "0" 
>　　3バイト目 30H "0" 2バイト目と3バイト目を合わせて Node No.
　　考えなのですが、コードとデザインの関連がよくわからない状態です。
　　
　　今あるコードを載せてみますので、わかり難いかもしれませんが、ご指摘等頂けないでしょうか。

　◆デザイン側
　　トップダウンメニューのNameをcmbNodeNoに変更
　
  ◆コード側
　　'---NodeNo格納用のクラス定義.
　　Private Class NodeNoItem
        Inherits Object

        Private m_name As String = ""
        Private m_value As Integer = 0

        '表示名称
        Public Property NAME() As String
            Set(ByVal value As String)
                m_name = value
            End Set
            Get
                Return m_name
            End Get
        End Property

        'NodeNo設定値.
        Public Property NodeNo() As Integer
            Set(ByVal value As Integer)
                m_value = value
            End Set
            Get
                Return m_value
            End Get
        End Property

        'コンボボックス表示用の文字列取得関数.
        Public Overrides Function ToString() As String
            Return m_name
        End Function

    End Class

　　Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
　　　'ノードNo選択コンボボックスに選択項目をセットする.
        Dim Node As NodeNoItem

        Node = New NodeNoItem
        Node.NAME = "00"
        cmbNodeNo.Items.Add(Node)
        cmbNodeNo.SelectedIndex = 0

        Node = New NodeNoItem
        Node.NAME = "01"
        cmbNodeNo.Items.Add(Node)
        cmbNodeNo.SelectedIndex = 1
　　End Sub
　　
　　'---データ送信を行う処理
　　Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
　　　　'シリアルポートをオープンしていない場合、処理を行わない.
        If SerialPort1.IsOpen = False Then
            Return
        End If

　　　　Dim byttmp(24) As Byte
        Dim NodeNo As String
　　　　
　　　　'--- Node No(00〜31番)
        NodeNo = Node.NAME
        byttmp(1) = (CByte(Asc(NodeNo.Substring(0, 1))))

　　以上、よろしくお願いいたします。
　

■No75071 (ガッキー さん) に返信
> 　もう一点、疑問があるのですが、�Aの可変番号なのですが、
> 　�Aはデザイン画面でコンボボックスを配置し、コンボボックス内から値を選択(00〜31)番して、
> 　　その値をbyttmpに代入する(ご教示頂いた内容で)
> >　　2バイト目 30H "0" 
> >　　3バイト目 30H "0" 2バイト目と3バイト目を合わせて Node No.
> 　　考えなのですが、コードとデザインの関連がよくわからない状態です。
> 　　
> 　　今あるコードを載せてみますので、わかり難いかもしれませんが、ご指摘等頂けないでしょうか。

コードを読ませていただきました。問題の部分というか、わかっていない部分はこのあたりでしょうか。

>         '--- Node No(00〜31番)
>         NodeNo = Node.NAME
>         byttmp(1) = (CByte(Asc(NodeNo.Substring(0, 1))))

追いかけるのが大変になるので、とりあえずは対象の部分だけあればいいかもしれません。

まず byttmp(1) は Byte 型の一項目というのはわかりますよね。
その中には Byte 型、つまり 1 バイト分しか入りません。
MSDN で Asc を調べていただくとわかりますが Asc("00") では 1 文字目の "0" のアスキーコードしか取得できません。
なので 1 文字目のアスキーコードと 2 文字目のアスキーコードをそれぞれ別に求めて byttmp には 2 つの項目として
設定する必要があります。


>         byttmp(1) = CByte(Asc(NodeNo.Substring(0, 1)))
>         byttmp(2) = CByte(Asc(NodeNo.Substring(1, 1)))

前に書いたこのコードは NodeNo.Substring(0, 1) で先頭の文字 1 文字（ 1 番目の引数は開始文字位置なので 0 から始まります）を
取得して、そのアスキーコードを求めて、そのアスキーコードを CByte で Byte 型に変換しています。
（Integer から Byte へは暗黙のキャストがあるはずなので必要ないかもしれませんが、念のため）

2 行目は同様に NodeNo.Substring(1, 1) で 2 文字目の 1 文字を取得し、そのアスキーコードを求めています。

> >　　2バイト目 30H "0" 
> >　　3バイト目 30H "0" 2バイト目と3バイト目を合わせて Node No.

これは NodeNo が "00" という値として仮定して書いているのでちょっとわかりにくいですが "31" という値が入っていた
とするならば、 1 文字ずつのアスキーコードが入るので、こういった感じになります。

> >　　2バイト目 33H "3" 
> >　　3バイト目 31H "1" 2バイト目と3バイト目を合わせて Node No.

こんな感じの説明で大丈夫でしょうか。

■No75068 (ガッキー さん) に返信
> 　　　送信コマンドの仕様ですが

こういうことで良いのかな…。

Dim STX() As Byte = {&H2}       '02H固定
Dim NodeNo As String = "01"     'ASCII 2桁 "00"〜"31"
Dim SubAdd As String = "00"     'ASCII 2桁 "00" 固定
Dim SID As String = "0"         'ASCII 1桁 "0" 固定
Dim MRC As String = "01"        'ASCII 2桁 "01" 固定
Dim SRC As String = "01"        'ASCII 2桁 "01" 固定
Dim Var As String = "40"        'ASCII 2桁 "40" or "C2"
Dim ReadStAd As String = "0000" 'ASCII 4桁 "0000" 固定
Dim Bit As String = "00"        'ASCII 2桁 "00" 固定
Dim Ele As String = "000B"      'ASCII 4桁 "0001" or "000B"
Dim BCC As Byte

Dim sendText As String = NodeNo & SubAdd & SID & MRC & SRC & Var & ReadStAd & Bit & Ele
Dim sendBinary() As Byte = System.Text.Encoding.ASCII.GetBytes(sendText)

BCC = 0
Array.ForEach(sendBinary, Sub(b) BCC = BCC Xor b)

Dim buffer() As Byte = STX.Concat(sendBinary).Concat({BCC}).ToArray()

'この時点で、buffer.Length は 23 を返す。bufferは0〜22。
SerialPort1.Write(buffer, 0, buffer.Length)

■No75071 (ガッキー さん) に返信
> 　　Private Class NodeNoItem
>         Inherits Object
Inherits Object は冗長かと思いますよ。

ところで、NAME はすべて大文字で、NodeNo はパスカルケース記法なのは
意図的にそうされているのでしょうか。


>         Private m_value As Integer = 0
>         Public Property NodeNo() As Integer
提示範囲では、これらが使われている様子が無いので、
ComboBox には .Items.Add("00") などとして、
文字列を直接渡すだけで済むようにも見えます。


>         cmbNodeNo.SelectedIndex = 0
> 
>         cmbNodeNo.SelectedIndex = 1
最後の SelectedIndex で上書きされているので、前者の 0 代入は無意味かと。
cmbNodeNo.SelectedIndex ではなく、Node.NodeNo





>         Node = New NodeNoItem
>         Node.NAME = "00"
>         cmbNodeNo.Items.Add(Node)
管理する値が 2 つ(NodeNo As Integer と NAME As String)だけなのであれば、
KeyValuePair(Of Integer, String) を使うこともできます。


Public Class Form1

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Dim node As New Dictionary(Of Integer, String)()

        '第一引数が、NodeItem.NodeNo に相当(重複不可)。
        '第二引数が、NodeItem.NAME および ToString に相当。
        node.Add( 0, "00")
        node.Add( 1, "01")
        node.Add(31, "31")

        ComboBox1.DataSource = node.ToArray()
        ComboBox1.ValueMember = "Key"
        ComboBox1.DisplayMember = "Value"

        '末尾項目を選択
        ComboBox1.SelectedIndex = node.Count - 1
    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        If ComboBox1.SelectedIndex <> -1 Then
            'Dim NAME As String = ComboBox1.GetItemText(ComboBox1.SelectedItem)

            Dim item = DirectCast(ComboBox1.SelectedItem, KeyValuePair(Of Integer, String))
            Dim NAME As String    = item.Value
            Dim NodeNo As Integer = item.Key

            '
            '
        End If
    End Sub
End Class

お世話になります。

書き込んで頂いた内容を整理しまして、以下のようなコードに修正しました。
また、確認中に出た疑問なのですが
下記のコードで、送信を行うと★部分の箇所で

 「インデックスが範囲を超えています。負でない値で、コレクションのサイズよりも小さくなければなりません。
　パラメータ名: index」

というエラーがbyttmp(i)の箇所で吐き出されます。For文を消してBCC = BCC Xor byttmp(0)にすると吐き出されないのですが、これの出現する原因と対処方法を教えて頂けないでしょうか。


Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

        Dim byttmp As New List(Of Byte)
        Dim NodeNo As String
        Dim SubAdd As String = "00"
        Dim SID As String = "0"
        Dim MRC As String = "01"
        Dim SRC As String = "01"
        Dim Var As String = "40"
        Dim ReadStAd As String = "0000"
        Dim Bit As String = "00"
        Dim Ele As String = "0001"
        Dim BCC As Byte

        '--- STX
        byttmp.Add(2)

        '--- Node No(00〜31番)
        NodeNo = ComboBox1.Text          '---コンボボックスから値を取得
        byttmp.Add(CByte(Asc(NodeNo(0))))
        byttmp.Add(CByte(Asc(NodeNo(1))))

        '--- サブアドレス
        byttmp.Add(CByte(Asc(SubAdd(0))))
        byttmp.Add(CByte(Asc(SubAdd(1))))

        '--- SID
        byttmp.Add(CByte(Asc(SID(0))))

        '--- MRC
        byttmp.Add(CByte(Asc(MRC(0))))
        byttmp.Add(CByte(Asc(MRC(1))))

        '--- SRC
        byttmp.Add(CByte(Asc(SRC(0))))
        byttmp.Add(CByte(Asc(SRC(1))))

        '--- Var
        byttmp.Add(CByte(Asc(Var(0))))
        byttmp.Add(CByte(Asc(Var(1))))

        '--- ReadStAd
        byttmp.Add(CByte(Asc(ReadStAd(0))))
        byttmp.Add(CByte(Asc(ReadStAd(1))))
        byttmp.Add(CByte(Asc(ReadStAd(2))))
        byttmp.Add(CByte(Asc(ReadStAd(3))))

        '--- Bit
        byttmp.Add(CByte(Asc(Bit(0))))
        byttmp.Add(CByte(Asc(Bit(1))))

        '--- Ele
        byttmp.Add(CByte(Asc(Ele(0))))
        byttmp.Add(CByte(Asc(Ele(1))))
        byttmp.Add(CByte(Asc(Ele(2))))
        byttmp.Add(CByte(Asc(Ele(3))))

        '--- EXT
        byttmp.Add(3)

        '--- BCC
        Dim i As Integer = 0
        BCC = 0
        For i = 0 To byttmp.Count
★            BCC = BCC Xor byttmp(i)
        Next

        byttmp.Add(BCC)


        'シリアルポートをオープンしていない場合、処理を行わない.
        If SerialPort1.IsOpen = False Then
            Return
        End If

        'シリアルポートからデータを送信する.
        SerialPort1.Write(byttmp.ToArray(), 0, byttmp.Count)

    End Sub

■No75113 (ガッキー さん) に返信

shu さんがフォローしてくださっていますが、 byttmp の Count は要素数より 1 少なくなります。
例えば 10 要素が追加されていた場合は、 Count プロパティは 9 になります。

なので、修正するとしたらこんな感じです。

        For i = 0 To byttmp.Count - 1
            BCC = BCC Xor byttmp(i)
        Next

あるいは For Each を使用してこんな感じとか。要素数を気にしなくていいので楽です。

        For Each b As Byte In byttmp
            BCC = BCC Xor b
        Next

ただ、 No.75079 で弁士さんが的確なフォローをしてくださっているので、それを応用するならば

        byttmp.ForEach(Sub(b) BCC = BCC Xor b)

こんな感じで書けそうな気がします。 VB は最近全然書いてないのでうろ覚えですが。