C# と VB.NET の質問掲示板

こんにちは、やま　と申します。お世話になります。

使用言語はVisual Basic2005で、
マウスでボタンを押し込んでいる間に処理を繰り返したいと思っています。

以下のようなソースで動作させると、while文の実行中にMouseUpのイベントを読み込めません。
どのようにすれば良いか、ご教授頂ければ幸いです。

よろしくお願い致します。

--------------------------------

Public Class Form1

    Private Sum As Integer
    Private Mouse As Boolean

    Private Sub Button1_MouseDown(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles Button1.MouseDown

        Mouse = True
        Do
            Sum = Sum + 1
        Loop While Mouse = True

    End Sub

    Private Sub Button1_MouseUp(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles Button1.MouseUp

        Mouse = False
        MsgBox(Sum)

    End Sub

End Class

■No52350 (やま さん) に返信
> マウスでボタンを押し込んでいる間に処理を繰り返したいと思っています。
「実際にやりたい処理」の内容にもよりますが、Timer で処理するのは駄目でしょうか。

> 以下のようなソースで動作させると、while文の実行中にMouseUpのイベントを読み込めません。
この場合、MouseDown イベントの処理が終了するまで MouseUp が発生しません。
ゆえに無限ループとなり、Sum がオーバーフローするまで止まらないと思います。

とりあえず単純な対策としては、ループ中に
　Application.DoEvents()
を入れておくことで一応は回避できますが、この方法は
個人的には避けた方が良いと思います。


> どのようにすれば良いか、ご教授頂ければ幸いです。
実際の繰り返し処理は、別のスレッドに担当させてみては如何でしょう。
http://www.tt.rim.or.jp/~rudyard/torii009.html

Imports System.ComponentModel
Public Class Form1
    Private Sub Button1_MouseDown(…
        BackgroundWorker1.WorkerSupportsCancellation = True
        BackgroundWorker1.RunWorkerAsync(1) '開始値
    End Sub

    Private Sub Button1_MouseUp(…
        BackgroundWorker1.CancelAsync()
    End Sub

    Private Sub BackgroundWorker1_RunWorkerCompleted(…
        MsgBox(e.Result)
    End Sub

    Private Sub BackgroundWorker1_DoWork(…
        Dim bgw As BackgroundWorker = DirectCast(sender, BackgroundWorker)
        Dim sum As Integer = CInt(e.Argument)
        Do
            sum += 1
        Loop Until bgw.CancellationPending
        e.Result = sum
    End Sub
End Class