C# と VB.NET の質問掲示板

■No81766 (Artor さん) に返信

VB.net 知らないので、プログラムは書けないです。

ExcelなどのCOM オブジェクトは
丁寧に丁寧に解放してやらないとプロセスが残ってしまいます。

Artorさんのプログラムで、Workbooks.AddのWorkbooksや
objRange2(row, 1).textのobjRange2(row, 1)のように
ピリオドの前のやつは常に解放が必要です。

Do While Not String.IsNullOrEmpty(objRange2(row, 1).text)
は、こんな感じです。

　　Do While 真 '無限ループ
　　　　aaa = objRange2(row, 1)
        sss = aaa.text
        System.Runtime.InteropServices.Marshal.FinalReleaseComObject(aaa)
        if String.IsNullOrEmpty(sss) ループを抜ける

気持ちが伝わりますでしょうか？

■No81762 (Artor さん) に返信
> シート1：シート上の5つのセルにそれぞれ名前が付けられている
> シート2：A列（A1〜A5）にシート1の名前5つが記載されている
> シート2のA列に記載されている名前から、シート1の該当セルの値を読み取り、
> データテーブルに入れて返す

1 行 5 列の DataTable ということでしょうか。
この条件だと、Cells プロパティの出番は無い気がします。


Private Function Sample(ByVal folderPath As String, ByVal fileName As String) As DataTable
    Dim ds As New DataSet()
    Dim dt As DataTable = ds.Tables.Add(fileName)
    dt.CaseSensitive = True

    Dim xlApp As New Excel.Application()
    xlApp.DisplayAlerts = False
    xlApp.Visible = Debugger.IsAttached
    Dim xlBooks As Excel.Workbooks = xlApp.Workbooks
    Dim fullPath As String = Path.Combine(folderPath, fileName)
    Dim xlBook As Excel.Workbook = xlBooks.Add(fullPath)
    Dim xlSheets As Excel.Sheets = xlBook.Worksheets
    Dim xlSheet1 = DirectCast(xlSheets(1), Excel.Worksheet)
    Dim xlSheet2 = DirectCast(xlSheets(2), Excel.Worksheet)

    'シート2：A列（A1〜A5）にシート1の名前5つが記載されている
    Dim xlRange2 As Excel.Range = xlSheet2.Range("A1:A5")
    Dim oValue As Object = xlRange2.Value
    Marshal.ReleaseComObject(xlRange2)

    Dim sNames = DirectCast(oValue, Object(,)).OfType(Of String)()
    sNames = sNames.Where(Function(sName) Not String.IsNullOrEmpty(sName)).Distinct()

    'シート1：シート上の5つのセルにそれぞれ名前が付けられている
    Dim dr As DataRow = dt.NewRow()
    For Each sName In sNames
        dt.Columns.Add(sName)
        Dim xlRange1 As Excel.Range = xlSheet1.Range(sName)
        dr(sName) = xlRange1.Text
        Marshal.ReleaseComObject(xlRange1)
    Next

    Marshal.ReleaseComObject(xlSheet2)
    Marshal.ReleaseComObject(xlSheet1)
    Marshal.ReleaseComObject(xlSheets)
    xlBook.Close(False)
    Marshal.ReleaseComObject(xlBook)
    Marshal.ReleaseComObject(xlBooks)
    xlApp.ScreenUpdating = True
    xlApp.DisplayAlerts = True
    xlApp.Quit()
    Marshal.ReleaseComObject(xlApp)

    dt.Rows.Add(dr)
    dt.AcceptChanges()

    Return dt
End Function