C# と VB.NET の質問掲示板

■No54586 (774RR さん) に返信
> ファイル名の 「ロジカルソート」 という奴っすね。
> API の StrCmpLogicalW で出来るっす。
> http://msdn.microsoft.com/en-us/library/bb759947(VS.85).aspx
> 
> こいつの locale の指定がどうなっているのか微妙に不明。
> どっとねっと系からどう呼べばよいのかはまったく知らないので誰か詳しい人にパス。

私はこんな感じで書いてます。

    // ソート方法

    string[] filenames = new string[] {"2010-1.txt","2010-10.txt","2010-5.txt" };
    Array.Sort(filenames, new FileNameComparer());

　　// 以下クラス　

    public class FileNameComparer : IComparer<string>
    {

        public FileNameComparer() 
            : this(false)
        { }

        public FileNameComparer(bool descending)
        {
            if (descending) modifier = -1;
        }

        private readonly int modifier = 1;

        public int Compare(string x, string y)
        {
            return SafeNativeMethods.StrCmpLogicalW(x ?? "", y ?? "") * modifier;
        }

        [SuppressUnmanagedCodeSecurity]
        internal static class SafeNativeMethods
        {
            [DllImport("shlwapi.dll", CharSet = CharSet.Unicode)]
            public static extern int StrCmpLogicalW(string psz1, string psz2);
        }

    } 

■No54590 (ペンネ さん) に返信
> これを参考にVBに変換して試してみます。

変換例。

Imports System.IO
Module Module1

    Private Declare Unicode Function StrCmpLogicalW Lib "SHLWAPI" _
        (ByVal psz1 As String, ByVal psz2 As String) As Integer

    Sub Main()
        Dim dirName As String = "C:\A\B\"

        '取得 & ソート
        Dim q = Directory.GetFiles(dirName).ToList()
        q.Sort(Function(x, y) StrCmpLogicalW(x, y))

        '結果確認
        q.ForEach(AddressOf Console.WriteLine)
    End Sub
End Module

■No54590 (ペンネ さん) に返信
> Algolさん、サンプルありがとうございます。
> これを参考にVBに変換して試してみます。
> ありがとうございました。

あっ… VB でしたか(汗
お詫びにVB(2005 2008で確認)へマイグレーションしてみました。

' 使い方
 Dim filenames As String() = New String() {"2010-1.txt", "2010-10.txt", "2010-5.txt"}
 Array.Sort(filenames, New FileNameComparer())


' クラス

Imports System.Collections.Generic
Imports System.Security
Imports System.Runtime.InteropServices

Public Class FileNameComparer
    Implements IComparer(Of String)

    Public Sub New()
        Me.New(False)
    End Sub

    Public Sub New(ByVal descending As Boolean)
        If (descending) Then Me.modifier = -1
    End Sub

    Private ReadOnly modifier = 1

    Public Function Compare(ByVal x As String, ByVal y As String) As Integer _
        Implements IComparer(Of String).Compare

        Dim psz1 As String = ""
        Dim psz2 As String = ""
        If (String.IsNullOrEmpty(x) = False) Then psz1 = x
        If (String.IsNullOrEmpty(y) = False) Then psz2 = y

        Return SafeNativeMethods.StrCmpLogicalW(psz1, psz2) * Me.modifier
    End Function

End Class

<SuppressUnmanagedCodeSecurity()> _
Friend Module SafeNativeMethods

    <DllImport("shlwapi.dll", CharSet:=CharSet.Unicode)> _
    Public Function StrCmpLogicalW(ByVal psz1 As String, ByVal psz2 As String) As Integer
    End Function

End Module

ついでだから native C++ でも (祭りだ祭りだ)

#if 0 // standard function
bool mycmp(const std::wstring& l, const std::wstring& r) {
    return StrCmpLogicalW(l.c_str(), r.c_str())<0;
}
#endif

#if 1 // functional object
struct mycmp {
    int factor;
    mycmp(int order=1) : factor(order) {}
    bool operator()(const std::wstring& l, const std::wstring& r) const {
        return (factor*StrCmpLogicalW(l.c_str(), r.c_str()))<0;
    }
};
#endif

int main() {
    std::vector<std::wstring> tx;
    tx.push_back(L"2003-4.txt");
    tx.push_back(L"2001-1.txt");
    tx.push_back(L"2001-11.txt");
    tx.push_back(L"2001-3.txt");
    std::sort(tx.begin(), tx.end(), mycmp()); // descending order cmp(-1)
    std::copy(tx.begin(), tx.end(), std::ostream_iterator<std::wstring,wchar_t>(std::wcout, L"\n"));
    return 0;
}