C# と VB.NET の質問掲示板

初めて利用させて頂きます。
私は今VB.net 2005を使用してメニュー画面を作成している所なのですが
少し気になるところがありましたので、書き込みさせてもらいました。

気になるところとは、方向キーによるボタンコントロールにおける遷移制御(フォーカス制御)についてです。

今の状態・・

 _Menu(Form1)______________________________
|  _______     _______                     |
| |       |   |       |                    |
| |___0___|   |___3___|                    |
|  _______     _______                     |
| |       |   |       |                    |
| |___1___|   |___4___|                    |
|  _______     _______                     |
| |       |   |       |                    |
| |___2___|   |___5___|                    |
|                                          |
|                                          |
|__________________________________________|

*数字が書いてあるところがボタンコントロールです。また数字はTab Indexです。

通常方向キーの「↓」または「→」を押した場合Tab Indexの数+1に、「↑」または「左」を押せばTab Indexの数-1に
フォーカスが移動するかと思います。

前置きが長くなりましたが・・今回私がやりたいのは、

Tab Index0にカーソルが当たっていた場合、「→」を押せば、Tab Index3へ。
Tab Index1にカーソルが当たっていた場合、「→」を押せば、Tab Index4へ。
Tab Index5にカーソルが当たっていた場合、「←」を押せば、Tab Index2へ。

など、自由にカーソルを動かしているように見えるようにしたいのです。

分かりにくいかとも思いますが；何卒宜しくお願いします。

■No24823 (ひで さん) に返信
> ■No24822 (トトロ さん) に返信
>>Tab Index0にカーソルが当たっていた場合、「→」を押せば、Tab Index3へ。
>>Tab Index1にカーソルが当たっていた場合、「→」を押せば、Tab Index4へ。
>>Tab Index5にカーソルが当たっていた場合、「←」を押せば、Tab Index2へ。
>>
>>など、自由にカーソルを動かしているように見えるようにしたいのです。
> 
> VBは知らないので、考え方だけ。。
> 
> if (現在のTab Index値 < 3) {
> 　移動先Tab Index = 現在のTab Index値+3
> }
> else {
> 　移動先Tab Index = 現在のTab Index値-3
> }
> 
> または
> 
> 移動先Tab Index = 現在のTab Index値 + 3 * ((現在のTab Index値 < 3) ? -1 : 1); 
> 
> の後に
> フォーカス移動(移動先Tab Index);
> 
> では駄目ですか？


返信有難う御座います。

私も以前記述でなんとかなるかなと思いやってみたのですが…

ボタン１の記述(Tab Index0)
Private Sub Button1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Button1.KeyDown

        Select Case e.KeyCode
            Case Keys.Right
                Button4.Focus()
            Case Keys.Down
                Button2.Focus()
        End Select

End Sub

*Button4(Tab Index3) Button2(Tab Index1)
で、やってみたのですが、うまく動かなかったのです…。
ブレークポイントを設定してやってみた所、処理に入ってすらいなかったのです；

■No24825 (トトロ さん) に返信
> Private Sub Button1_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Button1.KeyDown

「KeyDown イベント」ではなく、「PreviewKeyDown イベント」を使ってみるとか。

' 
' ┏━━━━━━━━━━┓┏━━━━━━━━━━┓
' ┃Button1 (TabIndex=0)┃┃Button4 (TabIndex=3)┃
' ┗━━━━━━━━━━┛┗━━━━━━━━━━┛
' ┏━━━━━━━━━━┓┏━━━━━━━━━━┓
' ┃Button2 (TabIndex=1)┃┃Button5 (TabIndex=4)┃
' ┗━━━━━━━━━━┛┗━━━━━━━━━━┛
' ┏━━━━━━━━━━┓┏━━━━━━━━━━┓
' ┃Button3 (TabIndex=2)┃┃Button6 (TabIndex=5)┃
' ┗━━━━━━━━━━┛┗━━━━━━━━━━┛
' 

Public Class Form1

　Private buttonNavi As New Navigators(Of Button)()
　Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
　　buttonNavi.Add(Button1, Nothing, Button4, Button2, Nothing)
　　buttonNavi.Add(Button2, Button1, Button5, Button3, Nothing)
　　buttonNavi.Add(Button3, Button2, Button6, Nothing, Nothing)
　　buttonNavi.Add(Button4, Nothing, Nothing, Button5, Button1)
　　buttonNavi.Add(Button5, Button4, Nothing, Button6, Button2)
　　buttonNavi.Add(Button6, Button5, Nothing, Nothing, Button3)
　End Sub

　Private Class Navigators(Of T As Control)
　　Private list As New List(Of Navigator)()
　　Public Sub Add(ByVal target As T, ByVal up As T, ByVal right As T, ByVal down As T, ByVal left As T)
　　　list.Add(New Navigator(target, up, right, down, left))
　　End Sub

　　Private Class Navigator
　　　Private self As T
　　　Private up, right, down, left As T
　　　Private Sub PreviewKeyDown(ByVal sender As Object, ByVal e As PreviewKeyDownEventArgs)
　　　　Select Case e.KeyCode
　　　　　Case Keys.Up
　　　　　　up.Focus()
　　　　　　e.IsInputKey = True
　　　　　Case Keys.Right
　　　　　　right.Focus()
　　　　　　e.IsInputKey = True
　　　　　Case Keys.Down
　　　　　　down.Focus()
　　　　　　e.IsInputKey = True
　　　　　Case Keys.Left
　　　　　　left.Focus()
　　　　　　e.IsInputKey = True
　　　　End Select
　　　End Sub

　　　Public Sub New(ByVal target As T, ByVal up As T, ByVal right As T, ByVal down As T, ByVal left As T)
　　　　Me.self = target
#If VBC_VER < 9 Then
　　　　Me.up = IIf(IsNothing(up), target, up)
　　　　Me.right = IIf(IsNothing(right), target, right)
　　　　Me.down = IIf(IsNothing(down), target, down)
　　　　Me.left = IIf(IsNothing(left), target, left)
#Else
　　　　Me.up = If(up, target)
　　　　Me.right = If(right, target)
　　　　Me.down = If(down, target)
　　　　Me.left = If(left, target)
#End If
　　　　AddHandler target.PreviewKeyDown, AddressOf PreviewKeyDown
　　　End Sub
　　End Class
　End Class
End Class