C# と VB.NET の質問掲示板

■No103146 (かんぼ さん) に返信
> FirstDisplayedCell だとセルごとにしか
> 表示領域を設定できないので
> 同じセルの中で表示できていない領域を表示することはできないのではないでしょうか？

完全に読み違えてました。

編集状態にすればスクロールバーが出せますが、どのようにしたいんでしょうか？

Private Sub DataGridView1_EditingControlShowing(
        sender As Object, e As DataGridViewEditingControlShowingEventArgs) _
        Handles DataGridView1.EditingControlShowing
    Dim textBox = TryCast(DataGridView1.EditingControl, TextBox)
    If textBox IsNot Nothing Then
        If textBox.Multiline Then
            textBox.ScrollBars = ScrollBars.Vertical
        Else
            textBox.ScrollBars = ScrollBars.None
        End If
    End If
End Sub

■No103154 (かんぼ さん) に返信

なるほど、こういう状態ですね。

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    With DataGridView1
        Const fiveLinesValue = "1" & vbCrLf & "2" & vbCrLf & "3" & vbCrLf & "4" & vbCrLf & "5"
        Dim fiveLinesHeight As Integer
        Using g = .CreateGraphics()
            fiveLinesHeight = TextRenderer.MeasureText(g, fiveLinesValue, .Font).Height + 5
        End Using
        Dim cs = DataGridView1.ClientSize
        .ClientSize = New Size(cs.Width, fiveLinesHeight + .ColumnHeadersHeight)
        .Columns.Add(New DataGridViewTextBoxColumn With {.HeaderText = "Column1"})

        Dim columnValue = "A1" & vbCrLf & "A2" & vbCrLf & "A3" & vbCrLf & "A4" &
                         vbCrLf & "A5" & vbCrLf & "A6" & vbCrLf & "A7"
        .Rows.Add(columnValue)
        .Rows.Add(columnValue.Replace("A", "B"))
        .DefaultCellStyle.WrapMode = DataGridViewTriState.True
        .AutoSizeRowsMode = DataGridViewAutoSizeRowsMode.AllCells
    End With
End Sub

行の高さがクライアント領域をはみ出すから問題なので、はみ出さないよう調整すればよいと思います。

Private Sub AdjustRowHeight(dgv As DataGridView)
    With dgv
        .DefaultCellStyle.WrapMode = DataGridViewTriState.True
        .AutoSizeRowsMode = DataGridViewAutoSizeRowsMode.AllCells
        Dim maxRowHeight = .ClientSize.Height - .ColumnHeadersHeight - 1
        Dim rowHeights = .Rows.Cast(Of DataGridViewRow).Select(Function(r) r.Height).ToArray()
        .AutoSizeRowsMode = DataGridViewAutoSizeRowsMode.None
        For i = 0 To rowHeights.Length - 1
            If rowHeights(i) > maxRowHeight Then
                .Rows(i).Height = maxRowHeight
            Else
                .Rows(i).Height = rowHeights(i)
            End If
        Next
    End With
End Sub

そうすれば、編集状態にしたときのスクロールバーが生きます。
中身を編集したくないのであれば、ReadOnly にします。

Private Sub DataGridView1_EditingControlShowing(
    sender As Object, e As DataGridViewEditingControlShowingEventArgs) _
    Handles DataGridView1.EditingControlShowing

    Dim editingControl = TryCast(e.Control, DataGridViewTextBoxEditingControl)
    If editingControl IsNot Nothing Then
        editingControl.ReadOnly = True
        If editingControl.Multiline Then
            editingControl.ScrollBars = ScrollBars.Vertical
        Else
            editingControl.ScrollBars = ScrollBars.None
        End If
    End If
End Sub

マウスホイールで行がスクロールするのが嫌であれば 
DataGridView を継承してカスタムコントロールを作って

Public Class DataGridViewEx
    Inherits DataGridView

    Protected Overrides Sub OnMouseWheel(e As MouseEventArgs)
        If Not IsCurrentCellInEditMode Then
            MyBase.OnMouseWheel(e)
        End If
    End Sub

End Class

としてください。

水平スクロールバーのことを忘れていました。

Dim maxRowHeight = .ClientSize.Height - .ColumnHeadersHeight - 1

としていましたが、

Dim maxRowHeight = .DisplayRectangle.Height - .ColumnHeadersHeight - 1

が正しいです。

ただ、水平スクロールバーが表示されたというイベントがありません。
マウスホイールのこともあるし、カスタムコントロール側で行ったほうがよさそうです。

Public Class DataGridViewEx
    Inherits DataGridView

    Public Sub New()
        AddHandler HorizontalScrollBar.VisibleChanged, AddressOf HorizontalScrollBar_VisibleCganged
    End Sub

    Protected ReadOnly Property MaxRowHeight As Integer
        Get
            Return DisplayRectangle.Height - ColumnHeadersHeight - 1
        End Get
    End Property

    Private Sub HorizontalScrollBar_VisibleCganged(sender As Object, e As EventArgs)
        AdjustRows()
    End Sub

    Protected Overrides Sub OnMouseWheel(e As MouseEventArgs)
        If Not IsCurrentCellInEditMode Then
            MyBase.OnMouseWheel(e)
        End If
    End Sub

    Public Sub AdjustRows()
        AutoSizeRowsMode = DataGridViewAutoSizeRowsMode.AllCells
        Dim rowHeights = Rows.Cast(Of DataGridViewRow).Select(Function(r) r.Height).ToArray()
        AutoSizeRowsMode = DataGridViewAutoSizeRowsMode.None
        For i = 0 To rowHeights.Length - 1
            If rowHeights(i) > MaxRowHeight Then
                Rows(i).Height = MaxRowHeight
            Else
                Rows(i).Height = rowHeights(i)
            End If
        Next
    End Sub

    Public Sub AdjustRow(index As Integer)
        Dim row = Rows(index)
        AutoResizeRow(index, DataGridViewAutoSizeRowMode.AllCells)
        If row.Height > MaxRowHeight Then
            row.Height = MaxRowHeight
        End If
    End Sub

    Protected Overrides Sub OnResize(e As EventArgs)
        MyBase.OnResize(e)
        AdjustRows()
    End Sub

    Private IsReadOnlyColumnState As Boolean
    Private IsReadOnlyRowState As Boolean
    Private IsReadOnlyCellState As Boolean
    Private IsReadOnlyCell As Boolean

    Private Sub SaveReadOnly(cell As DataGridViewCell)
        IsReadOnlyColumnState = Columns(cell.ColumnIndex).State.HasFlag(DataGridViewElementStates.ReadOnly)
        IsReadOnlyRowState = Rows(cell.RowIndex).State.HasFlag(DataGridViewElementStates.ReadOnly)
        IsReadOnlyCellState = cell.State.HasFlag(DataGridViewElementStates.ReadOnly)
        IsReadOnlyCell = cell.ReadOnly

        Me.ReadOnly = False
        Columns(cell.ColumnIndex).ReadOnly = False
        Rows(cell.RowIndex).ReadOnly = False
        cell.ReadOnly = False
    End Sub

    Private Sub RestoreReadOnly(cell As DataGridViewCell)
        Columns(cell.ColumnIndex).ReadOnly = IsReadOnlyColumnState
        Rows(cell.RowIndex).ReadOnly = IsReadOnlyRowState
        cell.ReadOnly = IsReadOnlyCell
    End Sub

    Protected Overrides Sub OnCellEnter(e As DataGridViewCellEventArgs)
        Dim cell = Me(e.ColumnIndex, e.RowIndex)
        If TypeOf cell Is DataGridViewTextBoxCell Then
            SaveReadOnly(Me(e.ColumnIndex, e.RowIndex))
        End If
        MyBase.OnCellEnter(e)
    End Sub

    Protected Overrides Sub OnCellLeave(e As DataGridViewCellEventArgs)
        Dim cell = Me(e.ColumnIndex, e.RowIndex)
        If TypeOf cell Is DataGridViewTextBoxCell Then
            RestoreReadOnly(Me(e.ColumnIndex, e.RowIndex))
        End If
        MyBase.OnCellLeave(e)
    End Sub

    Protected Overrides Sub OnEditingControlShowing(e As DataGridViewEditingControlShowingEventArgs)
        MyBase.OnEditingControlShowing(e)
        Dim textBox = TryCast(e.Control, DataGridViewTextBoxEditingControl)
        If textBox IsNot Nothing Then
            textBox.ReadOnly = IsReadOnlyCell
            If textBox.Multiline Then
                textBox.ScrollBars = ScrollBars.Vertical
            Else
                textBox.ScrollBars = ScrollBars.None
            End If
        End If
    End Sub

    Protected Overrides Sub OnCellValueChanged(e As DataGridViewCellEventArgs)
        MyBase.OnCellValueChanged(e)
        AdjustRow(e.RowIndex)
    End Sub

End Class

考慮漏れなどあるかもしれませんが、カスタムコントロール側に手をいれるか、
AdjustRows/AdjustRow メソッドを本体側で呼び出してください。

ありがとうございます。

Visual Studio2022 
.NET Framework4.7.2

の環境で

DataGridViewExを宣言した上で、
フォーム上にDataGridViewExを一つだけ配置し、
以下を実行していますが、
想定通りの挙動にはなりません。

どこを修正すればよろしいでしょうか？


Public Class Form1
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load

        With DataGridViewEx1
            Const fiveLinesValue = "1" & vbCrLf & "2" & vbCrLf & "3" & vbCrLf & "4" & vbCrLf & "5"
            Dim fiveLinesHeight As Integer
            Using g = .CreateGraphics()
                fiveLinesHeight = TextRenderer.MeasureText(g, fiveLinesValue, .Font).Height + 5
            End Using
            Dim cs = DataGridViewEx1.ClientSize
            .ClientSize = New Size(cs.Width, fiveLinesHeight + .ColumnHeadersHeight)
            .Columns.Add(New DataGridViewTextBoxColumn With {.HeaderText = "Column1"})

            Dim columnValue = "A1" & vbCrLf & "A2" & vbCrLf & "A3" & vbCrLf & "A4" &
                             vbCrLf & "A5" & vbCrLf & "A6" & vbCrLf & "A7"
            .Rows.Add(columnValue)
            .Rows.Add(columnValue.Replace("A", "B"))
            .DefaultCellStyle.WrapMode = DataGridViewTriState.True
            .AutoSizeRowsMode = DataGridViewAutoSizeRowsMode.AllCells


            Call AdjustRowHeight(DataGridViewEx1)

            '  Call DataGridViewEx1.AdjustRow()
            Call DataGridViewEx1.AdjustRows()


        End With


    End Sub

    Private Sub AdjustRowHeight(dgv As DataGridViewEx)
        With dgv
            .DefaultCellStyle.WrapMode = DataGridViewTriState.True
            .AutoSizeRowsMode = DataGridViewAutoSizeRowsMode.AllCells
            Dim maxRowHeight = .ClientSize.Height - .ColumnHeadersHeight - 1
            Dim rowHeights = .Rows.Cast(Of DataGridViewRow).Select(Function(r) r.Height).ToArray()
            .AutoSizeRowsMode = DataGridViewAutoSizeRowsMode.None
            For i = 0 To rowHeights.Length - 1
                If rowHeights(i) > maxRowHeight Then
                    .Rows(i).Height = maxRowHeight
                Else
                    .Rows(i).Height = rowHeights(i)
                End If
            Next
        End With
    End Sub


    Private Sub DataGridView1_EditingControlShowing(
    sender As Object, e As DataGridViewEditingControlShowingEventArgs) _
    Handles DataGridViewEx1.EditingControlShowing

        Dim editingControl = TryCast(e.Control, DataGridViewTextBoxEditingControl)
        If editingControl IsNot Nothing Then
            editingControl.ReadOnly = True
            If editingControl.Multiline Then
                editingControl.ScrollBars = ScrollBars.Vertical
            Else
                editingControl.ScrollBars = ScrollBars.None
            End If
        End If
    End Sub


End Class