C# と VB.NET の質問掲示板

開発環境
Windows 11 pro
C#
VS2019
.NET Framework 4.7.2
Windowsフォームアプリケーション（.Net Framework）でプロジェクトを作成しています。

2年前にも同じ質問（101639）をさせていただきました。

【現象】
Windows 10では問題なかったフォーム画面が、
Windows 11では、Surface Go 4 でキーボード（タイプカバー）を外すと勝手に最大化される。

【原因】
Windows 11では「タブレットモード」が廃止され、自動的に端末の状態（キーボード有無）に応じたモード切り替えが行われる。
タイプカバーを外すとタブレットとして認識され、フォームが最大化される動きになる。

【対策】
MaximizeBox：False に設定する
または、Windows 10 にダウングレード

今回、Winodows10 のサポートがきれるということで再度解決策を考えているところです。

レジストリを修正することでモードを切り替えることはできました。
しかし、もう少し良くしたい箇所があります。

改善策1：バッチファイルでモード切替
下記URL を参考にタスクスケジュールに設定しました。
https://qiita.com/kazu_iroiro/items/15e6ee3a6f1d1b66e48a
モードの切り替えはできましたが、変更時に画面が一瞬チラつく問題がある。
タイプカバーの脱着以外でも実行されて、チラつきが多いです。


改善策2：フォームのロード時にモード切替
起動時のフォームにロード時の処理を追加しました。
モードの切替自体はできました。
しかし、起動時のフォームにはモードが適用されないので、PGを閉じて再度開く作業必要です。

        private void SetConvertibleSlateMode()
       {
            const string regPath = @"SYSTEM\CurrentControlSet\Control\PriorityControl";
            const string regName = "ConvertibleSlateMode";

            using (RegistryKey key = Registry.LocalMachine.OpenSubKey(regPath, writable: true))
            {
                if (key != null)
                {
                    key.SetValue(regName, 1, RegistryValueKind.DWord);
                }
                else
                {
                    throw new Exception("レジストリキーが開けませんでした。");
                }
            }
        }

        private bool IsRunAsAdmin()
        {
            try
            {
                WindowsIdentity identity = WindowsIdentity.GetCurrent();
                WindowsPrincipal principal = new WindowsPrincipal(identity);
                return principal.IsInRole(WindowsBuiltInRole.Administrator);
            }
            catch
            {
                return false;
            }
        }

        private void Form1_Load(object sender, EventArgs e)
        {
            try
            {
                if (IsRunAsAdmin())
                {
                    SetConvertibleSlateMode();
                    MessageBox.Show("ConvertibleSlateMode を 1 に設定しました。", "成功", MessageBoxButtons.OK, MessageBoxIcon.Information);
                }
                else
                {
                    MessageBox.Show("レジストリの変更には管理者権限が必要です。", "権限エラー", MessageBoxButtons.OK, MessageBoxIcon.Error);
                }
            }
            catch (Exception ex)
            {
                MessageBox.Show($"エラーが発生しました: {ex.Message}", "エラー", MessageBoxButtons.OK, MessageBoxIcon.Error);
            }
        }


教えていただきたいこと
・タスク実行時の画面チラつき防止
・PG再起動なしでモードを切り替える方法

その他、別方法がございましたら、お教えください。
よろしくお願いいたします。

■No103650 (河童 さん) に返信

こちらの内容であっているのかな？
https://learn.microsoft.com/ja-jp/windows-hardware/design/device-experiences/continuum
環境がないので試せないけれども
モード切り替え時に
・WM_SETTINGCHANGE
https://learn.microsoft.com/ja-jp/windows/win32/winmsg/wm-settingchange
がWinProcに届くみたい
'#define WM_WININICHANGE                 0x001A
'#define WM_SETTINGCHANGE                WM_WININICHANGE

Const WM_WININICHANGE As Integer = &H001A
WinProcのサンプルは
https://dobon.net/vb/dotnet/form/fixformposition.html
から拝借で

実際は以下の通りで動くかな？
----- Form1というフォームを作成したとして -----

Imports System.Runtime.InteropServices
Imports System.Security.Permissions

Public Class Form1

    ''' <summary>
    ''' アクティブな入力ロケール識別子 (以前はキーボード レイアウトと呼ばれます) を取得します。
    ''' https://learn.microsoft.com/ja-jp/windows/win32/api/winuser/nf-winuser-getkeyboardlayout
    ''' </summary>
    ''' <param name="idThread"></param>
    ''' <returns></returns>
    <DllImport("User32.dll", SetLastError:=True)>
    Private Shared Function GetKeyboardLayout(
            idThread As Integer
        ) As IntPtr
    End Function

    ''' <summary>
    ''' キーボードが接続してるかを取得します。
    ''' </summary>
    ''' <param name="value">HRESULT。</param>
    ''' <returns>キーボードが接続してる true。それ以外の場合は false。</returns>
    Private Function IsKeyboardConnected() As Boolean
        Return (GetKeyboardLayout(0) <> IntPtr.Zero)
    End Function

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        If IsKeyboardConnected() = True Then
            Me.MaximizeBox = False
        Else
            Me.MaximizeBox = True
        End If
    End Sub

    <SecurityPermission(SecurityAction.Demand,
    Flags:=SecurityPermissionFlag.UnmanagedCode)>
    Protected Overrides Sub WndProc(ByRef m As Message)
        Const WM_SETTINGCHANGE As Integer = &H1A

        If m.Msg = WM_SETTINGCHANGE Then
            ' SystemParametersInfo 関数がシステム全体の設定を変更した時
            'https://learn.microsoft.com/ja-jp/windows/win32/winmsg/wm-settingchange

            If IsKeyboardConnected() = True Then
                Me.MaximizeBox = False
            Else
                Me.MaximizeBox = True
            End If
        End If

        MyBase.WndProc(m)
    End Sub
End Class

----------------

訂正(編集キー入れてなくって修正できない...)
誤り
            If IsKeyboardConnected() = True Then
                Me.MaximizeBox = False
            Else
                Me.MaximizeBox = True
            End If
正解
            If IsKeyboardConnected() = True Then
                Me.MaximizeBox = True
            Else
                Me.MaximizeBox = False
            End If
ですよね...

多分以下の仕組みでタブレットモード?の時は「最大化」はしないようになるはず
仕組みは
1. フォームに「最大化」してと要求があった時
2. デバイスのキーボードを検索
3. キーボードが1件もない場合、タブレットモードとして判定
4. タブレットモードの場合、「最大化」をキャンセルする。

ただ正確には「Surface Go 4」のキーボードデバイスが接続しているか?なんだよね...
メーカーが違うとその機種専用のキーボードで判断してるから
どっかに判定値が入っていてそれで判断してると思う。

環境がないもので推測ばっかりで申し訳ないです。

----- Form3というフォーム(Form3.vb)を作成したとして -----
Imports System.Security.Permissions

Public Class Form3

    <SecurityPermission(SecurityAction.Demand,
    Flags:=SecurityPermissionFlag.UnmanagedCode)>
    Protected Overrides Sub WndProc(ByRef m As Message)
        'Const WM_SETTINGCHANGE As Integer = &H1A
        'Const WM_DEVICECHANGE As Integer = &H219
        'Const DBT_DEVNODES_CHANGED = &H7            'デバイスがシステムに追加されたか、システムから削除されました。
        'Const DBT_QUERYCHANGECONFIG = &H17          '現在の構成を変更するためのアクセス許可が要求されます (ドッキングまたはドッキング解除)。
        'Const DBT_CONFIGCHANGED = &H18              'ドッキングまたはドッキング解除により、現在の構成が変更されました。
        'Const DBT_CONFIGCHANGECANCELED = &H19       '現在の構成を変更する要求 (ドックまたはドッキング解除) が取り消されました。
        'Const DBT_DEVICEARRIVAL = &H8000            'デバイスまたはメディアが挿入され、使用可能になりました。
        'Const DBT_DEVICEQUERYREMOVE = &H8001        'デバイスまたはメディアの一部を削除するためのアクセス許可が要求されます。 どのアプリケーションでも、この要求を拒否し、削除を取り消すことができます。
        'Const DBT_DEVICEQUERYREMOVEFAILED = &H8002  'デバイスまたはメディアの一部を削除する要求が取り消されました。
        'Const DBT_DEVICEREMOVEPENDING = &H8003      'デバイスまたはメディアの一部が削除されようとしています。 拒否できません。
        'Const DBT_DEVICEREMOVECOMPLETE = &H8004     'デバイスまたはメディアが削除されました。
        'Const DBT_DEVICETYPESPECIFIC = &H8005       'デバイス固有のイベントが発生しました。
        'Const DBT_CUSTOMEVENT = &H8006              'カスタム イベントが発生しました。
        'Const DBT_USERDEFINED = &HFFFF              'このメッセージの意味は、ユーザー定義です。
        Const WM_SYSCOMMAND As Integer = &H112
        Const SC_MAXIMIZE = &HF030                  'ウィンドウを最大化します。

        'Debug.Print("WndProc m.Msg = &h{0:X}", m.Msg)

        Select Case m.Msg
            'Case WM_DEVICECHANGE
            '    'デバイスまたはコンピューターのハードウェア構成の変更をアプリケーションに通知します。
            '    'https://learn.microsoft.com/ja-jp/windows/win32/devio/wm-devicechange
            '    Debug.Print("WM_DEVICECHANGE {0} {1}", m.WParam, m.LParam)
            '    'デスクトップPCでキーボードのUSBを抜き差しすると
            '    'm.WParam = DBT_DEVNODES_CHANGED が発生
            '    'GetKeyboardLayout APIでも取得できてるし...

            '    'Surface Go 4　だと
            '    'm.WParam = DBT_QUERYCHANGECONFIG
            '    'm.WParam = DBT_CONFIGCHANGED
            '    'かな？
            '    Select Case m.WParam.ToInt64
            '        Case DBT_DEVNODES_CHANGED
            '    End Select

            'Case WM_SETTINGCHANGE
            '    ' SystemParametersInfo 関数がシステム全体の設定を変更した時
            '    'https://learn.microsoft.com/ja-jp/windows/win32/winmsg/wm-settingchange

            Case WM_SYSCOMMAND
                '最大化ボタン、最小化ボタン、復元ボタン、または閉じるボタンを選択したときに
                'https://learn.microsoft.com/ja-jp/windows/win32/menurc/wm-syscommand
                Select Case (m.WParam.ToInt64() And &HFFF0L)
                    Case SC_MAXIMIZE
                        ' キーボードが未接続の状態
                        If Devices.IsKeyboardConnected() = False Then
                            ' WndProc標準処理をスキップする事で最大化をさせない。
                            m.Result = IntPtr.Zero
                            Return
                        End If
                End Select
        End Select

        ' WndProc標準処理を行う
        MyBase.WndProc(m)

    End Sub

End Class
----- Form3終わり -----
----- Devicesというモジュールファイル(Devices.vb)だとして -----
Imports System.Runtime.InteropServices

Module Devices

    Private Const RIM_TYPEKEYBOARD As Integer = 1

    Private Const RIDI_DEVICENAME As Integer = &H20000007

    <StructLayout(LayoutKind.Sequential)>
    Private Structure RAWINPUTDEVICELIST
        Public hDevice As IntPtr
        <MarshalAs(UnmanagedType.U4)>
        Public dwType As Integer
    End Structure

    <StructLayout(LayoutKind.Sequential)>
    Private Structure RAWINPUTDEVICE
        <MarshalAs(UnmanagedType.U2)>
        Public usUsagePage As System.UInt16
        <MarshalAs(UnmanagedType.U2)>
        Public usUsage As System.UInt16
        <MarshalAs(UnmanagedType.U4)>
        Public dwFlags As Integer
        Public hwndTarget As IntPtr
    End Structure

    <DllImport("User32.dll", SetLastError:=True)>
    Private Function GetRawInputDeviceList(
            ByVal pRawInputDeviceList As IntPtr,
            ByRef uiNumDevices As UInteger,
            ByVal cbSize As UInteger
        ) As UInteger
    End Function

    <DllImport("User32.dll", SetLastError:=True)>
    Private Function GetRawInputDeviceInfo(
             ByVal hDevice As IntPtr,
             ByVal uiCommand As UInteger,
             ByVal pData As IntPtr,
             ByRef pcbSize As UInteger
        ) As UInteger
    End Function

    ''' <summary>
    ''' キーボードが接続しているか判定する。
    ''' </summary>
    ''' <returns>キーボードが接続している場合は true。それ以外の場合は false。</returns>
    Public Function IsKeyboardConnected() As Boolean
        Dim result As Boolean = False
        '----- デバイス一覧を取得する
        Dim NumberOfDevices As Integer = 0
        Dim deviceCount As UInteger = 0
        Dim dwSize As Integer = Marshal.SizeOf(GetType(RAWINPUTDEVICELIST))
        If GetRawInputDeviceList(IntPtr.Zero, deviceCount, CType(dwSize, UInteger)) = 0 Then
            Dim pRawInputDeviceList As IntPtr = Marshal.AllocHGlobal(CType((dwSize * deviceCount), Integer))
            GetRawInputDeviceList(pRawInputDeviceList, deviceCount, CType(dwSize, UInteger))
            For index As Integer = 0 To deviceCount - 1
                Dim pcbSize As UInteger = 0
                Dim rid As RAWINPUTDEVICELIST =
                    CType(
                        Marshal.PtrToStructure(
                            New IntPtr((pRawInputDeviceList.ToInt64 + (dwSize * index))),
                            GetType(RAWINPUTDEVICELIST)),
                        RAWINPUTDEVICELIST)
                GetRawInputDeviceInfo(rid.hDevice, RIDI_DEVICENAME, IntPtr.Zero, pcbSize)
                If pcbSize > 0 Then
                    If rid.dwType = RIM_TYPEKEYBOARD Then
                        '----- キーボードデバイスが存在する場合
                        result = True
                        Exit For
                    End If
                End If
            Next
            Marshal.FreeHGlobal(pRawInputDeviceList)
        Else
            '----- API失敗だがキーボードはある事とする。
            result = True
        End If
        Return result
    End Function
End Module
----- Devices終わり -----

ERROR-迷惑投稿者と判定されました。
となって送れない...涙