C# と VB.NET の質問掲示板

VB.NET2015を使用しております。


マルチモニターで且つスケーリングがディスプレイ毎に異なる環境で
フォームのスクリーンショットを取得するために
フォームのある位置を取得したいと考えています。


仮想ディスプレイと呼ばれるものなので、

https://social.msdn.microsoft.com/Forums/vstudio/ja-JP/1bfd425f-b153-4079-bb51-8d525dc2937b/35079259681239812514124911247912487124511247312503125241245212?forum=vcgeneralja
http://www.vbaccelerator.com/home/vb/tips/Working_with_Multiple_Monitors/article.html


これらのページにあるように、
EnumDisplayMonitorsを使えば良いのではないかと思います。



        <DllImport("user32.dll")>
        Private Shared Function EnumDisplayMonitors(ByVal hdc As IntPtr, ByVal lprcClip As IntPtr, ByVal lpfnEnum As EnumMonitorsDelegate, ByVal dwData As IntPtr) As Boolean
        End Function

        <StructLayout(LayoutKind.Sequential)>
        Public Structure Rect
            Private Left As Integer, Top As Integer, Right As Integer, Bottom As Integer
        End Structure

        Delegate Function EnumMonitorsDelegate(hMonitor As IntPtr, hdcMonitor As IntPtr, ByRef lprcMonitor As Rect, dwData As IntPtr) As Boolean


        Sub main()

            EnumDisplayMonitors(IntPtr.Zero, IntPtr.Zero, AddressOf EnumMonitorsDelegate, IntPtr.Zero)

        End Sub

こんな感じでコードを書いてみたのですが、


エラー	BC30577	'AddressOf' オペランドはメソッドの名前でなければなりません。かっこは不要です。	
というエラーが出てしまいます、


どのようにすれば、エラーが出なくなりますか？

Module1.vbのソース

Imports System.Runtime.InteropServices
Module Module1

    <DllImport("user32.dll")>
    Private Function GetWindowRect(ByVal hwnd As IntPtr, ByRef lpRect As RECT) As Boolean
    End Function
    <StructLayout(LayoutKind.Sequential)>
    Private Structure RECT
        Public left As Integer
        Public top As Integer
        Public right As Integer
        Public bottom As Integer
    End Structure

    <DllImport("dwmapi.dll")>
    Private Function DwmGetWindowAttribute(ByVal hWnd As IntPtr, ByVal dwAttribute As DWMWINDOWATTRIBUTE, ByRef rect As RECT, ByVal cbAttribute As Integer) As Long
    End Function
    Private Enum DWMWINDOWATTRIBUTE
        DWMWA_NCRENDERING_ENABLED = 1
        DWMWA_NCRENDERING_POLICY
        DWMWA_TRANSITIONS_FORCEDISABLED
        DWMWA_ALLOW_NCPAINT
        DWMWA_CAPTION_BUTTON_BOUNDS
        DWMWA_NONCLIENT_RTL_LAYOUT
        DWMWA_FORCE_ICONIC_REPRESENTATION
        DWMWA_FLIP3D_POLICY
        DWMWA_EXTENDED_FRAME_BOUNDS 'ウィンドウのRect
        DWMWA_HAS_ICONIC_BITMAP
        DWMWA_DISALLOW_PEEK
        DWMWA_EXCLUDED_FROM_PEEK
        DWMWA_CLOAK
        DWMWA_CLOAKED
        DWMWA_FREEZE_REPRESENTATION
        DWMWA_LAST
    End Enum

    <DllImport("user32.dll")>
    Private Function GetDpiForWindow(ByVal hWnd As IntPtr) As Integer
    End Function
    <DllImport("kernel32.dll")>
    Private Function MulDiv(ByVal nNumber As Integer, ByVal nNumerator As Integer, ByVal nDenominator As Integer) As Integer
    End Function

    Public Structure WindowSize
        Public X As Integer
        Public Y As Integer
        Public Width As Integer
        Public Height As Integer
        Public OffsetX As Integer
        Public OffsetY As Integer
    End Structure

    Function GetWindowSize(ByVal hWnd As IntPtr) As WindowSize
        Dim lpRect As RECT
        Dim bounds As RECT

        '従来のフォームサイズの取得方法
        Call GetWindowRect(hWnd, lpRect)

        'プログラマから見たWindows 10 #4 〜 最新情報とプログラミングTips
        'https://www.webtech.co.jp/blog/os/win10/8445/
        '「ウィンドウのサイズと枠線についての仕様変更」より
        ' Windows10でのウインドウサイズの正確な求め方
        Call DwmGetWindowAttribute(hWnd, DWMWINDOWATTRIBUTE.DWMWA_EXTENDED_FRAME_BOUNDS, bounds, Marshal.SizeOf(GetType(RECT)))

        '各座標を設定
        Dim ws As WindowSize
        ws.X = bounds.left
        ws.Y = bounds.top
        ws.Width = bounds.right - bounds.left
        ws.Height = bounds.bottom - bounds.top
        'C#での画面キャプチャの取得方法を徹底解説！
        'https://www.fenet.jp/dotnet/column/language/4633/
        'BitBlt API等で取得する際、x, y座標に指定する値
        ws.OffsetX = bounds.left - lpRect.left
        ws.OffsetY = bounds.top - lpRect.top

        'ここから後が必要かわからないが一応

        'Windows での高 DPI デスクトップアプリケーション開発
        'https://docs.microsoft.com/ja-jp/windows/win32/hidpi/high-dpi-desktop-application-development-on-windows
        '現在表示されているウインドウのモニターのDPIを取得
        'SetWindowPos API等は96DPI固定で計算されているので、現在のDPIで96DPI相当の位置を再計算
        Dim iDpi As Long = GetDpiForWindow(hWnd)
        ws.X = MulDiv(ws.X, iDpi, 96)
        ws.Y = MulDiv(ws.Y, iDpi, 96)
        ws.Width = MulDiv(ws.Width, iDpi, 96)
        ws.Height = MulDiv(ws.Height, iDpi, 96)
        ws.OffsetX = MulDiv(ws.OffsetX, iDpi, 96)
        ws.OffsetY = MulDiv(ws.OffsetY, iDpi, 96)

        Return ws
    End Function


End Module

[Form1]フォームに[Button1]ボタンを配置
Public Class Form1
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        '[メモ帳]を起動
        Dim p As System.Diagnostics.Process = System.Diagnostics.Process.Start("notepad.exe")
        '表示されるまで待機
        System.Threading.Thread.Sleep(1000)
        For Each p In System.Diagnostics.Process.GetProcesses()
            '[メモ帳]をプロセスから判断
            If p.ProcessName = "notepad" Then
　　　　　　　　'座標を取得
                Dim ws As WindowSize = GetWindowSize(p.MainWindowHandle)
                Debug.Print("X={0},Y={1},Width={2},Height={3},OffsetX={4},OffsetY={5}", ws.X, ws.Y, ws.Width, ws.Height, ws.OffsetX, ws.OffsetY)
            End If
        Next
    End Sub
End Class

お二方ありがとうございます。


本当にお聞きしたかったのは、
起動しているフォーム内（くまさんは.「別のフォーム」と仰っていますが、同じフォーム内です）にあるPictureBoxのスクリーンショットを取得することです。

最初から、これを質問するよりも
フォームだけを取得したいと質問した方が回答が得られやすいかと思い、
フォームの取得方法を先に質問しました、


魔界の仮面弁士さんの回答だと、
100%以外のDPIでも普通に取得できるそうなのですが、
こちらの環境だとうまくいきません、

以下のコードで何が間違っていますでしょうか？


    Public Sub PBoxScreenshot2()


        Dim PBox As PictureBox = PictureBox1


        Dim PBoxScreenLocation1 As Point = PBox.PointToScreen(PBox.ClientRectangle.Location)

        Dim BoundaryWidth As Integer = PBox.Width - PBox.ClientSize.Width
        Dim BoundaryWidth2 As Integer = BoundaryWidth \ 2


        PBoxScreenLocation1.X -= BoundaryWidth2
        PBoxScreenLocation1.Y -= BoundaryWidth2



        Using bmp As New Bitmap(PBox.Size.Width, PBox.Size.Height)

            Using g As Graphics = Graphics.FromImage(bmp)

                g.CopyFromScreen(PBoxScreenLocation1, New Point(0, 0), bmp.Size, CopyPixelOperation.SourceCopy)

            End Using

            Clipboard.SetImage(bmp)

        End Using


    End Sub


あとちなみに、スケーリングを変更しても、

Dim iDpi As Integer = GetDpiForWindow(hWnd)

で得られる値は96から変化しません、

検索して調べると、スケーリングを変えるとDPIが変化すると書かれてあるのですが
不思議です。