C# と VB.NET の質問掲示板

（VB2013使用）
正規表現を使用した置換で、以下のようにMatchEvaluatorを使う方法があります。

'例
Regex.Replace(txt, ptn, AddressOf ReplText)

'MatchEvaluator用メソッド
Private Function ReplText(ByVal m As Match) As String
    'マッチの結果に応じて置換文字列を返す
    Return ret   '←処理の結果
End Function


最初はこの概念が中々理解できなかったのですが、結構便利だし、
よく使うようになりました。

ただ、ここでまた壁にぶつかってしまいました。
MatchEvaluator用メソッドに渡したい変数が出てきました。
この変数の内容により処理を分岐させたいのです。
例えば以下のようなことをやりたいのです。

Private Function ReplText(ByVal m As Match, ByVal idx As Integer) As String
    If m.Index > idx Then
        '処理１
        Return ret1
    Else
        '処理２
        Return ret2
    End If
End Function

デリゲートという概念を十分に理解できていないことが問題だと思いますが、
MatchEvaluatorに別引数を渡す方法はあるのでしょうか？

デリゲートの概念というよりもうちょっと外側の方の話になりそうですが。

置換式が別関数化するほど複雑でないのなら、ラムダ式を使うことで解決できます。
ラムダ式内では、式外の変数を「キャプチャ」して使うことができます。

Dim idx As Integer = 1
' mの型はRegex.Replaceの定義から推論してくれるので省略
Regex.Replace(text, exp, Function (m)
    If idx < 0 Then
        Return "-" & m.Value
    Else
        Return "+" & m.Value
    End If
End Function)

置換式を関数化しておきたいのなら、クラス化する必要があるでしょう。
Class IndexReplacer
    Public Sub New(idx As Integer)
        _idx = idx
    End Sub
    Private _idx As Integer
    Public Function Match(m As Match) As String
        If _idx < 0 Then
            Return "-" & m.Value
        Else
            Return "+" & m.Value
        End If
    End Function
End Class

' 使う時はこんな感じ
Dim replaced As String = Regex.Replace(text, exp, AddressOf New IndexReplacer(4).Match)