C# と VB.NET の質問掲示板

■No38503 (みのり さん) に返信
文章を拝見した限りでは、問題の切り分けは出来ているように思います。
後は、１つ１つ実装してみてくださいな。
そして、どのフェーズでうまくいかないか教えてください。

・データからファイル名となる文字列を切り出す。
・データからフォルダ名となる文字列を切り出す。
・切り出したフォルダ名でフォルダがあるか確認する。
・なければ、フォルダを作成する。
・切り出したファイル名でデータを保存する。

お世話になります。みのりです。
以前、質問させていただきました

　　・データからフォルダ名・ファイル名となる文字列を切り出す。
　　・フォルダ・ファイルがあるか確認。なければ作成。

までは、なんとか出来ました。（これだけでも感動しています＾＾；）

しかし、・切り出したファイル名で、データ保存がうまく行きません。
色々やってみたのですが、切り出したファイル名でファイルは作成されているのですが、
肝心のデータが書き込み出来ても、一行だけとか全く書き込み出来ていない
状態ばかりです。
　　


 >> file = New System.IO.StreamWriter("c:\data.txt")

>本筋と関係ないですが、これ↑ちゃんと「c:\data.txt」作られてます？ 

 .SHOさんに指摘いただいた、この辺の問題でしょうか？
どこが悪いのかアドバイスいただければ幸いです。




If Mid(buff, 1, 3) = "osk" Then

Kuiki.SetData(buff)

                    
   If System.IO.Directory.Exists("c:\" & Mid(buff, 1, 3) & "\" & _
                                  Mid(buff, 4, 4)) = True Then                         
   Else 
    System.IO.Directory.CreateDirectory("c:\" & Mid(buff, 1, 3) & "\" & _
                                   Mid(buff, 4, 4))
   End If

   If System.IO.File.Exists("c:\" & Mid(buff, 1, 3) & "\" & _
                            Mid(buff, 4, 4) & "\" & _
                            Mid(buff, 16, 6) & ".txt") = True Then 
   Else 
    file = New System.IO.StreamWriter("c:\" & Mid(buff, 1, 3) & "\" & _
                                       Mid(buff, 4, 4) & "\" & _
                                       Mid(buff, 16, 6) & ".txt", _
                                       False, System.Text.Encoding.Default)
    file.WriteLine(buff & vbCrLf)
    file.Close()
    End If
End If


後、・データからフォルダ名・ファイル名となる文字列を切り出す。
　　・フォルダ・ファイルがあるか確認。なければ作成。
の、もっと綺麗な？方法などがあれば、アドバイスいただけたら、うれしいです＾＾；

よろしくおねがいします。

■No38595 (みのり さん) に返信
> 後、・データからフォルダ名・ファイル名となる文字列を切り出す。
> 　　・フォルダ・ファイルがあるか確認。なければ作成。
> の、もっと綺麗な？方法などがあれば、アドバイスいただけたら、うれしいです＾＾；
> 

        Dim file As System.IO.StreamWriter
        Dim fileName As String
        Dim directoryName As String
        Dim buff As String

        buff = "osk1234xxxxxxxxABCDEFGaaaaa" + vbCrLf + "あいうえおかきくけこ"

        If buff.Substring(0, 3) = "osk" Then

            Kuiki.SetData(buff)

            fileName = "c:\" & buff.Substring(0, 3) & "\" & _
                               buff.Substring(3, 4) & "\" & _
                               buff.Substring(15, 6) & ".txt"
            directoryName = System.IO.Path.GetDirectoryName(fileName)

            If System.IO.Directory.Exists(directoryName) = False Then
                System.IO.Directory.CreateDirectory(directoryName)
            End If

            If System.IO.File.Exists(fileName) = False Then
                file = New System.IO.StreamWriter(fileName, False, System.Text.Encoding.Default)

                file.WriteLine(buff & vbCrLf)
                file.Close()
            End If
        End If

■No38595 (みのり さん) に返信 
> しかし、・切り出したファイル名で、データ保存がうまく行きません。
> 色々やってみたのですが、切り出したファイル名でファイルは作成されているのですが、
> 肝心のデータが書き込み出来ても、一行だけとか全く書き込み出来ていない
> 状態ばかりです。
> If System.IO.File.Exists("c:\" & Mid(buff, 1, 3) & "\" & _
>                    Mid(buff, 4, 4) & "\" & _
>                    Mid(buff, 16, 6) & ".txt") = True Then
> Else
>     File = New System.IO.StreamWriter("c:\" & Mid(buff, 1, 3) & "\" & _
>                                        Mid(buff, 4, 4) & "\" & _
>                                        Mid(buff, 16, 6) & ".txt", _
>                                        False, System.Text.Encoding.Default)
>     File.WriteLine(buff & vbCrLf)
>     File.Close()
> End If
うーん・・・的を外していたらごめんなさい。

ファイルが存在しなければ書き込みを行うようになっていますので
たとえば、データがこのような場合

osk2009hogehoge090720HogeHoge
osk2009fugafuga090720FugaFuga

HogeHogeの時点でファイルが作成され
FugaFugaは書き込まれません

■No38608 (みのり さん) に返信
> 　　　　　　If System.IO.File.Exists(fileName) = False Then
> 　　　　　　　'↑ファイルが存在するかを確認だから関係ないですよね？
> 
>                 file = New System.IO.StreamWriter(fileName, False, System.Text.Encoding.Default)
> 　　　　　　　　'↑ファイルを作成。ここを色々試してもやはり一行だけしか書き込めないか、真っ白の状態です。
> 
>                 file.WriteLine(buff & vbCrLf)
>                 file.Close()
>             End If

IF ブロックの中にファイルの書き込み処理を
記述されているので、ファイルが無いという条件が成立
したときにしか書き込みは行われないです。

' ファイルが無ければ以下の処理を行う
If System.IO.File.Exists(fileName) = False Then
    ' ファイルを上書きモードで開く（ファイルが存在しない場合は作成されます）
    file = New System.IO.StreamWriter(fileName, False, System.Text.Encoding.Default)
    ' ストリームに書き込む
    file.WriteLine(buff & vbCrLf)
    ' ファイルにフラッシュする
    file.Close()
End If


ファイルに追加で書き込みをする場合は
ファイルが無ければの条件文を削除して、StreamWriter の２番目の引数に
True（追加書き込みモード）を指定してくださいな。

' ファイルを追加モードで開く（ファイルが存在しない場合は作成されます）
file = New System.IO.StreamWriter(fileName, True, System.Text.Encoding.Default)
' ストリームに書き込む
file.WriteLine(buff)
' ファイルにフラッシュする
file.Close()