C# と VB.NET の質問掲示板

お尋ねします。
メインフォームForm1から別スレッドで経過表示用フォームForm2をShowDialog表示する下記のコードで、
書き込み処理中にForm2のクローズボックスをクリックすると、Invokeのところで凍りついてしまいます。
どこに問題があるのでしょうか。
開発環境・使用言語はVB2003/Framework1.1です。

'/*** Form1 (メインフォーム) ***/
Public Class Form1 : Inherits System.Windows.Forms.Form
    '// Friend WithEvents Button1 As System.Windows.Forms.Button
    '// Friend WithEvents Button2 As System.Windows.Forms.Button
    Private fm2 As Form2

    '// Button1.Click : Form2を別スレッドで開く
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        If fm2 Is Nothing Then
            Dim t As New System.Threading.Thread(AddressOf Me.ShowForm2)
            t.Start()
        End If
    End Sub

    '// Form2を開くためのプロシージャ
    Private Sub ShowForm2()
        fm2 = New Form2
        fm2.ShowDialog()
        fm2.Dispose()
        fm2 = Nothing
    End Sub

    '// Button2.Click : 経過記録を表示しながら行う繰り返し処理
    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        Me.Button2.Enabled = False
        For i As Integer = 1 To 1000
            Me.WriteLine(i.ToString() & "巡目です。")
        Next
        Me.Button2.Enabled = True
    End Sub

    '// Form2に１行表示
    Private Sub WriteLine(ByVal text As String)
        If fm2 Is Nothing Then Return
        Try
            fm2.WriteLine(text)
        Catch ex As System.ObjectDisposedException
        End Try
    End Sub
End Class

'/*** Form2 (経過表示用フォーム) ***/
Public Class Form2 : Inherits System.Windows.Forms.Form
    '// Friend WithEvents RichTextBox1 As System.Windows.Forms.RichTextBox 
    Private Delegate Sub WriteLineDelegate(ByVal text As String)
    Private dlgt As New WriteLineDelegate(AddressOf Me.WriteLine)

    '// リッチテキストボックスに文字を追記表示する
    Public Sub WriteLine(ByVal text As String)
        If Me.IsDisposed OrElse Not Me.IsHandleCreated Then Return
        If Me.InvokeRequired Then
            Me.Invoke(dlgt, New Object() {text})    '// ここで凍りつく
        Else
            With Me.RichTextBox1
                .AppendText(text & vbCrLf)
                .ScrollToCaret()
                .Focus()
            End With
        End If
    End Sub
End Class


なお、Form1.ShowForm2の fm2.Dispose() : fm2 = Nothing を外しても状況は変わりませんでした。

■No6772 (まどか さん) に返信

アドバイスありがとうございます。

Form1側のWriteLineを

'/*** Form1 (メインフォーム) ***/

    Private Delegate Sub WriteLineDelegate(ByVal text As String)
    Private dlgt As New WriteLineDelegate(AddressOf Me.WriteLine)

    '// Form2に１行表示
    Private Sub WriteLine(ByVal text As String)
        If fm2 Is Nothing Then Return
        If fm2.IsDisposed OrElse Not fm2.IsHandleCreated Then Return
        Try
            If fm2.InvokeRequired Then
                fm2.Invoke(dlgt, New Object() {text})   '// ここで凍りつく
            Else
                fm2.WriteLine(text)
            End If
        Catch
        End Try
    End Sub

と改め、かつForm2側のWriteLineを

'/*** Form2 (経過表示用フォーム) ***/

    '// リッチテキストボックスに文字を追記表示する
    Public Sub WriteLine(ByVal text As String)
        With Me.RichTextBox1
            .AppendText(text & vbCrLf)
            .ScrollToCaret()
            .Focus()
        End With
    End Sub

としたコードでも、If分岐が移っただけなので、やはり fm2.Invoke のところで凍りついてしまいます。
ご指摘いただいた意図と食い違っていますでしょうか？

すみません。Form1.WriteLine では fm2.InvokeRequired を検査する意味がありませんでした。単純に；

'/*** Form1 (メインフォーム) ***/

    Private Delegate Sub WriteLineDelegate(ByVal text As String)

    '// Form2に１行表示
    Private Sub WriteLine(ByVal text As String)
        If fm2 Is Nothing Then Return
        If fm2.IsDisposed OrElse Not fm2.IsHandleCreated Then Return
        Try
            Dim dlgt As New WriteLineDelegate(AddressOf fm2.WriteLine)
            fm2.Invoke(dlgt, New Object() {text})
        Catch
        End Try
    End Sub

としてみましたが、やはり結果は同じでした。

■No6802 (れい さん) に返信

詳細なアドバイス、ありがとうございます。

> Undocumentedだと思います。

そうですか。残念です。

> Closingにフラグ組み込むだけではだめです。
> Form.CloseされてからClosingに入る前にInvokeされたら止まります。

そうなんです。原コード■No6760 のForm2を；

'/*** Form2 (経過表示用フォーム) ***/
Public Class Form2 : Inherits System.Windows.Forms.Form
    '// Friend WithEvents RichTextBox1 As System.Windows.Forms.RichTextBox 
    Private Delegate Sub WriteLineDelegate(ByVal text As String)
    Private dlgt As New WriteLineDelegate(AddressOf Me.WriteLine)
    Private blockedInvoking As Boolean                  '//  Closingイベントフラグ

    '// リッチテキストボックスに文字を追記表示する
    Public Sub WriteLine(ByVal text As String)
        If Me.IsDisposed OrElse Not Me.IsHandleCreated Then Return
        If Me.InvokeRequired Then
            If blockedInvoking Then Return '             // Closing中ならばInvokeを阻止
            Try
                Me.Invoke(dlgt, New Object() {text})
            Catch ex As System.ObjectDisposedException  '// 破棄後のアクセスは無視
            End Try
        Else
            With Me.RichTextBox1
                .AppendText(text & vbCrLf)
                .ScrollToCaret()
                .Focus()
            End With
        End If
    End Sub

    '// フォームを閉じようとしたときにフラグを立てる
    Private Sub Form2_Closing(ByVal sender As Object, ByVal e As System.ComponentModel.CancelEventArgs) Handles MyBase.Closing
        blockedInvoking = True
        '                                                // 以下は『確認のためのコード』
        Me.WriteLine("blockedInvoking = True")
        Static Dim retry As Boolean
        If Not retry Then e.Cancel = True '              // 1回目のClosingのみキャンセル
        retry = True
    End Sub
End Class

と書き換えて、書き込み中にクローズボタンを押して表示を止めてみると、

        1巡目です。
        ...
        163巡目です。
        164巡目です。
        blockedInvoking = True
        165巡目です。
        (停止)

のようになって、フラグを立てた後でも1回Invokeに進んでしまうことが判ります。
で、改めて『確認のためのコード』以下を外すと、最後のInvokeがObjectDisposedException
をスローするので、Catch句で殺しています。（原コードではForm1側に記述していました）

百回程度試行してみましたが、上記のコードだとフリーズすることはありませんでした。

しかし原コードでも、ObjectDisposedExceptionがキャッチされずにフリーズしていたので、
果たして『それで万全なのかが確信できない』というわけです。
必ず例外を投げてくれるのなら（エレガントとは言えませんけど^^;）安心なのですが。