C# と VB.NET の質問掲示板

■No96106 (雀 さん) に返信
> ウインドウを順番に .BringToFront()を設定していく必要があります。
> ウインドウの数が多いと、画面がちかちかして時間がかかってしまいます。

だからこそ、並びの順に下から作成するのがベストだと書いたのですが・・・

一応、こんな感じで抑制できそうです。

<DllImport("user32.dll")>
Private Shared Function LockWindowUpdate(ByVal hWndLock As IntPtr) As Boolean
End Function

Private Enum ShowWindowCommands
    SW_HIDE = 0
    SW_SHOWNORMAL = 1
    SW_SHOWMINIMIZED = 2
    SW_SHOWMAXIMIZED = 3
    SW_MAXIMIZE = 3
    SW_SHOWNOACTIVATE = 4
    SW_SHOW = 5
    SW_MINIMIZE = 6
    SW_SHOWMINNOACTIVE = 7
    SW_SHOWNA = 8
    SW_RESTORE = 9
    SW_SHOWDEFAULT = 10
    SW_FORCEMINIMIZE = 11
End Enum

<DllImport("user32.dll")>
Private Shared Function ShowWindow(hWnd As IntPtr, <MarshalAs(UnmanagedType.I4)> nCmdShow As ShowWindowCommands) As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function

Private Sub ToolStripButton1_Click(sender As Object, e As EventArgs) Handles ToolStripButton1.Click
    If Me.MdiChildren.Count > 0 Then
        Dim mc As MdiClient = Me.MdiChildren(0).Parent
        LockWindowUpdate(mc.Handle)
        ShowWindow(mc.Handle, ShowWindowCommands.SW_HIDE)
        '
        ' 並び替えの処理
        '
        ShowWindow(mc.Handle, ShowWindowCommands.SW_SHOW)
        LockWindowUpdate(IntPtr.Zero)
    End If
End Sub

■No96121 (KOZ さん) に返信



ありがとうございます。

試してみたところ、Zオーダーに関してはうまくいきました。

ただ、少し気になったのは、

Zオーダーと同時に、ウインドウサイズや位置、状態も復元したいと考えています。

あるウインドウが最小化した状態で
以下のコードを走らせると、


Private Sub ToolStripButton1_Click(sender As Object, e As EventArgs) Handles ToolStripButton1.Click
    If Me.MdiChildren.Count > 0 Then
        Dim mc As MdiClient = Me.MdiChildren(0).Parent
        LockWindowUpdate(mc.Handle)
        ShowWindow(mc.Handle, ShowWindowCommands.SW_HIDE)
        '
        ' 並び替えと、ウインドウサイズや位置、状態の処理（最小化していたウインドウが通常モードに切り替わる）
        '
        ShowWindow(mc.Handle, ShowWindowCommands.SW_SHOW)
        LockWindowUpdate(IntPtr.Zero)
    End If
End Sub

最小化していたウインドウを通常モードしようとすると、
タイトルバーだけのウインドウになってしまいます。


いろいろと試してみたのですが、
以下のように、SW_FORCEMINIMIZEを使えば、この問題は起きなくなります。


        Dim mc As MdiClient = Me.MdiChildren(0).Parent
        LockWindowUpdate(mc.Handle)
        ShowWindow(mc.Handle, ShowWindowCommands.SW_FORCEMINIMIZE)
        '
        ' 並び替えと、ウインドウサイズや位置、状態の処理
        '
        ShowWindow(mc.Handle, ShowWindowCommands.SW_SHOW)
        LockWindowUpdate(IntPtr.Zero)

  SW_MINIMIZEでもいけるかと思いましたが、
SW_FORCEMINIMIZEでしかうまくいかないようです。

SW_FORCEMINIMIZEについて調べてみると

https://www.tokovalue.jp/function/ShowWindow.htm

Windows 2000：たとえウィンドウを所有するスレッドがハングしていても、ウィンドウを最小化する。

このフラグは、ほかのスレッドのウィンドウを最小化する場合にだけ使用する。

Windows 2000と書かれてあり、何かよく分からない説明が書かれてあります。

Windows10を使った場合で、上記のような使い方は問題ないのでしょうか？

■No96163 (魔界の仮面弁士 さん) に返信


ありがとうございます。

                            If frm00.IsMdiContainer Then
                                Dim container As MdiClient = frm00.Controls.OfType(Of MdiClient).Single()
                                For Each child As Form In container.MdiChildren

                                    child.ZOrder = 1

                                Next
                            End If

とやろうとすると、
'ZOrder' は 'Form' のメンバーではありません。

というエラーが出てしまいます。

                                    CType(child, MdiChild).ZOrder = 1

でも駄目なようです。
何かやり方が間違っているのでしょうか？

■No96166 (雀 さん) に返信
> ■No96165 (魔界の仮面弁士 さん) に返信
> 
うあ、ごめんなさい。
Windows.Forms ではなくて、Microsoft Forms のメンバーでした。

えっと。。。そうすると、ちらつきなしでとするなら、DeferWindowPos を使う方法か。
Windows API なので、P/Invoke で呼び出しになりますが。


// 以下C#なコード(ただし、P/Invoke 省略)
List<Form> orderList; // Zorder 的に下から順に並べたいウィンドウのリスト

var dwp = BeginDeferWindowPos( orderList.Length );

Form prev = null;
foreach( var form in orderList )
{
  DeferWindowPos( dwp, form, prev, 0, 0, 0, 0, SWP_NOMOVE|SWP_NOSIZE );
  prev = form;
}
EndDeferWindowPos( dwp );

これで、任意順に並べ替えができるはずです。

■No96167 (とっちゃん さん) に返信
おお、こんないい方法があったのですね。知りませんでした。
とっちゃんさん、ありがとうございます。

順番を逆にするサンプルを書いてみました。
childForm.Left, childForm.Top, childForm.Width, childForm.Height の部分は回復する位置・大きさに修正してください。

<DllImport("user32.dll", SetLastError:=True, CharSet:=CharSet.Auto)>
Private Shared Function GetWindow(ByVal hWnd As IntPtr, ByVal uCmd As GetWindowType) As IntPtr
End Function

Private Enum GetWindowType As UInteger
    GW_HWNDFIRST = 0
    GW_HWNDLAST = 1
    GW_HWNDNEXT = 2
    GW_HWNDPREV = 3
    GW_OWNER = 4
    GW_CHILD = 5
    GW_ENABLEDPOPUP = 6
End Enum

<DllImport("user32.dll", SetLastError:=True)>
Private Shared Function BeginDeferWindowPos(nNumWindows As Integer) As IntPtr
End Function

Private Enum ShowWindowPosition As UInteger
    SWP_NOSIZE = &H1
    SWP_NOMOVE = &H2
    SWP_NOZORDER = &H4
    SWP_NOREDRAW = &H8
    SWP_NOACTIVATE = &H10
    SWP_DRAWFRAME = &H20
    SWP_FRAMECHANGED = &H20
    SWP_SHOWWINDOW = &H40
    SWP_HIDEWINDOW = &H80
    SWP_NOCOPYBITS = &H100
    SWP_NOOWNERZORDER = &H200
    SWP_NOREPOSITION = &H200
    SWP_NOSENDCHANGING = &H400
    SWP_DEFERERASE = &H2000
    SWP_ASYNCWINDOWPOS = &H4000
End Enum

<DllImport("user32.dll", SetLastError:=True)>
Private Shared Function DeferWindowPos(
    hWinPosInfo As IntPtr,
    hWnd As IntPtr,
    hWndInsertAfter As Integer,
    x As Integer, y As Integer,
    cx As Integer, cy As Integer,
    uFlags As ShowWindowPosition) As IntPtr
End Function

<DllImport("user32.dll", SetLastError:=True)>
Private Shared Function EndDeferWindowPos(hWinPosInfo As IntPtr) As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function

Private Sub ToolStripButton2_Click(sender As Object, e As EventArgs) Handles ToolStripButton2.Click
    If Me.MdiChildren.Count > 0 Then
        Dim orderList As New List(Of Form)
        Dim childHwnd As IntPtr = GetWindow(Me.MdiChildren(0).Handle, GetWindowType.GW_HWNDLAST)
        While childHwnd <> IntPtr.Zero
            Dim childForm As Form = Control.FromHandle(childHwnd)
            orderList.Add(childForm)
            childHwnd = GetWindow(childHwnd, GetWindowType.GW_HWNDPREV)
        End While
        Dim dwp As IntPtr = BeginDeferWindowPos(orderList.Count)
        Dim prev As IntPtr = IntPtr.Zero
        For Each childForm As Form In orderList
            childForm.WindowState = FormWindowState.Normal
            DeferWindowPos(dwp, childForm.Handle, prev, childForm.Left, childForm.Top, childForm.Width, childForm.Height, 0)
            prev = childForm.Handle
        Next
        EndDeferWindowPos(dwp)
    End If
End Sub