C# と VB.NET の質問掲示板

環境：VB2017,.NET4.7.2

整数を2進文字列に変換したいのですが、判らない事があるので、ご指導下さい。
教えてもらいたいのは以下のコードに記載した★印の箇所です。

★(1)：Int64型のMinValueをリテラルで宣言するとコンパイルエラーになります。
Long.MinValueやInt64.MinValueとすると大丈夫です。
リテラル表記ではエラーとなる仕様なのでしょうか？

★(2)：SByte.MinValue(-128)をConvert.ToStringで2進文字列に変換すると
「1111111110000000」になり2バイトで返却されます。
自分の予想では最上位の符号ビットだけが立った1バイト「10000000」が返却される
と思っていたのですが違うのでしょうか？SByteって「-128〜127」の1バイトですよね？

★(3)：UInt64型はConvert.ToStringでコンパイルエラーとなります。

以上、ご指導よろしくお願いします。

PS.その他の整数型も試したので変数名がv1からv15で途中欠番になっています。

    Private Sub ToolStripButton1_Click(sender As Object, e As EventArgs) Handles ToolStripButton1.Click
        Dim v1 As SByte = SByte.MinValue　
        Dim v15 As UInt64 = UInt64.MinValue
        Dim v16 As UInt64 = UInt64.MaxValue
        'Dim v17 As Int64 = -9223372036854775808L   ★(1)コンパイルエラー(オーバーフロー)
        Debug.WriteLine(Convert.ToString(v1, 2)) '1111111110000000 ★(2) 
        'Debug.WriteLine(Convert.ToString(v15, 2))  ★(3)コンパイルエラー(オーバーロードなし)
        'Debug.WriteLine(Convert.ToString(v16, 2))  ★(3)コンパイルエラー(オーバーロードなし)
    End Sub

■No94507 (otu さん) に返信

BigIntegerの拡張メソッドとして、自作してみました。ついでだったので16進用も作っています。
他の人の役に立つかもしれないので、置いておきます。

これも、BigIntegerコンストラクタでSByteを取るオーバーロードはないですが、
暗黙でキャストされて問題ないみたいです。
一応、期待通りの結果が得られていると思いますが、問題点があればご指摘下さい。


Module BigIntegerExtensions
    'System.Numerics.dllへの参照を追加
    <Extension()>
    Public Function ToBinaryString(Of T)(ByVal bigint As BigInteger) As String
        'T型のByte数
        Dim byteT As Integer = Marshal.SizeOf(GetType(T))
        '0の場合はビット数分の0を返却
        If bigint.IsZero Then Return New String("0"c, byteT * 8)
        'BigInteger==>Byte配列
        Dim bytes = bigint.ToByteArray().ToList
        'Byte配列の要素数をT型のByte数に合わせる
        If bytes.Count <> byteT Then
            If bytes.Count > byteT Then
                '多い場合は末尾をカット
                bytes = bytes.Take(byteT).ToList
            Else
                '少ない場合は末尾に付け加える
                For i = 0 To byteT - bytes.Count - 1
                    bytes.Add(0)
                Next
            End If
        End If
        Dim ret = New StringBuilder(bytes.Count * 8)
        For i = bytes.Count - 1 To 0 Step -1
            Dim binary = Convert.ToString(bytes(i), 2).PadLeft(8, "0"c)
            ret.Append(binary)
        Next
        Return ret.ToString()
    End Function
    <Extension()>
    Public Function ToHexString(ByVal bigint As BigInteger) As String
        Return bigint.ToString("X")
    End Function
    <Extension()>
    Public Function ToHexString(ByVal bigint As BigInteger, digits As Integer) As String
        Return bigint.ToString("X").PadLeft(digits, "0"c)
    End Function
End Module

呼び出し側
Dim v1 As SByte = SByte.MinValue
Dim bigdec As BigInteger = New BigInteger(v1)
'2進
Debug.WriteLine(bigdec.ToBinaryString(Of SByte))
'16進
Debug.WriteLine(bigdec.ToHexString)
        '16進+桁数指定
Debug.WriteLine(bigdec.ToHexString(10))