C# と VB.NET の質問掲示板

■No99152 (あんこ さん) に返信
> 親フォームの MyBase.Paintに直接文字列やラインを描画しようとしたのですが、
> フォームが変化するたびに、 MyBase.Paintは実行されているようなのですが、
> なぜか何も描画されません。
> なぜでしょうか・・・？

MDIForm で見えている表示領域は、MDIClient というコントロールです。
子ウインドウは、MDIClient の子ウインドウになります。

Private Sub MDIParent1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    Dim client As MdiClient = Controls.OfType(Of MdiClient).FirstOrDefault()
    If client IsNot Nothing Then
        AddHandler client.Paint, AddressOf Client_Paint
    End If
End Sub

Private Sub Client_Paint(sender As Object, ByVal e As PaintEventArgs)
    e.Graphics.DrawLine(Pens.White, New Point(0, 0), New Point(100, 100))
End Sub

こんな感じで描画できますが、子ウインドウの後ろに隠れちゃいます。

手前に透過ウインドウを置くとか。

Private TransparentWindow As Form

Private Sub MDIParent1_Shown(sender As Object, e As EventArgs) Handles Me.Shown
    TransparentWindow = New Form With {
        .ControlBox = False,
        .FormBorderStyle = FormBorderStyle.None,
        .Bounds = Me.Bounds,
        .BackColor = Color.White,
        .TransparencyKey = Color.White,
        .ShowInTaskbar = False
    }
    TransparentWindow.Show(Me)
    AddHandler TransparentWindow.Paint, AddressOf TransparentWindow_Paint
    Me.Activate()
End Sub

Private Sub TransparentWindow_Paint(sender As Object, ByVal e As PaintEventArgs)
    e.Graphics.DrawLine(Pens.Red, New Point(100, 100), New Point(200, 200))
End Sub

Private Sub MDIParent1_LocationChanged(sender As Object, e As EventArgs) Handles Me.LocationChanged
    If TransparentWindow IsNot Nothing Then
        TransparentWindow.Location = Me.Location
    End If
End Sub

Private Sub MDIParent1_SizeChanged(sender As Object, e As EventArgs) Handles Me.SizeChanged
    If TransparentWindow IsNot Nothing Then
        TransparentWindow.Size = Me.Size
    End If
End Sub