C# と VB.NET の質問掲示板

お世話になります。

VB2005 で xp,vista　向けに開発をしている初心者です。

スタートメニュー(All Users)のパスを取得するため
以下のソースを作成しました。

しかし、SHGetSpecialFolderPath で　False が返ってきてしまいます。
どのようにすれば　SHGetSpecialFolderPath 関数が成功するのでしょうか。

よろしくお願い致します。

------------------------------------------------------------
    ' API 関数定義 
    Private Declare Function SHGetSpecialFolderPath Lib _
        "Shell32" Alias "SHGetSpecialFolderPathA" ( _
        ByVal hWnd As Long, _
        ByVal lpPath As String, _
        ByVal nFolder As Long, _
        ByVal fCreate As Boolean) As Boolean
    ' フォルダID 
    Private Const CSIDL_COMMON_PROGRAMS = 23

    ' 共通プログラムメニューのパスを取得
    Sub Main()
        Dim strTemp As String = ""
        Dim intPoint As Integer
        Dim strPath As String

        strTemp.PadLeft(256)
        ' 共通プログラムメニューのパスを取得 
        If SHGetSpecialFolderPath( _
            0, strTemp, CSIDL_COMMON_PROGRAMS, False) Then
            ' 余計なNULL文字を削除 
            intPoint = InStr(strTemp, Chr(0))
            strPath = Left(strTemp, intPoint - 1)
        End If

    End Sub

■No48265 (魔界の仮面弁士) に追記
>>以下のソースを作成しました。
> これって、VB4〜6 向けの宣言ではありませんか? (VB6 だとしても、宣言が間違っていますが)

VB2005 向けに書き換えてみました。CSIDL は列挙型に変更しています。

Imports System.Text
Imports System.Runtime.InteropServices
Module Module1
    Public Enum CSIDL As Integer
        '略
        COMMON_STARTMENU = 22
        COMMON_PROGRAMS = 23
        COMMON_STARTUP = 24
        '略
    End Enum
    Private Const MAX_PATH As Integer = 260
    Private Declare Auto Function SHGetSpecialFolderPath Lib "Shell32" _
       (ByVal hWnd As IntPtr, _
        ByVal lpPath As StringBuilder, _
        ByVal nFolder As CSIDL, _
        <MarshalAs(UnmanagedType.Bool)> _
        ByVal fCreate As Boolean _
       ) As <MarshalAs(UnmanagedType.Bool)> Boolean

    Public Function GetPath(ByVal folder As CSIDL) As String
        If Not System.Enum.IsDefined(GetType(CSIDL), folder) Then
            'Throw New ArgumentOutOfRangeException("folder")
        End If

        Dim path As New StringBuilder(MAX_PATH)
        If SHGetSpecialFolderPath(IntPtr.Zero, path, folder, False) Then
            Return path.ToString()
        Else
            Return Nothing
        End If
    End Function

    Sub Main()
        Dim s As String = GetPath(CSIDL.COMMON_PROGRAMS)
        Console.WriteLine(s)
        Console.Read()
    End Sub

End Module