C# と VB.NET の質問掲示板

■No14237 (あき さん) に返信
> VB6.0での「UserControl_ReadProperties」「UserControl_WriteProperties」と同様の機能をVB2005で実現したいのですが、
> 実装方法がわかりません。（この機能によりデザイン時のユーザーコントロールの設定を記憶しています）

VB6 でいうところの PropertyBag 相当のデータは、*.Designer.vb ファイルに
自動的にシリアライズされるようになっています。


たとえば、Length プロパティを例にとると、
>     m_length = PropBag.ReadProperty("Length", 64)
(中略)
>     Call PropBag.WriteProperty("Length", m_length, 64)                                      
これらはそのまま、『Public Property Length() As Integer』として実装すれば OK です。
初期値の 64 を表すには、<DefaultValue(規定値)> 属性を利用します。

単純な DefaultValue としては扱えないような場合、たとえば、
VB6 でいうところの、(Font や BackColor などの)『Ambient』なプロパティのような
場合においては、DefaultValue 属性を使う代わりに、
　『Private Function ShouldSerializeLength() As Boolean』…規定値かどうかを返す
　『Public Overridable Sub ResetLength()』…初期値に戻すための処理を記述
のメソッドを用意する事で対応できます。

また余裕があれば、プロパティの変更通知のための、
　『Public Event LengthChanged(ByVal sender As Object, ByVal E As EventArgs)』…プロパティ変更イベント
　『Protected Overrides Sub OnLengthChanged(ByVal E As EventArgs)』…イベントを発生させるメソッド
も用意しておいてください。


なお、プロパティ値をシリアライズさせるかどうかを制御したいのであれば、
そのプロパティに DesignerSerializationVisibility 属性を割り当てれば OK です。


それ以外では、
　EditorBrowsable属性 … コードの入力補完(IntelliSense)に表示させるかどうか
　Browsable属性 … PropertyGrid の表示させるかどうか
　Category属性 … PropertyGrid でのカテゴリ名
　Description属性 … PropertyGrid 等に表示される説明文
あたりも調べとくと良いかも。

■No14262 (あき さん) に返信
> Public Event LengthChanged(ByVal e As System.EventArgs)
引数は 2 つ用意してください。自身を表す Object と、イベント自体の引数 EventArgs です。

すなわち、以下のいずれかの表記となります。
    Public Event LengthChanged As EventHandler
    Public Event LengthChanged(ByVal sender As Object, ByVal e As EventArgs)


> Public Property Length() As Integer
>     Get
>         Return m_length
>     End Get
>     Set(ByVal New_Lengtn As Integer)
>         m_length = New_Lengtn
>     	☆☆☆☆☆☆☆☆☆☆☆
>     End Set
> End Property
☆部では、直接 RaiseEvent するかわりに、Me.OnLengthChanged(EventArgs.Empty) を呼び出します。


> （Overridesキーワードを使用するとベースClassのSubをオーバーライドしないためとエラーが出ます）
> Protected Sub OnLengthChanged(ByVal E As EventArgs)
> 	☆☆☆☆☆☆☆☆☆☆☆
> End Sub
Overrides ではなく、Overridable です。
Overrides が必要なのは、Length プロパティを持ったクラスを継承している場合だけです。

☆部では、そのまま RaiseEvent のコードを書くだけです。
すなわち、RaiseEvent LengthChanged(Me, e) です。


> 例えば、TextBox.OnBackColorChanged メソッドのヘルプを参照すると、
> 以下の様に記載があるのですが、実際にユーザーコントロールに独自実装したプロパティとの
> 関連づいた使用方法が記載されていないためよく使用方法が理解できません。
まず、これが[Overrides]であるのは、TextBox の継承元のクラスが、
OnBackColorChanged を(オーバーライド可能なメソッドとして)実装済みだからです。
独自に追加する場合は、[Overridable] です。

TextBox.OnBackColorChanged は Overrides と書かれていますが、
Control.OnBackColorChanged は Overridable になっていますよね。

■No14268 (魔界の仮面弁士) に追記

ミニマムコードとして書くと、これだけです。
(VB6 の PropertyBag にあたる処理は自動的に行われるため、今回は特に実装する必要はありません)

Private _Length As Short
Public Property Length() As Short
    Get
        Return _Length
    End Get
    Set(ByVal value As Short)
        _Length = value
    End Set
End Property

=============================================================================
イベント制御を含めた場合は、こんな感じ。
サンプルということで、あえて属性を付けて冗長的に書いています。


#Region "Length プロパティの定義"
    Private Const DefaultLength As Short = 64S
    Private _Length As Short = DefaultLength

    ''' <summary>Length プロパティの概要説明をここに記述</summary>
    <Browsable(True)> _
    <EditorBrowsable(EditorBrowsableState.Always)> _
    <DesignerSerializationVisibility(DesignerSerializationVisibility.Visible)> _
    <DefaultValue(DefaultLength)> _
    <Category("Behavior")> _
    <Description("プロパティの概要説明をここに記述")> _
    Public Property Length() As Short
        Get
            Return _Length
        End Get
        Set(ByVal value As Short)
            _Length = value
            '
            ' TODO: 状態変更コードをここに記述します。
            '   (画面の再描画や、内包コントロールの制御など)
            '
            OnLengthChanged(EventArgs.Empty)
        End Set
    End Property

    ''' <summary><see cref="P:Length"/>プロパティの内容が変更されたときに発生します。</summary>
    <Browsable(True)> _
    <EditorBrowsable(EditorBrowsableState.Always)> _
    <Category("プロパティ変更")> _
    <Description("Length プロパティの内容が変更されたときに発生します。")> _
    Public Event LengthChanged As EventHandler

    ''' <summary><see cref="E:LengthChanged"/>イベントを発生させます。</summary>
    <EditorBrowsable(EditorBrowsableState.Always)> _
    Protected Overridable Sub OnLengthChanged(ByVal e As EventArgs)
        RaiseEvent LengthChanged(Me, e)
    End Sub
#End Region

=============================================================================
また、VB6 ヘルプでいうところの「アンビエント プロパティ」の実装が必要な場合は、
No14240 で解説したように、ShouldSerialize* と Reset* を実装しましょう。
http://msdn2.microsoft.com/ja-jp/library/53b8022e.aspx


なお、今回は Short 型であるため、属性指定が全く無くても問題ありませんでしたが
コレクションなどをシリアライズさせたい場合には、DesignerSerializationVisibility 属性が
意味を持ってきます。こちらについても調べておいてください。