C# と VB.NET の質問掲示板

■No55062 (チョーさん さん) に返信
> 複数セルの内容をドラッグで他のコントロールに持っていけるようにするため、
ドラッグでの範囲選択と、選択範囲のドラッグの両方を実現したいなら、
処理を単純化するために、
　「セルの選択は左ボタン」
　「ドラッグは右ボタン」
という仕様にしてしまうのが簡単かと。


> 現状では、複数セルが選択状態の時、任意の選択セルをマウスダウンした時点で、
> 選択状態が変わり、マウスダウンしたセルのみの選択になってしまいます。

どのようなコードになっていますか?


'手抜きコードなので、マウスドラッグでの選択はできません。
'複数選択には Ctrl や Shift キーを併用して行ってください。
Public Class Form1

    Private Sub Form1_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
        DataGridView1.AllowUserToAddRows = False
        DataGridView1.ColumnCount = 10
        DataGridView1.RowCount = 20
        DataGridView1.EditMode = DataGridViewEditMode.EditProgrammatically
        DataGridView1.MultiSelect = True
    End Sub

    Private Sub DataGridView1_MouseDown(ByVal sender As Object, _
      ByVal e As MouseEventArgs) Handles DataGridView1.MouseDown
        '実際に組み込む際には、SystemInformation.DragSize でのドラッグ開始判定や
        'クリックされた位置(ヘッダーは除外するなど)も判定条件に加えておいた方が良いかも。
        If CBool(e.Button And MouseButtons.Left) Then

            '選択されたセルの一覧
            Dim s As New List(Of String)()
            For Each c As DataGridViewCell In Me.DataGridView1.SelectedCells
                s.Insert(0, String.Format("{0}-{1}", c.RowIndex, c.ColumnIndex))
            Next

            '(テキストデータにしてあるので、メモ帳等にドロップしてください)
            DataGridView1.DoDragDrop(Join(s.ToArray(), vbCrLf), DragDropEffects.All)
        End If
    End Sub
End Class

■No55076 (チョーさん さん) に返信
> DataGridView1_MouseDownイベント内でDataGridView1.DoDragDropを行うことで、
> ドラッグ中はDataGridView上で複数選択状態（選択セルが反転表示）を保持したままになっていました。
だから、そういうコードを書いたのに…。(^_^;)


> ドラッグが終了あるいは中断するとセル選択は１セルのみになってしまいますが、
> とりあえずこれはよしとします。
無理矢理戻してみました。これでもまだ不十分な感はありますけれども。


Public Class Form1
    Private Sub Form1_Load(ByVal sender As Object, ByVal e As EventArgs) Handles MyBase.Load
        DataGridView1.AllowUserToAddRows = False
        DataGridView1.ColumnCount = 10
        DataGridView1.RowCount = 20
        DataGridView1.ReadOnly = True
        DataGridView1.MultiSelect = True
    End Sub

    Private Sub DataGridView1_MouseDown(ByVal sender As Object, ByVal e As MouseEventArgs) Handles DataGridView1.MouseDown
        If CBool(e.Button And MouseButtons.Left) Then
            Dim ht = DataGridView1.HitTest(e.X, e.Y)
            If ht.Type = DataGridViewHitTestType.Cell AndAlso ht.RowIndex <> -1 And ht.ColumnIndex <> -1 Then
                If DataGridView1(ht.ColumnIndex, ht.RowIndex).Selected Then
                    '選択されたセルの一覧
                    Dim cellList As New List(Of DataGridViewCell)()
                    Dim textList As New List(Of String)()
                    For Each c As DataGridViewCell In Me.DataGridView1.SelectedCells
                        cellList.Insert(0, c)
                        textList.Insert(0, String.Format("{0}-{1}", c.RowIndex, c.ColumnIndex))
                    Next

                    Dim data As String = Join(textList.ToArray(), vbCrLf)
                    DataGridView1.DoDragDrop(data, DragDropEffects.All)

                    BeginInvoke(New Foo(AddressOf ReSelect), cellList)
                End If
            End If
        End If
    End Sub

    Private Delegate Sub Foo(ByVal selectedCells As IEnumerable(Of DataGridViewCell))
    Private Sub ReSelect(ByVal selectedCells As IEnumerable(Of DataGridViewCell))
        For Each c In selectedCells
            c.Selected = True
        Next
    End Sub
End Class