C# と VB.NET の質問掲示板

■No97310 (魔界の仮面弁士) に追記
> WinForms とかであれば、felicalib Remodeled や felicalib を使うことができますし、

実装例。
AnyCPU/x86/x64 のいずれでも動作することを確認しています。


'参照設定：FelicaLib.DotNet.dll
'https://github.com/sakapon/felicalib-remodeled
Imports FelicaLib
Module Module1
    Function Main() As Integer
        Console.WriteLine("Is64BitProcess=" & Environment.Is64BitProcess)
        Do
            'FE00: FeliCa Networks Common Area (Waon/Edy/nanaco など)
            Using felica As New Felica(&HFE00)
                If felica.TryConnectionToPort() AndAlso felica.TryConnectionToCard() Then
                    '8 バイトの IDm (製造者コード 2 バイト + カード識別番号 6 バイト)
                    Console.WriteLine("共通領域のIDm:" & felica.GetIDm().ToHexString())
                    '8 バイトの PMm (ROM 種別 1 バイト + IC 種別 1 バイト + 最大応答時間パラメータ 6 バイト)
                    Console.WriteLine("共通領域のPMm:" & felica.GetPMm().ToHexString())
                    Try
                        'nanaco番号: サービスコード 0x558B の 先頭 8 バイト (BCD)
                        Console.WriteLine("nanaco番号:" & felica.ReadWithoutEncryption(&H558B, 0).Take(8).ToArray().ToHexString())
                    Catch
                    End Try
                End If
            End Using

            '0003: Cybernetics (Suica/ICOCA/PiTaPa/PASMO/TOICA など)
            Using felica As New Felica(&H3)
                If felica.TryConnectionToPort() AndAlso felica.TryConnectionToCard() Then
                    Console.WriteLine("SuicaのIDm:" & felica.GetIDm().ToHexString())
                    Console.WriteLine("SuicaのPMm:" & felica.GetPMm().ToHexString())
                End If
            End Using

            '04C1: QUICPay
            Using felica As New Felica(&H4C1)
                If felica.TryConnectionToPort() AndAlso felica.TryConnectionToCard() Then
                    Console.WriteLine("QUICPayのIDm:" & felica.GetIDm().ToHexString())
                    Console.WriteLine("QUICPayのPMm:" & felica.GetPMm().ToHexString())
                    Try
                        'QUICPay ID: サービスコード 100B の 10 バイト (16 進数)
                        Console.WriteLine("QUICPay ID:" & felica.ReadWithoutEncryption(&H100B, 0).ToHexString())
                    Catch
                    End Try
                End If
            End Using


            Console.ForegroundColor = ConsoleColor.Green
            Console.WriteLine("Escape=終了/Enter=再読み込み")
            Console.ResetColor()
        Loop Until Console.ReadKey().Key = ConsoleKey.Escape
        Return 0
    End Function
End Module


実行には、32bit / 64bit いずれかの PaSoRi ドライバーがインストールされている必要があります。
"C:\Program Files (x86)\Common Files\Sony Shared\FeliCaLibrary\felica.dll"
"C:\Program Files\Common Files\Sony Shared\FeliCaLibrary\felica.dll"

上記の FelicaLib.DotNet.dll は、
32bit モードでは felicalib.dll 経由で 32bit 版の felica.dll をロードし、
64bit モードでは felicalib64.dll 経由で 64bit 版の felica.dll をロードする設計に
なっているため、EXE と同じフォルダーまたは PATH の通った場所に、
32bit/64bit いずれの felicalib*.dll が配置しておく必要があります。