C# と VB.NET の質問掲示板

次々違う質問をされると回答できませんよ。
> Clipboard.SetImage(PictureBox1.Image)
> だと、PictureBox1_Paint上に書いたラインなどが描画されません、
ラインの描写先が間違っていませんか？

        Dim objPen = New Pen(System.Drawing.Color.Blue, 2)
        Dim objFont = New Font("ＭＳ Ｐゴシック", 15)
        Dim objGrp As Graphics = Graphics.FromImage(PictureBox1.Image) 'ここポイント

        ' 直線を引く
        objGrp.DrawLine(objPen, 20, 20, 200, 200)
        ' 楕円を描く
        objGrp.DrawEllipse(objPen, 10, 10, 190, 190)
        ' 楕円を描く
        objGrp.DrawString("描画テスト", objFont, Brushes.Red, 80, 100)

        ' リソースを解放する
        objPen.Dispose()
        objFont.Dispose()
        objGrp.Dispose()

        Clipboard.SetImage(PictureBox1.Image)

これで書かれた線などもクリップボードに読み込まれます。
というかそうしないとフォーム最小化とか重なった後書いた線消えてるでしょ？

フォーム全体なら
        'コントロールの外観を描画するBitmapの作成
        Dim bmp As New Bitmap(Me.Width, Me.Height)
        'キャプチャする
        Me.DrawToBitmap(bmp, New Rectangle(0, 0, Me.Width, Me.Height))

        Clipboard.SetImage(bmp)

        bmp.Dispose()

> あと、Chart1に関してもクリップボードにコピーしたいのですが、
> これにはImageがないのでコピーすることができません。

コントロールだけなら
フォームやコントロールの外観をキャプチャする
https://dobon.net/vb/dotnet/graphics/invokepaint.html

        <System.Runtime.InteropServices.DllImport("User32.dll")> _
        Private Shared Function PrintWindow(ByVal hwnd As IntPtr, _
            ByVal hDC As IntPtr, ByVal nFlags As Integer) As Boolean
        End Function
        
        ''' <summary>
        ''' コントロールのイメージを取得する
        ''' </summary>
        ''' <param name="ctrl">キャプチャするコントロール</param>
        ''' <returns>取得できたイメージ</returns>
        Public Function CaptureControl(ByVal ctrl As Control) As Bitmap
            Dim img As New Bitmap(ctrl.Width, ctrl.Height)
            Dim memg As Graphics = Graphics.FromImage(img)
            Dim dc As IntPtr = memg.GetHdc()
            PrintWindow(ctrl.Handle, dc, 0)
            memg.ReleaseHdc(dc)
            memg.Dispose()
            Return img
        End Function

        Dim bmp As Bitmap = CaptureControl(Chart1)
	Clipboard.SetImage(bmp)
        bmp.Dispose()

重ね重ねありがとうございます。

GetWindowDC → BitBlt の方も調べてみましたが、

https://dobon.net/vb/dotnet/graphics/screencapture.html

このページを参考に

Public Shared Function CaptureActiveWindow() As Bitmap
    'アクティブなウィンドウのデバイスコンテキストを取得
    Dim hWnd As IntPtr = GetForegroundWindow()
    Dim winDC As IntPtr = GetWindowDC(hWnd)
    'ウィンドウの大きさを取得
    Dim winRect As New RECT
    GetWindowRect(hWnd, winRect)
    'Bitmapの作成
    Dim bmp As New Bitmap(winRect.right - winRect.left, _
        winRect.bottom - winRect.top)
    'Graphicsの作成
    Dim g As Graphics = Graphics.FromImage(bmp)
    'Graphicsのデバイスコンテキストを取得
    Dim hDC As IntPtr = g.GetHdc()
    'Bitmapに画像をコピーする
    BitBlt(hDC, 0, 0, bmp.Width, bmp.Height, winDC, 0, 0, SRCCOPY)
    '解放
    g.ReleaseHdc(hDC)
    g.Dispose()
    ReleaseDC(hWnd, winDC)

    Return bmp
End Function

というコードを試してみたところ
うまく取得することができました。

ただ、タイトルバーが真っ黒になってしまい表示されません。

これは仕様上仕方ないことでしょうか？