C# と VB.NET の質問掲示板

■No11567 (ＩＤ非公開 さん) に返信
> 　　デザイナが変なコードを生成してしまい、

属性とかきちんとしてないと変になりますね。

時と場合によりますが、
コレクションが専用ならこんな感じで作ります。

Imports System.ComponentModel

Public Class DesignerTest
    Inherits Panel
    Private _item As New MyCollection(Me)

    <DesignerSerializationVisibility(DesignerSerializationVisibility.Content)> _
    Public ReadOnly Property Items() As MyCollection
        Get
            Return _item
        End Get
    End Property

    Friend Sub OnCollectionChanged()
        Me.Invalidate()
    End Sub

    Protected Overrides Sub OnPaint(ByVal e As System.Windows.Forms.PaintEventArgs)
        For i As Integer = 0 To _item.Count - 1
            e.Graphics.DrawString(_item(i).ToString, Me.Font, Brushes.Black, 0, i * 10)
        Next
        MyBase.OnPaint(e)
    End Sub

    Public Class MyCollection
        Inherits System.Collections.ObjectModel.Collection(Of Integer)
        Private _parent As DesignerTest

        Friend Sub New(ByVal parent As DesignerTest)
            _parent = parent
        End Sub

        Protected Overrides Sub ClearItems()
            MyBase.ClearItems()
            _parent.OnCollectionChanged()
        End Sub

        Protected Overrides Sub InsertItem(ByVal index As Integer, ByVal item As Integer)
            MyBase.InsertItem(index, item)
            _parent.OnCollectionChanged()
        End Sub

        Protected Overrides Sub RemoveItem(ByVal index As Integer)
            MyBase.RemoveItem(index)
            _parent.OnCollectionChanged()
        End Sub

        Protected Overrides Sub SetItem(ByVal index As Integer, ByVal item As Integer)
            MyBase.SetItem(index, item)
            _parent.OnCollectionChanged()
        End Sub

    End Class

End Class