C# と VB.NET の質問掲示板

VB2010

ジェネリックリストに追加した構造体データを、構造体の項目名で検索する方法についてご教授ください。
下記ソースの★★★部分がわかりません。

    Structure KojinInfo
        Public No As String
        Public Name As String
        Public Tel As String
    End Structure

    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        Dim kojin As New List(Of KojinInfo)
        Dim data() As String = {"1,伊藤,090-1111-1111", "2,鈴木,090-2222-2222", "3,斉藤,090-3333-3333"}
        Dim kInfo As KojinInfo
        For i = 0 To data.Length - 1
            Dim arr() As String = data(i).Split(","c)
            kInfo.No = arr(0)
            kInfo.Name = arr(1)
            kInfo.Tel = arr(2)
            kojin.Add(kInfo)
        Next

        ★★★「NO=1」で検索し「伊藤」と表示させたい
        ★★★「NAME=鈴木」で検索し「090-2222-2222」と表示させたい

    End Sub

■No54245 (pg さん) に返信

Linq で From, Whereを使った例です。

       '★★★「NO=1」で検索し「伊藤」と表示させたい
        Dim lstTmp = (From a In kojin Where a.No = "1").ToList
        If lstTmp.Count > 0 Then
            Dim itmFind = lstTmp.First
            Label1.Text = itmFind.Name
        End If

        '★★★「NAME=鈴木」で検索し「090-2222-2222」と表示させたい
        Dim lstTmp2 = (From a In kojin Where a.Name = "鈴木").ToList
        If lstTmp2.Count > 0 Then
            Dim itmFind = lstTmp2.First
            Label2.Text = itmFind.Tel
        End If

Azuleanさん、shuさん
無事解決しました。
ありがとうございました。

また、AzuleanさんからヒントをいただいたFindメソッドについても何とかできました。
>（２）Find メソッドで一致条件を判定するデリゲートを渡す。

    Dim fNo As KojinInfo = kojin.Find(AddressOf Findno)
    If fNo.No IsNot Nothing Then
        Console.WriteLine("No=1 --> " & fNo.Name)
    End If
    Dim fName As KojinInfo = kojin.Find(AddressOf FindName)
    If fName.Name IsNot Nothing Then
        Console.WriteLine("Name=鈴木 --> " & fName.Tel)
    End If

    Private Function Findno(ByVal kojin As KojinInfo) As Boolean
        If kojin.No = "1" Then
            Return True
        Else
            Return False
        End If
    End Function

    Private Function FindName(ByVal kojin As KojinInfo) As Boolean
        If kojin.Name = "鈴木" Then
            Return True
        Else
            Return False
        End If
    End Function