C# と VB.NET の質問掲示板

> ファイルが20個あった場合、同じようにToolStripMenuItemを作成し、それぞれイベントハンドラを振り分けようと思っています。
> これは不可能な事なのでしょうか？

いや、だからたとえばぁ...

Private MenuItems As New List(Of ToolStripMenuItem)

Private Sub Form1_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
  Dim I As Integer
  For I = 0 To 3
    Dim item As New ToolStripMenuItem(String.Format("Item-{0}", I))
    MainMenu.DropDownItems.Add(item)
  Next
End Sub

とかなんとか。

Mr.Tです、こんにちは。
> てっきり何らかの記号を使って変数を宣言に用いる事が出来たりするのかな、と思っていました。
> 規則性のある名前にしたかったのは、変数を宣言に用いる事が出来れば、配列やFor X To Y等のループ処理を使って簡単に出来ると思ったからです。 
> 不可能なら仕方無いのであきらめます。

それだけでは、「規則性を求めるのに、変数に番号をつけるのか」
がわかりません。
というか、その考え方だけにこだわるのは、もったいないです。
せっかく、VB.NETでやってるのに...
#というか、VBでもCollectionはあったと思いますが

規則性がある、ってのは「なんらかの順番をつけている」ってことで、
であれば、変数名に番号をつけること以外でも解決する方法が、世の中にはあります。

> ただ、挙げて貰ったSystem.Collections.Generic.ListやDictionary等は使ってみた事がありません。
> 参考になるサイトやソース等はありますか？

これがわかれば、今までの考え方（変数に番号をつける）以外にもうまいやり方が
あるんだと、わかると思います。

少なくとも、ループだけでいうなら、こういうことで解決できますよ？
#例は、IntegerとStringになってますが

        Dim dmyDictonary As System.Collections.Generic.Dictionary(Of Integer, String) _
                    = New System.Collections.Generic.Dictionary(Of Integer, String)

        dmyDictonary.Add(1, "これが一番目")
        dmyDictonary.Add(2, "これが二番目")
        dmyDictonary.Add(3, "これが三番目")

        For Each sItem As KeyValuePair(Of Integer, String) In dmyDictonary
            'ここでループ処理
            If sItem.Key = 1 Then
                'ここは、1番目に該当するときに行う処理
            Else
                'それ以外の処理
            End If
        Next

        Dim i As Integer
        For i = 1 To dmyDictonary.Count
            If dmyDictonary.Item(i) = "これが一番目" Then
                'これが一番目の処理
            Else
                'それ以外の処理
            End If
        Next

まあ、私のヘタッピサンプルよりも、ググればいろんなもんが
出てきますよ。

#一部、意味不明な点を訂正しました

> 規則性のある名前にしたかったのは、変数を宣言に用いる事が出来れば、
> 配列やFor X To Y等のループ処理を使って簡単に出来ると思ったからです。 

複数のToolStripMenuItemに通し番号を付け、N番目をお手軽に参照したいってーことでしょか。

Imports System.Collections.Generic

Public Class Form1

' 可変長配列
Private MenuItems As New List(Of ToolStripMenuItem)

Private Sub Form1_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
  Dim I As Integer
  For I = 0 To 3
    ' 一個作って
    Dim item As New ToolStripMenuItem(String.Format("Item-{0}", I))
    ' Tagを打ちこみ
    item.Tag = I
    ' 可変長配列に追加して
    MenuItems.Add(item)
    ' ハンドラを設定
    AddHandler item.Click, New EventHandler(AddressOf Me.MenuItemClicked)
    ' んでもってメニューに追加
    MainMenu.DropDownItems.Add(item)
  Next
End Sub

' イベントハンドラ
Private Sub MenuItemClicked(ByVal sender As System.Object, ByVal e As System.EventArgs)
  Dim I As Integer
  ' Tagから通番を取りだして
  I = CType(sender, ToolStripMenuItem).Tag
  ' 可変長配列 MenuItemsのI番目にアクセス
  ListBox1.Items.Add(MenuItems(I).Text)
End Sub

End Class