C# と VB.NET の質問掲示板

■No45275 (匿名 さん) に返信
> 単純に、「dRow = ds.Tables("テーブルA").NewRow」から
> 「da.Update(ds, "テーブルA") 」までをテーブルBに替えて
> 書き足すだけで良いのでしょうか？
単純に書き足すという言葉にどの様な意味が込められているのか量りかねる部分もありますが
そっくりそのままという意味ではおそらく出来ないです。
・DataAdapter のインスタンスをもうひとつ作らなくてはいけません。
・Connection.BeginTransaction は一回にしなければいけません。
概ね同じような処理という意味では良いとおもいます。

質問とはあまり関係ありませんが Connection オブジェクトは破棄を保証したほうが良いかと思
います。
Try
    ...
Catch ...
    ...
Finally
    cn.Dispose()
End Try

■No45275 (匿名 さん) に返信
> 2テーブル（テーブルA・テーブルB）の処理が完全に終了した場合のみコミット、 
> どちらか一方でも不具合があればロールバックしたいです。 

Connectionに対してTransactionをはって
Try
   UPDATE テーブルＡ
   UPDATE テーブルＢ
   TransactionのCommit
Catch
   TransactionのRollBacj
End Try

参考URL
http://hatsune.wankuma.com/seminer/tokyo20/25.PNG

■No45295 (匿名 さん) に返信
> da1 = New OleDb.OleDbDataAdapter(strSQL, cn)
> da2 = New OleDb.OleDbDataAdapter(strSQL, cn)

テーブルが異なるので strSQL は同じではいけないです。
それぞれのテーブルに対する SQL をセットしてください。

> .BeginTransactionと.commitは対にしなければいけませんよね？
> となると、どう対処したら良いのかがわかりません…

BeginTransaction にて Transaction オブジェクトを作成して、それぞれのコ
マンドにセットしてください。

Dim cnTran As OleDbTransaction = cn.BeginTransaction(IsolationLevel.ReadCommitted)
da1.InsertCommand.Transaction = cnTran
da2.InsertCommand.Transaction = cnTran

オブジェクトの破棄を保証するために Using 句を用いるとこんな感じです。

Using cnTran As OleDbTransaction = cn.BeginTransaction(IsolationLevel.ReadCommitted)
    ...
    da1.InsertCommand.Transaction = cnTran
    da2.InsertCommand.Transaction = cnTran
    ...
End Using

記述の仕方の話です。

変数 dRow にテーブル１の新規行、テーブル２の新規行をセットしていますが

dRow = ds.Tables("テーブル１").NewRow
dRow = ds.Tables("テーブル２").NewRow

可読性を考えると別の変数を用意したほうが善いです。

Dim newRow1 As DataRow = ds.Tables("テーブル１").NewRow()
Dim newRow2 As DataRow = ds.Tables("テーブル２").NewRow()

変数 cBuilder も同じようにテーブル１用、テーブル２用にそれぞれの変数を作成し
てインスタンスをセットした方が善いです。

Dim commandBuilder1 As New OleDbCommandBuilder()
commandBuilder1.DataAdapter = da1
da1.InsertCommand = commandBuilder1.GetInsertCommand()

Dim commandBuilder2 As New OleDbCommandBuilder()
commandBuilder2.DataAdapter = da2
da2.InsertCommand = commandBuilder2.GetInsertCommand()

行数は増えますが、変数がテーブル１の状態かテーブル２の状態かを気にする
必要がなくなるので、処理に着目してコードを整理することが出来ます。
そうすることで、トランザクションが行われている場所を明確に出来ますし、
メソッドの分割もやりやすくなるかと思います。

' データベースからデータを取得する処理
Dim da1 As New OleDb.OleDbDataAdapter("...", cn)
da1.Fill(ds, "テーブル１")

Dim da2 As New OleDb.OleDbDataAdapter("...", cn)
da2.Fill(ds, "テーブル２")

' 新規データを作成する処理
Dim newRow1 As DataRow = ds.Tables("テーブル１").NewRow()
newRow1("フィールド") = "値"
ds.Tables("テーブル１").Rows.Add(newRow1)

Dim newRow2 As DataRow = ds.Tables("テーブル２").NewRow()
newRow2("フィールド") = "値"
ds.Tables("テーブル２").Rows.Add(newRow2)

' データベースを更新する処理
Dim commandBuilder1 As New OleDbCommandBuilder()
commandBuilder1.DataAdapter = da1
da1.InsertCommand = commandBuilder1.GetInsertCommand()

Dim commandBuilder2 As New OleDbCommandBuilder()
commandBuilder2.DataAdapter = da2
da2.InsertCommand = commandBuilder2.GetInsertCommand()

Using cnTran As OleDbTransaction = cn.BeginTransaction(IsolationLevel.ReadCommitted)
    da1.InsertCommand.Transaction = cnTran
    da2.InsertCommand.Transaction = cnTran
    Try 
        da1.Update(ds, "テーブル１")
        da2.Update(ds, "テーブル２")
        cnTran.Commit()
    Catch e As Exception
        cnTran.Rollback()
    End Try
End Using