C# と VB.NET の質問掲示板

VB用に書き直してみた。
 
Imports System
Imports System.Runtime.InteropServices
 
Public Class CopyDataTest
    Private Const WM_COPYDATA As Integer = &H4A
    <DllImport("user32.dll")> _
    Private Shared Function FindWindow(ByVal lpClassName As String, ByVal lpWindowName As String) As IntPtr
    End Function
    ' ※ WM_COPYDATA用にlParamの型をByRef lParam As COPYDATASTRUCT にしてある。
    '    そのほかにSendMessageを多用するのであれば、IntPtrにするか(Marshal.StructureToPtrを使う)、
    '    関数名を変えるなどして対処する。
    <DllImport("user32.dll")> _
    Private Shared Function SendMessage _
        (ByVal hWnd As IntPtr, ByVal Msg As Integer, _
         ByVal wParam As IntPtr, ByRef lParam As COPYDATASTRUCT) As IntPtr
    End Function
    
    Private Structure COPYDATASTRUCT
        Public dwData As IntPtr
        Public cbData As Integer
        Public lpData As IntPtr
    End Structure
    
    Public Shared Sub Main(ByVal args() As String)
        Dim hWnd As IntPtr
        Dim cds As COPYDATASTRUCT
        Dim s As String
        
        hWnd = FindWindow(Nothing, "recv")
        
        If Not hWnd.Equals(IntPtr.Zero) Then
            s = "ほげ"
            
            cds = New COPYDATASTRUCT
            cds.dwData = IntPtr.Zero
            cds.lpData = Marshal.StringToHGlobalUni(s)
            cds.cbData = (s.Length + 1) * 2
            SendMessage(hWnd, WM_COPYDATA, IntPtr.Zero, cds)
            
            Marshal.FreeHGlobal(cds.lpData)
        End If
    End Sub
End Class

> しかしながら、私のスキル不足で受け側がよくわかりません。C++のサンプルを見たのですが理解不能です。
まぁ、C++のサンプルはわかんなくて当然だと思います。
ここら辺はIntPtrで受け渡しすることになるので、Marshal.〜を使ったことないとけっこう困難ですから。

Imports System
Imports System.Windows.Forms
Imports System.Runtime.InteropServices
    
Public Class Form1
    Inherits System.Windows.Forms.Form
            
    Private Const WM_COPYDATA As Integer = &H4A
    Private Structure COPYDATASTRUCT
        Public dwData As IntPtr
        Public cbData As Integer
        Public lpData As IntPtr
    End Structure

    Public Shared Sub Main()
        Application.Run(New Form1())
    End Sub
    
    Public Sub New()
        MyBase.New()
        
        InitializeComponent()
    End Sub
    
    Private Sub InitializeComponent()
        With Me
            .Text = "Recv"
            .Width = 100
            .Height = 100
        End With
    End Sub
    
    Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
        If m.Msg = WM_COPYDATA Then
            Dim cds As COPYDATASTRUCT
            
            cds = CType(Marshal.PtrToStructure(m.lParam, GetType(COPYDATASTRUCT)), COPYDATASTRUCT)
            MessageBox.Show(Marshal.PtrToStringUni(cds.lpData))
        Else
            MyBase.WndProc(m)
        End If
    End Sub

End Class