C# と VB.NET の質問掲示板

VB.NETに関する質問です。

TableLayoutPanelの中に画像を表示したPictureBoxが入っています。
ウインドウサイズを変えた時に、アスペクト比を変えずに
PictureBoxサイズをTableLayoutPanelのサイズにフィットさせたいと考えています。



    'フォームのサイズを変更したときに、PictureBoxサイズが追随して変更するようにする
    Public Sub Form1_SizeChanged() Handles MyBase.SizeChanged

        Call SetPictureBox()

    End Sub


    Private Sub SetPictureBox()

        Dim TL As Size

        TL.Height = frm.TableLayoutPanel9.GetRowHeights(1) - PBox.Margin.Size.Height
        TL.Width = frm.TableLayoutPanel9.GetColumnWidths(0) - PBox.Margin.Size.Width


        Dim SetSize As Size

        Dim BoundaryWidth As Integer = PictureBox1.Width - PictureBox1.ClientSize.Width

        If TL.Height / TL.Width > 1 Then

            SetSize.Width = TL.Width
            SetSize.Height = CInt((SetSize.Width - BoundaryWidth) * ImageAspect) + BoundaryWidth

        Else

            SetSize.Height = TL.Height
            SetSize.Width = CInt((SetSize.Height - BoundaryWidth) / ImageAspect) + BoundaryWidth

        End If


        PictureBox1.Size = SetSize

        PictureBox1.Invalidate()


    End Sub


こんな感じのコードでフィットさせることはできているのですが、
ウインドウサイズを変えた時に
TableLayoutPanelのサイズ変化してから少し遅れてから、
PictureBoxの中身のサイズも変化するため、少しぎこちない感じがします。

これらを同時に更新したいのですが
どのようにすれば良いですか？

Me.SuspendLayout()
Me.ResumeLayout()

の辺りを試してみたのですが
うまくいきませんでした。

どのようなコードなら良いでしょうか？

■No96331 (紐 さん) に返信
> TableLayoutPanelの中に画像を表示したPictureBoxが入っています。
> ウインドウサイズを変えた時に、アスペクト比を変えずに
> PictureBoxサイズをTableLayoutPanelのサイズにフィットさせたいと考えています。

TableLayoutPanel を使うときは、位置や大きさを Dock や Anchor に任せたほうが楽かと思います。
自分だったら表示するためのカスタムコントロールを作り、Dock = DockStyle.Fill にして配置します。
下のコードは、画像のアスペクト比を保ったまま表示するカスタムコントロールの例です。

Public Class KeepAspecctPictureBox
    Inherits PictureBox

    Public Sub New()
        SetStyle(ControlStyles.AllPaintingInWmPaint, True)
        SetStyle(ControlStyles.ResizeRedraw, True)
    End Sub

    Protected Overrides Sub OnPaint(pe As PaintEventArgs)
        Using b As New SolidBrush(BackColor)
            pe.Graphics.FillRectangle(b, ClientRectangle)
        End Using
        If Image Is Nothing Then
            Return
        End If
        Dim cs As Size = ClientSize
        Dim imageSize As Size = Image.Size
        Dim drawWidth As Integer
        Dim drawHeight As Integer
        'If cs.Width / cs.Height > imageSize.Width / imageSize.Height Then
        If cs.Width * imageSize.Height > imageSize.Width * cs.Height Then
            drawHeight = cs.Height
            drawWidth = CInt(cs.Height * imageSize.Width / imageSize.Height)
        Else
            drawWidth = cs.Width
            drawHeight = CInt(cs.Width * imageSize.Height / imageSize.Width)
        End If
        pe.Graphics.DrawImage(Me.Image, New Rectangle(0, 0, drawWidth, drawHeight))
    End Sub

End Class