C# と VB.NET の質問掲示板

お世話になります。

下記にては、親フォームForm1の中には子フォームForm2が開くのですが、
これを、子フォームForm2が開いた時には親フォームForm1は閉じ、子フォームForm2が閉じた時には再び親フォームForm1は開く。

このようにするにはどのようにすべきなのでしょう？
よろしくお願いします。

Public Class Form1
    Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        Me.SetBounds(0, 0, 1000, 800, BoundsSpecified.All)
        'このフォームを MDI コンテナとして設定 
        Me.IsMdiContainer = True
    End Sub

    '子フォーム Test1を開く
    Private Sub Test1ToolStripMenuItem_Click(sender As Object, e As EventArgs) Handles Test1ToolStripMenuItem.Click
        Dim frmchild As New Form2
        frmchild.MdiParent = Me
        frmchild.Show()
    End Sub
End Class

Public Class Form2
    Private Sub Form2_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
        Me.SetBounds(300, 100, 500, 200, BoundsSpecified.All)
    End Sub

    'このフォームを閉じる
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Me.Close()
    End Sub
End Class

■No93878 (くま さん) に返信
> これを、子フォームForm2が開いた時には親フォームForm1は閉じ、子フォームForm2が閉じた時には再び親フォームForm1は開く。

MDI では実現できません。
こんな感じにしてみてはいかがでしょうか。

Public Class Form1

    Private WithEvents _Form2 As Form2

    Private Sub ToolStrip1_ItemClicked(sender As Object,
                                    e As ToolStripItemClickedEventArgs) _
                                    Handles ToolStrip1.ItemClicked
        _Form2 = New Form2()
        _Form2.Show()
    End Sub

    Private Sub _Form2_Shown(sender As Object, e As EventArgs) _
                                    Handles _Form2.Shown
        Me.Visible = False
    End Sub

    Private Sub _Form2_FormClosed(sender As Object, e As FormClosedEventArgs) _
                                    Handles _Form2.FormClosed
        _Form2 = Nothing
        Me.Visible = True
    End Sub

End Class

■No93880 (KOZ さん) に返信

Public Class Form1

    Private WithEvents _Form2 As Form2

    Private Sub ToolStrip1_ItemClicked(sender As Object, e As ToolStripItemClickedEventArgs) Handles ToolStrip1.ItemClicked
        _Form2 = New Form2()
        _Form2.Show()
    End Sub

    Private Sub _Form2_Shown(sender As Object, e As EventArgs) Handles _Form2.Shown
        Me.Visible = False
    End Sub

    Private Sub _Form2_FormClosed(sender As Object, e As FormClosedEventArgs) Handles _Form2.FormClosed
        _Form2 = Nothing
        Me.Visible = True
    End Sub

End Class

ありがとうございます。
これで合ってるでしょうか？
ToolStrip1　の部分で下記のエラーが出てもしまいます。

また、_Form2 = New Form2()　などの前にある _ の意味も教えていただけますか？


> エラー BC30506	Handles 句には、それを含む型または基本型の 1 つで定義された WithEvents 変数が必要です。

■No93907 (くま さん) に返信

   '子フォーム Test1を開く
    Private Sub Test1ToolStripMenuItem_Click(sender As Object, e As EventArgs) Handles Test1ToolStripMenuItem.Click
        Dim frmchild As New Form2
        frmchild.MdiParent = Me
        frmchild.Show()
    End Sub

最初に提示されたコードがこうなってますので、中身を

        _Form2 = New Form2()
        _Form2.Show()

に入れ替えればよいはずですけど。

もう少し考えてみます。