C# と VB.NET の質問掲示板

はじめまして、VB(.NET)について質問させていただきます

今現在、VBでTreeViewを用いてＤＢ上での受注管理をしやすくするようなものを作っています。 

しかし、TreeViewを読み込むところで、
TreeViewが階層構造にならず下に１つしか出ないようになってしまいます

◎
 |--XXX
 |--OOO

現在↑のようになってしまい、実際はこのような感じにしたいと思っております
◎
 |--XXX
 |　 |_yyy
 | 　　　|_zzz
 | 　　　　　|_ddd
 |
 |-OOO

このようにするためには、どのようにプログラムを直したらよろしいでしょうか？


 回答よろしくお願いします


********##コード##**************
Private Sub TreeViewLoad()

        Dim contorol As New Contoroller
        Dim orderlist As ArrayList = contorol.GetOrderList
       
        Me.TreeView.Nodes.Clear()

        Dim rootNode As TreeNode
        rootNode = New TreeNode()
        rootNode.Text = " 受注リスト "
        TreeView.Nodes.Add(rootNode)

        Dim prod As ProductClass
        Dim proc As ProcessClass
        Dim parts As PartsClass
        Dim order As OrderClass

        For Each order In orderlist

            Dim i As Integer = 0
            Dim j As Integer = 0
            Dim q As Integer = 0

            Dim myTreeNodeArray(order.ProductList.Count - 1) As TreeNode


            For Each prod In order.ProductList

                Dim mytreeNodeArrayProcess(prod.ProcessList.Count - 1) As TreeNode 
                myTreeNodeArray(i) = New TreeNode("プロダクト名 :" + prod.ProductName)
          
                For Each proc In prod.ProcessList

                    Dim mytreeNodeArrayParts(proc.PartsList.Count - 1) As TreeNode


                    mytreeNodeArrayProcess(j) = New TreeNode("プロセス名 :" + proc.ProcessName)

                    For Each parts In proc.PartsList

                        mytreeNodeArrayParts(q) = New TreeNode("部品名 :" + parts.PartsName)

                           mytreeNodeArrayParts(q).Tag = parts

                        q += 1
                    Next parts
                    j += 1
                Next proc
                i += 1
            Next prod
            Dim orderNode As New TreeNode("受注先 :" + order.OrderName, myTreeNodeArray)
            orderNode.ForeColor = Color.Red
            Me.TreeView.Nodes(0).Nodes.Add(orderNode)


        Next order
        With Me.TreeView
            .ExpandAll()
            .ForeColor = Color.Navy
            .BackColor = Color.Azure
            .LineColor = Color.Red
            .ContextMenuStrip = Me.ContextMenuStrip1
        End With
    End Sub

■No78182 (魔界の仮面弁士) に追記
>> こちらは受注管理クラスを持ち合わせていないので、
>> 動作未検証のイメージコードですけれども。
> # あ…。受注先ノードが漏れてた。

掲示板が復活したようなので、検証用のダミーデータ付きで再掲。
受注管理クラスは XML で代用しています。


Public Class Form1
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        TreeViewLoad(Me.TreeView1)
    End Sub

    Private Sub TreeViewLoad(tv As TreeView)
        tv.Nodes.Clear()

        Dim orderList = GetOrderList().Root.Elements

        Dim rootNode As TreeNode = tv.Nodes.Add(" 受注リスト ")
        For Each order In orderList
            Dim orderNode As TreeNode = rootNode.Nodes.Add("受注先 :" & order.@OrderName)
            For Each prod In order.<ProductList>
                Dim productNode As TreeNode = orderNode.Nodes.Add("プロダクト名 :" & prod.@ProductName)
                For Each proc In prod.<ProcessList>
                    Dim processNode As TreeNode = productNode.Nodes.Add("プロセス名 :" & proc.@ProcessName)
                    For Each parts In proc.<PartsList>
                        Dim partsNode As TreeNode = processNode.Nodes.Add("部品名 :" & parts.@PartsName)
                        partsNode.Tag = parts
                    Next parts
                Next proc
            Next prod
            orderNode.ForeColor = Color.Red
        Next order

        tv.ExpandAll()
        tv.ForeColor = Color.Navy
        tv.BackColor = Color.Azure
        tv.LineColor = Color.Red
        tv.ContextMenuStrip = Me.ContextMenuStrip1
    End Sub


    Private Function GetOrderList() As XDocument
        Return <?xml version="1.0"?>
               <受注リスト>
                   <OrderList OrderName="Developer Tools">
                       <ProductList ProductName="Visual Studio">
                           <ProcessList ProcessName="Boston">
                               <PartsList PartsName="Visual Basic 5.0"/>
                               <PartsList PartsName="Visual C++ 5.0"/>
                               <PartsList PartsName="Visual J++ 1.1"/>
                               <PartsList PartsName="Visual InterDev 1.0"/>
                               <PartsList PartsName="Visual SourceSafe 5.0"/>
                           </ProcessList>
                           <ProcessList ProcessName="Aspen">
                               <PartsList PartsName="Visual Basic 6.0"/>
                               <PartsList PartsName="Visual C++ 6.0"/>
                               <PartsList PartsName="Visual J++ 6.0"/>
                               <PartsList PartsName="Visual InterDev 6.0"/>
                               <PartsList PartsName="Visual Studio Installer 1.1"/>
                               <PartsList PartsName="Visual SourceSafe 6.0"/>
                           </ProcessList>
                       </ProductList>
                   </OrderList>
                   <OrderList OrderName="Operating Systems">
                       <ProductList ProductName="Release">
                           <ProcessList ProcessName="9x">
                               <PartsList PartsName="Chicago"/>
                               <PartsList PartsName="Detroit"/>
                               <PartsList PartsName="Nashville"/>
                               <PartsList PartsName="Memphis"/>
                               <PartsList PartsName="Millennium"/>
                           </ProcessList>
                           <ProcessList ProcessName="NT">
                               <PartsList PartsName="Razzle"/>
                               <PartsList PartsName="Daytona"/>
                               <PartsList PartsName="Cairo"/>
                               <PartsList PartsName="Janus"/>
                               <PartsList PartsName="Whistler"/>
                               <PartsList PartsName="Freestyle"/>
                               <PartsList PartsName="Harmony"/>
                               <PartsList PartsName="Symphony"/>
                               <PartsList PartsName="Emerald"/>
                           </ProcessList>
                       </ProductList>
                       <ProductList ProductName="Dropped">
                           <ProcessList ProcessName="9x">
                               <PartsList PartsName="Nashville"/>
                           </ProcessList>
                           <ProcessList ProcessName="NT">
                               <PartsList PartsName="Neptune"/>
                               <PartsList PartsName="Odyssey"/>
                           </ProcessList>
                       </ProductList>
                   </OrderList>
               </受注リスト>
    End Function

End Class