C# と VB.NET の質問掲示板

お世話になります。えれこぜと申します。
VB2005を使用して、別スレッドから親フォームのラベルコントロールを操作するプログラムを作成しています。
別スレッドの動作中に親フォームを終了させると、かなりの頻度でエラーが発生してしまいます。

ObjectDisposedException
破棄されたオブジェクトにアクセスできません。
オブジェクト名 'Form1' です。

親フォームが破棄されていたら、メソッドを抜けるようにしましたが、
あまり意味がないようで、エラーが発生してしまいます。

'親フォーム
Public Class Form1
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        If Not BackgroundWorker1.IsBusy Then
            BackgroundWorker1.RunWorkerAsync()
        End If
    End Sub

    Public Delegate Sub Label1ValueDelegate(ByVal str As String)
    Public Sub Label1_Value(ByVal str As String)
        If Me.IsDisposed Then
            Return
        End If
        If Me.InvokeRequired Then
            Me.Invoke(New Label1ValueDelegate(AddressOf Label1_Value), str)　'ここでエラーが発生します！
        End If
        Me.Label1.Text = str
    End Sub

    Private Sub BackgroundWorker1_DoWork(ByVal sender As Object, ByVal e As DoWorkEventArgs) Handles BackgroundWorker1.DoWork
        Dim hoge As New hoge(Me)
        hoge.DisplayMessage()
    End Sub
End Class

'別スレッド
Public Class hoge
    Private _form As Form1
    Sub New(ByVal form As Form1)
        Me._form = form
    End Sub

    Public Sub DisplayMessage()
        Dim label As New Form1.Label1ValueDelegate(AddressOf _form.Label1_Value)
        For i As Integer = 100 To 1 Step -1
            label.Invoke(i.ToString)
            System.Threading.Thread.Sleep(100)
        Next
    End Sub
End Class

何かヒントでも頂ければと考えます。
よろしくお願い致します。

なぜわざわざ別クラス作成して複雑なコードを組んでいるのかがようわからん。
とりあえず、そのままの状態でやるとするなら

 Private Sub BackgroundWorker1_DoWork(ByVal sender As System.Object, ByVal e As DoWorkEventArgs) Handles　ackgroundWorker1.DoWork
        Dim bgw As BackgroundWorker = CType(sender, BackgroundWorker)
        Dim hoge As New hoge(Me)
        hoge.DisplayMessage(bgw, e)
 End Sub

Private Sub Form1_FormClosing(ByVal sender As System.Object, ByVal e As System.Windows.Forms.FormClosingEventArgs) Handles MyBase.FormClosing
    Me.BackgroundWorker1.CancelAsync()
    While Me.BackgroundWorker1.IsBusy
        Application.DoEvents()
    End While
End Sub

' hogeクラス
Public Sub DisplayMessage(ByVal bgw As BackgroundWorker, ByVal e As DoWorkEventArgs)
    Dim label As New Form1.Label1ValueDelegate(AddressOf _form.Label1_Value)
    For i As Integer = 100 To 1 Step -1
        If bgw.CancellationPending Then
            e.Cancel = True
            Return
        End If
        label.Invoke(i.ToString)
        System.Threading.Thread.Sleep(100)
    Next
End Sub

とすればできる。


でもわざわざこんな複雑なコードを書かなくてもProgressChangeイベント関数はフォームスレッドで実行されるから
直接コントロールを扱えるから以下のコードで済む
(BackgroundWorkerのWorkeReportsProgress及びWorkerSupportsCancellationをTrueに設定しておく)

Private Sub BackgroundWorker1_DoWork(ByVal sender As System.Object, ByVal e As DoWorkEventArgs) Handles BackgroundWorker1.DoWork
    Dim bgw As BackgroundWorker = CType(sender, BackgroundWorker)
    For i As Integer = 100 To 1 Step -1
        If bgw.CancellationPending Then
            e.Cancel = True
            Return
        End If
        bgw.ReportProgress(i)
        System.Threading.Thread.Sleep(100)
    Next
End Sub

Private Sub BackgroundWorker1_ProgressChanged(ByVal sender As System.Object, ByVal e ProgressChangedEventArgs) Handles BackgroundWorker1.ProgressChanged
    Label1.Text = e.ProgressPercentage.ToString()
End Sub