C# と VB.NET の質問掲示板

以前AccessDataSourceのデータの絞込み方法の件でお世話になった
http://bbs.wankuma.com/search.cgi?no=0&word=GridView%82%CC%8Di%8D%9E%82%DD%95%5C%8E%A6&andor=and&logs=70.txt&PAGE=20
続きの質問です。

検索用のキーワードをGoogleの様にスペースで区切って入力すると、単語のand検索が
行える様にしたいのですが、以下に示したコードの通り、単語が２個に限った特定の場合
のand検索は出来る様になったのですが、汎用性のあるコードをどの様に書けば良いのか
わかりません。アドバイス頂けると助かります。

スペースで区切った検索用キーワードが１個だったり、３個の時でも対応出来る
コードです。たぶん定石なので参考ページがあると思うのですがグーグルで見付ける
事が出来ません。よろしくお願いします。

VWD2005 + Access2003

TextBox1に「佐　一」を入力しButton1をクリックすると「佐藤一郎」の１行のみ表示されます。

Protected Sub Button1_Click(ByVal sender As Object, ByVal e As System.EventArgs)
            
    If (TextBox1.Text <> "") Then
        'スペースで区切られた単語のand検索を行う
        'TextBox1が空でないならば、条件検索を行う。
        Dim Words As String = TextBox1.Text.Replace("　", " ") ' 全角スペースは半角スペースに
        '検索キーワードをSplitKeyWords配列に格納する
        Dim SplitKeyWords As String() = Words.Split(New Char() {" "})
        
        'パラメータをクリア 
        AccessDataSource1.SelectParameters.Clear()

        'パラメータをセット 
        '@は必要ないです。 
        AccessDataSource1.SelectParameters.Add("KeyWord1", "%" & SplitKeyWords(0) & "%")
        AccessDataSource1.SelectParameters.Add("KeyWord2", "%" & SplitKeyWords(1) & "%")
        
        '検索の実行
        AccessDataSource1.SelectCommand = "SELECT [ID], [namae] FROM [MeiboTable] WHERE ((namae LIKE @KeyWord1) AND (namae LIKE @KeyWord2))"
        
    Else
        'TextBoxが空ならば、全件表示 
        'パラメータをクリア 
        AccessDataSource1.SelectParameters.Clear()
        AccessDataSource1.SelectCommand = "SELECT [ID], [namae] FROM [MeiboTable]"
    End If
    
End Sub

2009/10/05(Mon) 09:50:53 編集(投稿者)

SQLインジェクション対策のためにも、パラメーターを使用したコーディングを行ったほうがいいと思う。
（まあ、そんな危険性がなければ別にやる必要はないが）
Jittaさんがおっしゃっている2番目の「…Lengthで〜」というのをコードにすると

AccessDataSource1.SelectParameters.Clear()
AccessDataSource1.SelectCommand = "SELECT [ID], [namae] FROM [MeiboTable]"
Dim wa As String = " WHERE "
Dim SplitKeyWords As String() = Me.TextBox1.Text.Split("　 ".ToCharArray(), StringSplitOptions.RemoveEmptyEntries) ' 全角と半角のスペース
For i As Integer = 0 To SplitKeyWords.Length - 1
    AccessDataSource1.SelectCommand &= wa & "namae LIKE @KeyWord" & i
    AccessDataSource1.SelectParameters.Add("KeyWord" & i, "%" & SplitKeyWords(i) & "%")
    wa = " AND "
Next

こんな感じになる。

■No41945 (gtk2k さん) に返信
gtk2kさん、お返事ありがとうございます。
gtk2kさんのご提示頂いたコードを拝見し、スゴイの一言です。
これだけのコードをすらすらと書けるには、相当に広い範囲の知識、経験を積まなければ
と感じました。どういう意味を表現しているコードかわからないところもあり勉強していき
ます。ありがとうございました。

以下のコードで、スペースで区切られた単語のAND検索が出来る様になりました。

Protected Sub Button1_Click(ByVal sender As Object, ByVal e As System.EventArgs)
            
    If (TextBox1.Text <> "") Then
        'TextBoxが空でないならば、条件検索を行う。
        'スペースで区切られた単語のand検索を行う
        AccessDataSource1.SelectParameters.Clear() 'パラメータをクリア 
        AccessDataSource1.SelectCommand = "SELECT [ID], [namae] FROM [MeiboTable]"
        Dim wa As String = " WHERE "
        Dim SplitKeyWords As String() = Me.TextBox1.Text.Split("　 ".ToCharArray(), StringSplitOptions.RemoveEmptyEntries) ' 全角と半角のスペース
        For i As Integer = 0 To SplitKeyWords.Length - 1
            AccessDataSource1.SelectCommand &= wa & "namae LIKE @KeyWord" & i
            AccessDataSource1.SelectParameters.Add("KeyWord" & i, "%" & SplitKeyWords(i) & "%")
            wa = " AND "
        Next
        
    Else
        'TextBoxが空ならば、全件表示 
        AccessDataSource1.SelectParameters.Clear() 'パラメータをクリア 
        AccessDataSource1.SelectCommand = "SELECT [ID], [namae] FROM [MeiboTable]"
    End If
    
End Sub

> SQLインジェクション対策のためにも、パラメーターを使用したコーディングを行ったほうがいいと思う。
> （まあ、そんな危険性がなければ別にやる必要はないが）
パラメーターを使用したSQLのコーディングの方が安全である事を覚えておきます。

■No41984 (gtk2k さん) に返信
> あ、いや、あれだけでTextBoxが空の場合にも対応してるんだが。

gtk2kさん、提示頂いた高機能な、すばらしいコードを使いこなせてなく申し訳ございません。
以下のコードだけで、TextBoxが空の場合も全件表示される事を確認しました。
改めて、すばらしいコードの提供ありがとうございました。

Protected Sub Button1_Click(ByVal sender As Object, ByVal e As System.EventArgs)
    'スペースで区切られた単語のand検索を行う
    'TextBoxが空の場合は全件を表示
    AccessDataSource1.SelectParameters.Clear() 'パラメータをクリア 
    AccessDataSource1.SelectCommand = "SELECT [ID], [namae] FROM [MeiboTable]"
    Dim wa As String = " WHERE "
    Dim SplitKeyWords As String() = Me.TextBox1.Text.Split("　 ".ToCharArray(), StringSplitOptions.RemoveEmptyEntries) ' 全角と半角のスペース
    For i As Integer = 0 To SplitKeyWords.Length - 1
        AccessDataSource1.SelectCommand &= wa & "namae LIKE @KeyWord" & i
        AccessDataSource1.SelectParameters.Add("KeyWord" & i, "%" & SplitKeyWords(i) & "%")
        wa = " AND "
    Next
End Sub