C# と VB.NET の質問掲示板

Public Class Parent
  Public Sub New(value As Integer)
    Me.x = value
  End Sub
  Private x As Integer
  Private Shared sharedChild As New Child
  Private Class Child
    Public Function GetX() As Integer
      ' Parent の x を返す
    End Function
  End Class
End Class

という構成だと、
Dim a As New Parent(0)
Dim b As New Parent(1)
のとき sharedChild.GetX() はどちらの x を返せばいいのでしょう？
と考えると分かるとおり、Parent のメンバは静的（Shared/Const）でない限り Parent の参照が必要です。
Child のコンストラクタに Parent の参照（Me）を渡すことが多いでしょう。

Public Class Parent
  Public Sub New(value As Integer)
    Me.x = value
    Me.c = New Child(Me)
  End Sub
  Private x As Integer
  Private c As Child
  Private Shared ReadOnly y As Integer = 4

  Private Class Child
    Public Sub New(ByVal parent As Parent)
      Me.p = parent
    End Sub
    Private p As Parent
    Public Function GetX() As Integer
      Dim a As Integer = p.x  ' Private にもアクセス可能
      Dim b As Integer = Parent.y  ' Shared/Const メンバは当然ながらクラス名からアクセス
      Return a + b
    End Function
  End Class

  ' Shared As Child の場合も同様
  Private Shared sharedChild As Child
  Shared Sub New()
    Parent.sharedChild = New Child(New Parent(0))
  End Sub
End Class

■No48097 (ペインタ さん) に返信
> ここで入れ子になっている子クラスChildClass内のメソッドで、
ChildClass は、ParentClass の内部クラスにはなっていますが、
そのインスタンスは親子関係になっていない事に注意してください。

インスタンスを親子関係として管理している例としては、
フォームの .Controls プロパティなどがあります。


> 親クラスParentClassのPrivate変数・定数（例えばTEST_MSGやiNum・sText）を参照したいのですが、
下記のようにすることは可能です。

Public Class ParentClass
    Private Const TEST_MSG As String = "これはテストです"
    Private iNum As Integer = 123
    Private sText As String = "Sample"
    Private child As New ChildClass(Me)
    '　：
    '　略
    '　：
    Private Class ChildClass
        Private parent As ParentClass
        Public Sub New(ByVal p As ParentClass)
            Me.parent = p
        End Sub
        Friend Sub FireTest()
            MsgBox(Me.parent.sText, vbInformation, ParentClass.TEST_MSG)
        End Sub
    End Class
End Class

みなさま、ご回答ありがとうございました。
ParentClassクラスで定義している定数、

    Private Const TEST_MSG As String

については、ChildClass側でも参照できますね。
また、ParentClassクラスで定義している変数についても、
以下のように、Private Shared〜と定義すれば参照できる（ビルドエラーとならない）ようですが、
この使い方は問題ないでしょうか？

Public Class ParentClass
    Private Const TEST_MSG As String = "これはテストです"
    Private Shared iNum As Integer
    Private Shared sText As String
    （以下略）
    ・
    ・
    ・
    Private Class ChildClass
        （以下略）
        ・
        ・
        ・
    End Class
End Class

これら変数は、親のParentClassクラスのインスタンス生成時に、定数式では表現できない内容を格納します。
ParentClassクラスだけでなく、子のChildClassクラスでも参照したいので、この方法で問題なければ
このように対応したいと思います。