C# と VB.NET の質問掲示板

■No75122 (VBNET さん) に返信

だいたいこんな感じでいけると思います。
Form1以外はたくさん用意するのが面倒なのでForm2を兼用しています。
実際はそれぞれのFormインスタンスを作成するようにしてください。
Iterator,yieldが使えないバージョンでしたらShowFormの中を工夫して
呼ばれる毎にCheckedIndicesを順番に処理するようにしてみて下さい。

Public Class Form1

    Private _Forms As IEnumerator(Of Form)
    Private WithEvents _Form As Form

    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles Me.Load
        CheckedListBox1.Items.AddRange({"Form2を表示",
                                        "Form3を表示",
                                        "Form4を表示"})
    End Sub

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        _Forms = OpenForms().GetEnumerator()
        ShowForm()
    End Sub

    Private Iterator Function OpenForms() As IEnumerable(Of Form)
        Dim idxs() As Integer = CheckedListBox1.CheckedIndices.OfType(Of Integer)().ToArray
        Dim frm As Form = Nothing

        For Each idx In idxs
            Select Case idx
                Case 0
                    frm = New Form2()
                    frm.Text = "Form2"
                Case 1
                    frm = New Form2()
                    frm.Text = "Form3"
                Case 2
                    frm = New Form2()
                    frm.Text = "Form4"
            End Select
            Yield frm
        Next
        frm = New Form2()
        frm.text = "Form5"
        Yield frm
    End Function

    Private Sub ShowForm()
        If _Forms.MoveNext Then
            _Form = _Forms.Current()
            If _Form IsNot Nothing Then
                _Form.Show()
                Me.Hide()
            End If
        Else
            Me.Show()
        End If
    End Sub

    Private Sub _Form_FormClosed(sender As Object, e As FormClosedEventArgs) Handles _Form.FormClosed
        ShowForm()
    End Sub
End Class