C# と VB.NET の質問掲示板

Imports System.Windows.Forms
Public Class ProcInfoDialog

#Region "■変数　　　　　　　　　　　　"
    Private P_strMsgString As String = ""
    Private P_strChangeString As String = "・"
    Private P_intCnt As Integer = 0
    Private P_image As System.Drawing.Image = Nothing
    Private P_MsgFont As System.Drawing.Font = New System.Drawing.Font("MS UI Gothic", 12)

    '処理中ダイアログを表示するスレッド
    Private thread As System.Threading.Thread = Nothing
    'SyncLock用のオブジェクト

    Private ReadOnly syncObject As New Object()
    '処理中ダイアログが表示されるまで待機するための待機ハンドル
    Private splashShownEvent As System.Threading.ManualResetEvent = Nothing
#End Region

#Region "■プロパティ　　　　　　　　　"

#Region "◇ChangeString                "
    <System.ComponentModel.Description("処理中に変わり続ける文字列を指定します。")> _
   <System.ComponentModel.Category("メッセージ")> _
    Public Property ChangeString As String
        Get
            Return P_strChangeString
        End Get
        Set(ByVal value As String)
            P_strChangeString = value
        End Set
    End Property
#End Region

#Region "◇MsgString                   "
    <System.ComponentModel.Description("処理中表示されるメッセージを指定します。")> _
    <System.ComponentModel.Category("メッセージ")> _
    Public Property MsgString As String
        Get
            Return P_strMsgString
        End Get
        Set(ByVal value As String)
            P_strMsgString = value
        End Set
    End Property
#End Region

#Region "◇Disp                        "
    <System.ComponentModel.Description("処理中表示されるイメージを指定します。")> _
    <System.ComponentModel.Category("イメージ")> _
    Public Property DispImage As System.Drawing.Image
        Get
            Return P_image
        End Get
        Set(ByVal value As System.Drawing.Image)
            P_image = value
        End Set
    End Property
#End Region

#Region "◇MsgFont                     "
    <System.ComponentModel.Description("処理中表示される文字のフォントを指定します。")> _
    <System.ComponentModel.Category("メッセージ")> _
    Public Property MsgFont As System.Drawing.Font
        Get
            Return P_MsgFont
        End Get
        Set(ByVal value As System.Drawing.Font)
            P_MsgFont = value
        End Set
    End Property
#End Region

#End Region

#Region "■処理中ダイアログ表示処理　　"
    ''' <summary>処理中ダイアログ表示処理 </summary>
    ''' <param name="mainForm">メインフォーム</param>
    Public Sub ShowMsgDialog(ByVal mainForm As Form)
        SyncLock syncObject
            If (Not thread Is Nothing) Then
                Return
            End If

            '待機ハンドルの作成
            splashShownEvent = New System.Threading.ManualResetEvent(False)

            'スレッドの作成
            thread = New System.Threading.Thread( _
                New System.Threading.ThreadStart(AddressOf StartThread))
            thread.Name = "ProcInfoDialog"
            thread.IsBackground = True
            thread.SetApartmentState(System.Threading.ApartmentState.STA)
            '.NET Framework 1.1以前では、以下のようにする
            'thread.ApartmentState = System.Threading.ApartmentState.STA
            'スレッドの開始

            thread.Start()
        End SyncLock
    End Sub

    ''' <summary>Splash処理中ダイアログ表示処理表示する</summary>
    Public Sub ShowMsgDialog()
        ShowMsgDialog(Nothing)
    End Sub
#End Region

#Region "■処理中ダイアログ表示処理　　"
    ''' <summary>処理中ダイアログを消す</summary>
    Public Sub CloseMsgDialog()
        SyncLock syncObject
            If thread Is Nothing Then
                Return
            End If

            '処理中ダイアログが表示されるまで待機する

            If Not splashShownEvent Is Nothing Then
                splashShownEvent.WaitOne()
                splashShownEvent.Close()
                splashShownEvent = Nothing
            End If

            '処理中ダイアログを閉じる
            'Invokeが必要か調べる

            If Me.InvokeRequired Then
                Me.Invoke(New MethodInvoker(AddressOf CloseProcInfoDialog))
            Else
                CloseProcInfoDialog()
            End If

            thread = Nothing
        End SyncLock
    End Sub
#End Region

#Region "■スレッドで開始するメソッド　"
    'スレッドで開始するメソッド'
    Private Sub StartThread()
        '処理中ダイアログが表示されるまでCloseMsgDialogメソッドをブロックする'
        AddHandler Me.Activated, AddressOf _form_Activated
        '処理中ダイアログを表示する'
        Application.Run(Me)
    End Sub

#End Region

#Region "■クローズメソッド　　　　　　"
    '処理中ダイアログのCloseメソッドを呼び出す'
    Private Sub CloseProcInfoDialog()
        Me.Close()
    End Sub
#End Region

#Region "■ダイアログが表示されたとき　"
    '処理中ダイアログが表示された時'
    Private Sub _form_Activated(ByVal sender As Object, _
                                       ByVal e As EventArgs)
        RemoveHandler Me.Activated, AddressOf _form_Activated
        'CloseMsgDialogメソッドの待機を解除'
        If Not splashShownEvent Is Nothing Then
            splashShownEvent.Set()
        End If
    End Sub
#End Region

#Region "■オブジェクトイベント　　　　"

#Region "◆フォーム　　　　　　　　　　"

#Region "○Load                        "

    Private Sub ProcInfoDialog_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        'メッセージの表示'
        lblMsg.Text = P_strMsgString

        '変化する文字列が指定されている場合はタイマーを起動します。'
        If P_strChangeString <> "" Then
            timMsg.Enabled = True
            timMsg.Interval = 1000
        End If

        'イメージが設定されていない場合はフォームサイズを小さくします。（ピクチャーボックスを隠す）'
        If P_image Is Nothing Then
            Me.Width = 197
        Else
            picImg.Image = P_image
            Me.Width = 252
        End If

        'フォントの設定

        lblMsg.Font = P_MsgFont
    End Sub
#End Region

#End Region

#Region "◆タイマー　　　　　　　　　　"

#Region "○Tick                        "
    Private Sub timMsg_Tick(ByVal sender As Object, ByVal e As System.EventArgs) Handles timMsg.Tick
        If Me.P_strChangeString <> "" Then
            If P_intCnt = 3 Then P_intCnt = -1
            P_intCnt += 1
            lblMsg.Text = P_strMsgString.PadRight(Len(P_strMsgString) + P_intCnt, CChar(P_strChangeString))
        End If
    End Sub
#End Region

#End Region

#End Region

End Class
==================================================================================

Public Class ProcInfo

#Region "■変数　　　　　　　　　　　　"
    Private P_strMsgString As String = ""
    Private P_strChangeString As String = "・"
    Private P_image As System.Drawing.Image = Nothing
    Private P_MsgFont As System.Drawing.Font = New System.Drawing.Font("MS UI Gothic", 12)
    Private P_ProcInfoMsg As ProcInfoDialog = Nothing
    Private P_BackColor As System.Drawing.Color = Drawing.Color.Aquamarine
#End Region

#Region "■プロパティ　　　　　　　　　"

#Region "◇ChangeString                "
    <System.ComponentModel.Description("処理中に変わり続ける文字列を指定します。")> _
   <System.ComponentModel.Category("メッセージ")> _
    Public Property ChangeString As String
        Get
            Return P_strChangeString
        End Get
        Set(ByVal value As String)
            P_strChangeString = value
        End Set
    End Property
#End Region

#Region "◇MsgString                   "
    <System.ComponentModel.Description("処理中表示されるメッセージを指定します。")> _
    <System.ComponentModel.Category("メッセージ")> _
    Public Property MsgString As String
        Get
            Return P_strMsgString
        End Get
        Set(ByVal value As String)
            P_strMsgString = value
        End Set
    End Property
#End Region

#Region "◇Disp                        "
    <System.ComponentModel.Description("処理中表示されるイメージを指定します。")> _
    <System.ComponentModel.Category("イメージ")> _
    Public Property DispImage As System.Drawing.Image
        Get
            Return P_image
        End Get
        Set(ByVal value As System.Drawing.Image)
            P_image = value
        End Set
    End Property
#End Region

#Region "◇MsgFont                     "
    <System.ComponentModel.Description("処理中表示される文字のフォントを指定します。")> _
    <System.ComponentModel.Category("メッセージ")> _
    Public Property MsgFont As System.Drawing.Font
        Get
            Return P_MsgFont
        End Get
        Set(ByVal value As System.Drawing.Font)
            P_MsgFont = value
        End Set
    End Property
#End Region

#Region "◇BackColor                   "
    Public Property BackColor As System.Drawing.Color
        Get
            Return P_BackColor
        End Get
        Set(ByVal value As System.Drawing.Color)
            P_BackColor = value
        End Set
    End Property
#End Region

#End Region

#Region "■処理中ダイアログ表示処理　　"
    ''' <summary>処理中ダイアログ表示処理 </summary>
    Public Sub ShowMsgDialog()
        P_ProcInfoMsg = New ProcInfoDialog
        With P_ProcInfoMsg
            .MsgString = Me.MsgString
            .ChangeString = Me.ChangeString
            .BackColor = Me.BackColor
            .DispImage = Me.DispImage
        End With

        P_ProcInfoMsg.ShowMsgDialog()

    End Sub

#End Region

#Region "■処理中ダイアログ表示処理　　"
    ''' <summary>処理中ダイアログを消す</summary>
    Public Sub CloseMsgDialog()
        P_ProcInfoMsg.CloseMsgDialog()
        P_ProcInfoMsg.Dispose()
    End Sub
#End Region

End Class

==================================
'呼出画面での処理
 Private Sub Button_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button.Click

   
        
        Dim pd As New ProcInfo
        With pd
            .BackColor = Color.Aquamarine
            .MsgFont = New System.Drawing.Font("MS UI Gothic", 12, FontStyle.Italic)
            If Dir("C:\Icon_Graphic\image.gif") <> "" Then
                .DispImage = System.Drawing.Image.FromFile("C:\Icon_Graphic\image.gif")
            End If
        End With

        pd.ShowMsgDialog()

        MsgBox("エラーメッセージなど")  

        pd.CloseMsgDialog()

    End Sub

■No66879 (taka さん) に返信
> 上に現在試しているソースコードそのまま貼り付けてみました。
投稿された Class は、2 つとも Form なのですよね?


> 「ウィンドウハンドルが作成される前、コントロールでinvokeまたはbegininvokeを呼び出せません」
恐らくは、IsHandleCreated が False の状態だったのかと。


> 'スレッドで開始するメソッド'
> Private Sub StartThread()
>   '処理中ダイアログが表示されるまでCloseMsgDialogメソッドをブロックする'
>   AddHandler Me.Activated, AddressOf _form_Activated
>   '処理中ダイアログを表示する'
>   Application.Run(Me)
> End Sub

上記 Me のインスタンスは、メインスレッドで生成され、
ProcInfo.P_ProcInfoMsg フィールドで管理されていますので、
それをワーカー側で扱うのは望ましくありません。
ワーカー側で表示されるフォームは、ワーカー側で管理すべきかと。



> '呼出画面での処理
やりたいことは
　pd = New 進捗管理クラス()
　pd.BackColor = 進捗フォームの背景色
　pd.ShowMsgDialog()  '進捗フォームを別スレッドで非同期表示
　'　：
　'メインスレッド側の処理
　'　：
　pd.ClosMsgDialog()  '進捗フォームの終了要求
で宜しいでしょうか?

だとすればこの場合、「進捗管理クラス」を Form にするのではなく、
「進捗管理クラスが、内部で Private な Form を表示させる」だけにします。



単純な実装としてはこんな感じ。

Imports System.Drawing
Imports System.ComponentModel

Public Class Form1
    Inherits Form

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        '実際には匿名型ではなく、明示的な型を用意した方が良いでしょう
        Dim 設定値 = New With {
            .BackColor = Color.Cyan,
  　        .ImageFile = "C:\Icon_Graphic\image.gif",
            .MsgFont = New Font("MS UI GothicD", 12, FontStyle.Italic)
        }

        '下記では、テストしやすいよう BackgroundWorker を使っていますが
        '実際には再利用しやすいように 進捗管理クラス を別途用意しておき、
        'そのクラス内でワーカースレッドを作成するようにしてみてください
        Me.BackgroundWorker1.WorkerSupportsCancellation = True
        Me.BackgroundWorker1.RunWorkerAsync(設定値)

        MsgBox("エラーメッセージなど")

        '終了依頼
        BackgroundWorker1.CancelAsync()
    End Sub

    Private Sub BackgroundWorker1_DoWork(sender As Object, e As DoWorkEventArgs) Handles BackgroundWorker1.DoWork
        Dim 設定値 = e.Argument
        Dim bgw = DirectCast(sender, BackgroundWorker)

        Dim f As New Form2()
        f.BackColor = 設定値.BackColor
        f.Label1.Font = 設定値.MsgFont
        f.PictureBox1.LoadAsync(設定値.ImageFile)
        f.Timer1.Interval = 72
        f.Timer1.Start()
        AddHandler f.Timer1.Tick, Sub() If bgw.CancellationPending Then f.Close()
        f.Timer1.Start()
        Application.Run(f)
    End Sub

    '外部から直接呼ばれないよう、Private Class にした方が安全かも
    'Private Class Form2
    '    Inherits Form
    '    '    ：
    'End Sub
End Class


ただし、これはあまり好ましい実装ではありません。
メイン画面で時間のかかる処理が行われれば、アプリケーションが
暫く応答なし状態になる点は変わりませんし、先の投稿で問題視されていた
進捗画面とメイン画面の ZOrder 順に関する問題を抱える結果にもなるからです。

先にも少し書きましたが、UI の扱いはメインスレッドに任せておき、
時間のかかる作業の方をワーカースレッドに任せるのが、本来の対処方法です。


> 処理にはデータ表示を含んでおり、画面部品に依存しております。
データ表示だけ、相手に依頼してあげてください。

ワーカースレッドが、自身でデータを表示するのではなく、
ワーカースレッドが、UI スレッドにデータを BeginInvoke で渡して、
UI スレッド自身に表示させる形をとります。
(InvokeRequired プロパティの解説なども参考に)


> 1秒で終了してしまうこともあります。
ちなみに Windows 8 のストアアプリでは、
わずかでも時間のかかる可能性のある処理(50ミリ秒以上が目安)は、
全て非同期処理にすることが求められています。