C# と VB.NET の質問掲示板

windows10 VisualStudio2019 VB.NET .NETFramework4.7.2

以上の環境で三菱電機のシーケンサーと通信し、特定のデバイスからデータを読み込み、
そのデバイスのデータを2進数に変換(0000000000000000)し、
そのうちの特定の1ビットがONになればブザーと赤色の表示がでる。
OFFになればブザーと赤色の表示が消える。

ONの時にボタンをクリックすればブザーが消える。
というプログラムを作成しました。

途中までは順調に動くのですが、30〜60分経過すると必ずエラーが発生し、落ちてしまいます。

エラー内容は以下になります。
マネージド デバッグ アシスタント 'FatalExecutionEngineError' 
  Message=マネージド デバッグ アシスタント 'FatalExecutionEngineError' : 'ランタイムの重大なエラーが発生しました。エラーのアドレスは 0x67367f25、スレッド 0x7384 です。エラー コードは 0xc0000005 です。これは CLR のバグであるか、またはユーザー コードのアンセーフまたは確認不可能な部分にバグがある可能性があります。このバグの一般的な原因には、スタックが壊れる可能性のある COM-interop または PInvoke のユーザー マーシャリング エラーが含まれています。'

コードは以下になります。

Public Class Form1
    Public IRet As Long
    Public DataX(0) As Integer
    Public flg1 As Integer
    Public flg2 As Integer
    Public flg3 As Integer
    Public flg4 As Integer
    Public flg5 As Integer
    'Public flg6 As Integer
    Public X16to2 As Integer
    Public XtoSt As String

    Private Sub Timer1_Tick(ByVal eventSender As System.Object, ByVal eventArgs As System.EventArgs) Handles Timer1.Tick


        IRet = AxActUtlType1.Open()

        'X20のデバイスブロックの16ビット分にDataX(0)として格納したデータを読み込む
        IRet = AxActUtlType1.ReadDeviceBlock("X20", 16, DataX(0))
        If IRet <> 0 Then Exit Sub

        'DataX(0)16進数を2進数に変換
        X16to2 = Convert.ToString(DataX(0), 2)
        XtoSt = Format(X16to2, "0000000000000000")
        TextBox1.Text = XtoSt 'テスト用

        'XtoStの左から13番目が1であれば警報
        If Mid(XtoSt, 13, 1) = "1" Then
            If flg1 = 0 Then
                Console.Beep(1500, 1000)
            End If
            RectangleShape1.BackColor = System.Drawing.Color.Red
            Label1.BackColor = System.Drawing.Color.Red
        Else
            flg1 = 0
            RectangleShape1.BackColor = System.Drawing.SystemColors.GradientInactiveCaption
            Label1.BackColor = System.Drawing.SystemColors.GradientInactiveCaption
        End If

        If Mid(XtoSt, 12, 1) = "1" Then
            If flg2 = 0 Then
                Console.Beep(1500, 1000)
            End If
            RectangleShape2.BackColor = System.Drawing.Color.Red
            Label2.BackColor = System.Drawing.Color.Red
        Else
            flg2 = 0
            RectangleShape2.BackColor = System.Drawing.SystemColors.GradientInactiveCaption
            Label2.BackColor = System.Drawing.SystemColors.GradientInactiveCaption
        End If

        If Mid(XtoSt, 11, 1) = "1" Then
            If flg3 = 0 Then
                Console.Beep(1500, 1000)
            End If
            RectangleShape3.BackColor = System.Drawing.Color.Red
            Label3.BackColor = System.Drawing.Color.Red
        Else
            flg3 = 0
            RectangleShape3.BackColor = System.Drawing.SystemColors.GradientInactiveCaption
            Label3.BackColor = System.Drawing.SystemColors.GradientInactiveCaption
        End If

        If Mid(XtoSt, 10, 1) = "1" Then
            If flg4 = 0 Then
                Console.Beep(1500, 1000)
            End If
            RectangleShape4.BackColor = System.Drawing.Color.Red
            Label4.BackColor = System.Drawing.Color.Red
        Else
            flg4 = 0
            RectangleShape4.BackColor = System.Drawing.SystemColors.GradientInactiveCaption
            Label4.BackColor = System.Drawing.SystemColors.GradientInactiveCaption
        End If

        If Mid(XtoSt, 9, 1) = "1" Then
            If flg5 = 0 Then
                Console.Beep(1500, 1000)
            End If
            RectangleShape5.BackColor = System.Drawing.Color.Red
            Label5.BackColor = System.Drawing.Color.Red
        Else
            flg5 = 0
            RectangleShape5.BackColor = System.Drawing.SystemColors.GradientInactiveCaption
            Label5.BackColor = System.Drawing.SystemColors.GradientInactiveCaption
        End If

        If Mid(XtoSt, 8, 1) = "1" Then
            'If flg6 = 0 Then
            'Beep()
            'End If
            RectangleShape6.BackColor = System.Drawing.Color.Yellow
            Label6.BackColor = System.Drawing.Color.Yellow
        Else
            'flg6 = 0
            RectangleShape6.BackColor = System.Drawing.SystemColors.GradientInactiveCaption
            Label6.BackColor = System.Drawing.SystemColors.GradientInactiveCaption
        End If



    End Sub



    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

        If flg1 = 0 Then flg1 = 1
        If flg2 = 0 Then flg2 = 1
        If flg3 = 0 Then flg3 = 1
        If flg4 = 0 Then flg4 = 1
        If flg5 = 0 Then flg5 = 1
        'If flg6 = 0 Then flg6 = 1
    End Sub

End Class

エラーが発生する原因について何が考えられそうでしょうか。
よろしくお願い致します。

■No100157 (初心者HK さん) に返信
> windows10 VisualStudio2019 VB.NET .NETFramework4.7.2

ActiveX コンポーネント + Visual Basic PowrPacks + .NET Framework 4.7.2 ですか・・・
.NET Framework 3.5 という選択肢はなかったんでしょうか？

>         IRet = AxActUtlType1.Open()

Open() があるのに Close() が見当たりませんが大丈夫ですか？

>         'X20のデバイスブロックの16ビット分にDataX(0)として格納したデータを読み込む
>         IRet = AxActUtlType1.ReadDeviceBlock("X20", 16, DataX(0))
>         If IRet <> 0 Then Exit Sub

エラーが発生したら Close() しないで抜けてしまいますが、大丈夫ですか？

https://www.mitsubishielectric.co.jp/fa/download/software/detailsearch.do?mode=software&kisyu=/plc_fx&shiryoid=0000000028&lang=1&select=0&softid=1&infostatus=2_5_1&viewradio=0&viewstatus=&viewpos=

上のページからダウンロードできる 「MX Component Version 4 プログラミングマニュアル」の 354〜355ページに

■Visual Basic .NET
IRet = object.ReadDeviceBlock(szDevice, iSize, iData(0))

Integer  IRet       戻り値               Output
String   szDevice   デバイス名           Input
Integer  iSize      読出し点数           Input
Integer  iData(n)   読み出したデバイス値 Output

説明
・szDevice(varDevice)にて指定したデバイスから，lSize(varSizeまたはiSize)分のデバイス値を一括して読み出します。
・読み出したデバイス値は，lData(lplData，lpvarData，またはiData)に格納されます。
・lData(lplData，lpvarData，またはiData)は，lSize(varSizeまたはiSize)以上の配列を確保してください。

とあります。

Public DataX(0) As Integer

では足りないのでは？

ざっと見た感じ、配列の数は１つだけで良さそうなので

  IRet = AxActUtlType1.ReadDeviceBlock("X20", 1, DataX(0))

とするといいんじゃないでしょうか。

■No100176 (初心者HK さん) に返信

解決して良かったです。
ところでコーディングについて２つほど指摘させてください。

(1) メソッドを分けて見通しよく

ラベルや RectangleShape の色を変えたり、音を鳴らす部分は別のメソッドにしたほうがいいかと思います。

Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick
    IRet = AxActUtlType1.Open()
    If IRet <> 0 Then Return
    Try
        IRet = AxActUtlType1.ReadDeviceBlock("X20", 1, DataX(0))
        If IRet <> 0 Then
            Return ' ここで抜けても Finally ブロックで Close が実行される
        End If
        SetControls()
    Finally
        AxActUtlType1.Close()
    End Try
End Sub

のようにして、Sub SetControls の中に書きます。

(2) 同じような繰り返し処理はまとめる

Beep 音を鳴らす、フラグをゼロクリアする、色を変えるという一連の処理はまとめることが出来そうです。

Private Sub SetRepeat(index As Integer, ByRef flg As Integer, shape As RectangleShape, label As Label)
    If Mid(XtoSt, index, 1) = "1" Then
        If flg = 0 AndAlso index <> 8 Then ' index が 8 のときは音を鳴らさない
            Console.Beep(1500, 1000)
        End If
        shape.BackColor = Color.Red
        label.BackColor = Color.Red
    Else
        flg = 0
        shape.BackColor = SystemColors.GradientInactiveCaption
        label.BackColor = SystemColors.GradientInactiveCaption
    End If
End Sub

これを、先ほどの SetControls の中から呼び出します。
(flg6 もコメントアウトを解除します。）

Private Sub SetControls()
    'DataX(0)16進数を2進数に変換
    X16to2 = Convert.ToString(DataX(0), 2)
    XtoSt = Format(X16to2, "0000000000000000")
    TextBox1.Text = XtoSt 'テスト用
    SetRepeat(13, flg1, RectangleShape1, Label1)
    SetRepeat(12, flg2, RectangleShape2, Label2)
    SetRepeat(11, flg3, RectangleShape3, Label3)
    SetRepeat(10, flg4, RectangleShape4, Label4)
    SetRepeat(9, flg5, RectangleShape5, Label5)
    SetRepeat(8, flg6, RectangleShape6, Label6)
End Sub