C# と VB.NET の質問掲示板

■No8335 (河童３０ さん) に返信

Public Class Form1

    Private WithEvents tm As New Timer
    Private WithEvents treeview1 As New TreeView()
    Private WithEvents webbrowser1 As New WebBrowser()

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

        Dim splitter As New SplitContainer()

        treeview1.Dock = DockStyle.Fill
        webbrowser1.Dock = DockStyle.Fill

        splitter.Panel1.Controls.Add(treeview1)
        splitter.Panel2.Controls.Add(webbrowser1)

        splitter.Dock = DockStyle.Fill

        Me.Controls.Add(splitter)

        Dim tn1 As TreeNode = New TreeNode(My.Resources.PDF1)
        Dim tn2 As TreeNode = New TreeNode(My.Resources.PDF2)
        Dim tn3 As TreeNode = New TreeNode(My.Resources.PDF3)

        tn1.Tag = My.Settings.PDF_FILE1
        tn2.Tag = My.Settings.PDF_FILE2
        tn3.Tag = My.Settings.PDF_FILE3

        TreeView1.Nodes.Add(tn1)
        TreeView1.Nodes.Add(tn2)
        TreeView1.Nodes.Add(tn3)

        tm.Interval = 500

        AddHandler treeview1.AfterSelect, AddressOf treeview1_onchanged
        AddHandler webbrowser1.DocumentCompleted, AddressOf webbrowser1_completed

    End Sub


    Private Sub treeview1_onchanged(ByVal sender As Object, ByVal e As TreeViewEventArgs)
        Dim selectedNode As TreeNode = TreeView1.SelectedNode
        WebBrowser1.Navigate(DirectCast(selectedNode.Tag, System.Uri))

    End Sub

    Private Sub webbrowser1_completed(ByVal sender As Object, ByVal e As WebBrowserDocumentCompletedEventArgs)
        Me.Update()
        Me.Focus()
        TreeView1.Focus()
        ''このタイマーが肝;;
        tm.Start()
    End Sub
    Private Sub tm_tick(ByVal sender As Object, ByVal e As EventArgs) Handles tm.Tick
        tm.Stop()
        'Me.Update()
        treeview1.Focus()

    End Sub
End Class

リソースと設定は、MyProject ダブクリして設定して下さい。
設定は、型に System.Uri を指定しておくとほんのちょびっと手間が省けます。

とりあえず、サンプルなんで、ご自分で利用する際は、GetFiles() して、Uri を TreeNode.Tag に
入れることになりそうですね。

■No8343 (ｍあ さん) に返信
> ■No8340 (渋木宏明(ひどり) さん) に返信
>>WebBrowser なんか通さないで、AcrobatReader を（の）ActiveX コントロールとしてフォームに貼りこめばいいんじゃないでしょうか。
>>
> うーん、COM わからんこちゃんよ。
> もう寝るけど、ちょっと時間ください。解決するかどーかわからんけど（；；もう眠い

完了しますた。

Public Class Form1

    Private tv1 As New TreeView
    Private pdd As AxAcroPDFLib.AxAcroPDF

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim spl As New SplitContainer
        pdd = New AxAcroPDFLib.AxAcroPDF()
        spl.Dock = DockStyle.Fill
        spl.Panel1.Controls.Add(tv1)
        tv1.Dock = DockStyle.Fill
        spl.Panel2.Controls.Add(pdd)

        pdd.Dock = DockStyle.Fill
        pdd.Visible = True

        Controls.Add(spl)

        tv1.Nodes.Add("ok")
        tv1.Nodes.Add("ng")

        Try
            pdd.LoadFile("C:\map_tokyo.pdf")

        Catch ex As Exception
            MsgBox(ex.Message + ">>>" + ex.StackTrace)

        End Try

    End Sub
End Class

コマンドプロンプトで,

cd C:\
mkdir C:\AxAcroPDF
cd C:\AxAcroPDF
-- 以下２行で１行です(AxImp.exe を実行するのだ） --
C:\Program Files\Microsoft Visual Studio 8\SDK\v2.0\Bin\AxImp.exe 
    C:\Program Files\Adobe\Acrobat 7.0\ActiveX\AcroPDF.ocx
--
dir
2007/09/28  13:30             8,192 AcroPDFLib.dll
2007/09/28  13:30             7,680 AxAcroPDFLib.dll ***** コイツ

「コイツ」を参照設定。

以上、勉強になりました。

■No8369 (渋木宏明(ひどり) さん) に返信
>>C:\Program Files\Microsoft Visual Studio 8\SDK\v2.0\Bin\AxImp.exe 
>>    C:\Program Files\Adobe\Acrobat 7.0\ActiveX\AcroPDF.ocx
> 
> あれ？ ウチは ActoPDF.ocx は無くて ACroPDF.dll ってのがありますぜ。

へぇ、タイプミスです。
dll が正解。

> 
> ↑の投稿の後に Adobe のサイトに行ってみたら、ちゃんとデベロッパ向けの SDK & ドキュメントが公開されてますね。
> ざーーーっとみた限り、Automation や ActiveX ぽいもののリファレンスも入ってるみたいでした。
> 
> 英語なのでー、とか言われそうだけど、急がば回れで「正規ルートから攻める」のがやっぱ正解かと。
>

おっしゃる通り、正規ルートの方が安心ちゃー安心です。
会社のPCでいじっているので、あまりインストールできないのが現状。という言い訳でもしとこ・・・

ちょっと手直ししました。
SetView と SetPageMode のパラメータを調べたのでそれを追加しました。
主さんの案件にもピッタンコかと思います。


''' <summary>
''' void SetPageMode(BSTR bszPageMode);
''' </summary>
''' <remarks></remarks>
Public NotInheritable Class PdfPageMode
    Public Const NONE As String = "none" ''ブックマークもサムネイルも無い
    Public Const BOOKMARKS As String = "bookmarks" ''ブックマーク付き
    Public Const THUMBS As String = "thumbs" ''サムネイル付き
End Class


''' <summary>
''' void SetView(BSTR bszViewMode);
''' </summary>
''' <remarks>
''' http://partners.adobe.com/public/developer/en/acrobat/sdk/pdf/iac/IACReference.pdf
''' </remarks>
Public NotInheritable Class PdfViewMode
    Public Const FIT As String = "Fit" ''枠に収まる全体表示
    Public Const FITH As String = "FitH" ''横が収まる
    Public Const FITV As String = "FitV" ''縦が収まる
    Public Const FITB As String = "FitB" '' ?
    Public Const FITBH As String = "FitBH" '' ?
    Public Const FITBV As String = "FitBV" '' ?
End Class

Public Class Form1

    Private WithEvents tv1 As New TreeView
    Private pdd As AxAcroPDFLib.AxAcroPDF

    Private Sub tv1_AfterSelected(ByVal sender As Object, ByVal e As TreeViewEventArgs) Handles tv1.AfterSelect

        Try
            Dim file As String = DirectCast(tv1.SelectedNode.Tag, String)

            Console.WriteLine("showFile::{0}", file)
            pdd.LoadFile(file)

            '' こいつらは毎度設定しないと意味ない
            pdd.setShowToolbar(False)
            pdd.setView(PdfViewMode.FIT)

        Catch ex As Exception
            MsgBox(ex.Message + ">>>" + ex.StackTrace)
        End Try

    End Sub

    Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Dim spl As New SplitContainer
        pdd = New AxAcroPDFLib.AxAcroPDF()
        spl.Dock = DockStyle.Fill
        spl.Panel1.Controls.Add(tv1)
        tv1.Dock = DockStyle.Fill
        spl.Panel2.Controls.Add(pdd)

        pdd.Dock = DockStyle.Fill
        pdd.Visible = True

        Me.Size = New Size(800, 600)
        Controls.Add(spl)


        tv1.Nodes.Add("PDF1")
        tv1.Nodes.Add("PDF2")

        '' 以下２ PDF は、Google で PDF で検索して最初のページの
        '' [PDF] リンクから抜いたもの。
        tv1.Nodes(0).Tag = "C:\map_tokyo.pdf"
        tv1.Nodes(1).Tag = "C:\fragment.pdf"


    End Sub
End Class