C# と VB.NET の質問掲示板

> 現在はTextBoxAもTextBoxBも「未入力禁止」にはなっていない状態、
> という理解であってますか？
> (実は既にTextBoxAクラスに未入力禁止機能があって、
>  それが派生したTextBoxBクラスでは邪魔なのかな？という可能性を考えました)
その通りです。未入力禁止機能はありません。

> 
> 
> (1) ここの説明はどのクラスのどのメンバで書いている(もしくは書こうとしている)
> 　　コードについての話なんでしょうか？
> 　　→前半の説明で明らかになっていないこととして、
> 　　「TextBoxAのみ未入力を禁止」とするために、どのクラスを修正しようとしているのか？
> 　　(あるいは、その辺の方針は決めることができていないのか？)、ということが挙げられます。
> 
> 　　　(a) TextBoxAだけで何とかしたい
> 　　　(b) TextBoxAやTextBoxBを配置する側のフォームなどで対処する
> 　　　(c) その他
フォームのクラスで行います。 


> (2) また、このIf文で何を判断しようとしているのでしょうか？
> 　　(コードの意味はわかります。その用途がわからない、ということです。
> 　　用途がわからないと答えられないので)
> 
> 　　このコードを書いている場所は、TextBoxAクラスやTextBoxBクラス内のコードではなく、
> 　　例えば、どこか(フォームだったり標準モジュールだったり)に用意しようとしている
> 　　共通処理のメソッドの中で、テキストボックスのインスタンスが、
> 　　TextBoxAのインスタンスか、TextBoxBのインスタンスなのか？という判断をしたい、
> 　　という意味なのでしょうか？
> 　　＃ でも、そうだとすると、魔界の仮面弁士さんのNo48450の回答がズバリなので
> 　　＃ 違う意図なのかなぁと想像しています
フォーム上に未入力のテキストボックスがないかチェックするためです。
フォームクラスでPrivate Functionの中で行います。未入力がなければTrueが返り、未入力があればFalseが返ります。
具体的なコードは以下の通り

Private Class Frm_Hoge

Private Function TextBoxCheck(Ctrl As Contorl) As Boolean
    For Each CtrlItem As Control In Ctrl.Controls
       If TypeOf CtrlItem Is TextBox Then

           '未入力チェック
           If DirectCast(CtrlItem, TextBox).Text = String.Empty Then
                  Return False
                  Exit Function
           End If
        End If

        '内包されているコントロールがないか
        If CtrlItem.Control.Count > 0 Then
            TextBoxCheck(CtrlItem)
        End If
     Next

     Return True

End Function

End Class 

■No48477 (うれ さん) に返信
コメント頂いた内容でやりたいこと・今やっていることの全体像は理解できました。

>>>　　このコードを書いている場所は、TextBoxAクラスやTextBoxBクラス内のコードではなく、
>>　　例えば、どこか(フォームだったり標準モジュールだったり)に用意しようとしている
>>　　共通処理のメソッドの中で、テキストボックスのインスタンスが、
>>　　TextBoxAのインスタンスか、TextBoxBのインスタンスなのか？という判断をしたい、
>>　　という意味なのでしょうか？
>>　　＃ でも、そうだとすると、魔界の仮面弁士さんのNo48450の回答がズバリなので
>>　　＃ 違う意図なのかなぁと想像しています
> フォーム上に未入力のテキストボックスがないかチェックするためです。

TextBoxAは必須(未入力禁止)、TextBoxBは未入力OKでいいんですよね？
魔界の仮面弁士さんの回答通り

>        If TypeOf CtrlItem Is TextBox Then

If CtrlItem .GetType() Is GetType(TextBoxA) Then 

のようにすればTextBoxAだけが条件に合致する(TextBoxBに対しては処理されない)
と思いますが、うまく行かないのであれば、どのような結果になるのでしょうか？

--
GeTypeメソッドとGetTypeキーワードを使う方式でうまく行くだろうというのは
以下の実験コードで検証しました。”変数”の中身がクラスAのインスタンスであるパターンの
「1:表示される」という文言のみが表示されます。

Imports System

Class O     ' TextBox/Controlの代わり
End Class

Class A     ' TextBoxAの代わり
    Inherits O
End Class

Class B     ' TextBoxBの代わり
    Inherits A
End Class

Module X
    Sub Main()
        Dim 変数 As O
        変数 = New A()
        If 変数.GetType() Is GetType(A) Then
            Console.WriteLine("1:表示される")
        End If
        変数 = New B()
        If 変数.GetType() Is GetType(A) Then
            Console.WriteLine("2:表示されない")
        End If
    End Sub
End Module

■No48535 (うれ さん) に返信
> If TypeOf Ctrl Is TextBox Then
> だと派生したコントロールはFalseになります。

ステップ実行などを行って変数Ctrlの中身がTextBoxA〜TextBoxZのインスタンスだった場合でも、
If文の条件が成立しないということですか？
ソースコードはNo48477 のコードなんですよね？？

そんなはずはないのですけどね・・・昨日の実験コードは以下のコードの抜粋＆改変版で、
「If TypeOf Ctrl Is TextBox Then」のパターンについても検証済みです。

--
◇実験コード
' VB8.0/VB9.0のコンパイラで検証
'コンパイル方法：vbc /out:test.exe test.vb
Imports System

Class O
End Class

Class A
    Inherits O
End Class

Class B
    Inherits A
End Class

Module X
    Sub Main()
        Dim 変数 As O
        変数 = New A()
        If 変数.GetType() Is GetType(A) Then
            Console.WriteLine("1:表示される")
        End If
        If TypeOf 変数 Is A Then
            Console.WriteLine("2:表示される")
        End If
        変数 = New B()
        If 変数.GetType() Is GetType(A) Then
            Console.WriteLine("3:表示されない")
        End If
        If TypeOf 変数 Is A Then
            Console.WriteLine("4:表示される")
        End If
    End Sub
End Module

◇実行結果
1:表示される
2:表示される
4:表示される

--
O型の変数にAクラスを継承したBクラスのインスタンスが設定されている場合に
A型かどうかをチェックして、A型だと判定されているので「4:表示される」と表示されています。

■No48544 (うれ さん) に返信
>例えばClass AだったらClass 0 と出てきてほしいんですがClass Aとなってます。

クラス零?
唐突に Class 0 なるものが登場しましたが、どういう意味でしょうか。


質問内容がいまひとつ読みきれませんが、型の『名前』だけで判定したいという意味なら、
「TypeName(変数)」や「変数.GetType().FullName」等を使うことができます。たとえば、
　If TypeName(変数名) Like "TextBox[A-Z]" Then
などのような判定ですね。(もちろん、Like 以外の方法で判定しても OK です)


一方、『名前』ではなく『型』で判定したいのであれば、調べたい型というのが
「継承関係にある型」「インスタンスの型」「変数の型」のいずれかなのかで異なります。
--------------------

独自作成の TextBoxA や Class A だと、誤解があるといけないので、下記では
標準の TextBox クラスおよび RichTextBox クラスを使って説明していきます。


まず、TextBox および RichTextBox については、
　Control
　└TextBoxBase
　　├TextBox
　　└RichTextBox
という継承関係にあります。そのため、これらは、
　Dim C1 As New TextBox()
　Dim C2 As New RichTextBox()
　Dim C3 As Control = New TextBox()
　Dim C4 As Control = New RichTextBox()
のように宣言することができます。


この時、これらの変数 について『TypeOf 演算子』で
　If TypeOf 変数 Is 型 Then
と判定した場合、その結果は以下のようになります。

          ※ ○ = True、× = False ※
              ┏━┳━┳━┳━┓
  TypeOf 判定 ┃C1┃C2┃C3┃C4┃
┏━━━━━━╋━╋━╋━╋━┫
┃     Control┃○┃○┃○┃○┃
┣━━━━━━╋━╋━╋━╋━┫
┃ TextBoxBase┃○┃○┃○┃○┃
┣━━━━━━╋━╋━╋━╋━┫
┃     TextBox┃○┃×┃○┃×┃
┣━━━━━━╋━╋━╋━╋━┫
┃ RichTextBox┃×┃○┃×┃○┃
┗━━━━━━┻━┻━┻━┻━┛
つまり TypeOf 演算子では、クラスの継承元に対しても一致することになります。



一方、先の No48450 で回答した
　If 変数.GetType() Is GetType(型) Then
の方法を使った場合、以下のように判定されます。

              ┏━┳━┳━┳━┓
  GetType判定 ┃C1┃C2┃C3┃C4┃
┏━━━━━━╋━╋━╋━╋━┫
┃     Control┃×┃×┃×┃×┃
┣━━━━━━╋━╋━╋━╋━┫
┃ TextBoxBase┃×┃×┃×┃×┃
┣━━━━━━╋━╋━╋━╋━┫
┃     TextBox┃○┃×┃○┃×┃
┣━━━━━━╋━╋━╋━╋━┫
┃ RichTextBox┃×┃○┃×┃○┃
┗━━━━━━┻━┻━┻━┻━┛
この場合、インスタンスの型のみが調査対象です。変数の型は不問です。


その逆に、インスタンスではなく変数の型のみに着目して
              ┏━┳━┳━┳━┓
              ┃C1┃C2┃C3┃C4┃
┏━━━━━━╋━╋━╋━╋━┫
┃     Control┃×┃×┃○┃○┃
┣━━━━━━╋━╋━╋━╋━┫
┃ TextBoxBase┃×┃×┃×┃×┃
┣━━━━━━╋━╋━╋━╋━┫
┃     TextBox┃○┃×┃×┃×┃
┣━━━━━━╋━╋━╋━╋━┫
┃ RichTextBox┃×┃○┃×┃×┃
┗━━━━━━┻━┻━┻━┻━┛
のような判定結果を得たい場合には、このような方法があります。
　If GetVariableType(変数) Is GetType(型) Then

上記 GetVariableType は、下記のように記述してください。

Function GetVariableType(Of T)(ByVal obj As T) As Type
    Return GetType(T)
End Function